WOLFRAM

Wolfram 语言与系统参考资料中心

CarlemanLinearize[sys,spec]

根据 spec 对非线性状态空间模型 sys 进行 Carleman 线性化.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
属性  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

CarlemanLinearize

CarlemanLinearize[sys,spec]

根据 spec 对非线性状态空间模型 sys 进行 Carleman 线性化.

更多信息

  • CarlemanLinearize 给出 sys 所嵌入的无限阶系统的逼近.
  • 输入线性系统的结果是双线性的，即在状态和输入都是线性的. 在一般情况下，它仅在状态是线性的.
  • spec 的可能值有：
  • k逼近阶
    {{e1,…,en}}嵌入变换的单项式
    {…,{z1,…,zn}}新状态变量
    {…,z,order}单项式排序
  • order 的可能设置与 MonomialList 中相同.
  • CarlemanLinearize 返回 LinearizingTransformationData 对象，可用于提取各种属性.
  • 可以给出下列属性：
  • "EmbeddingTransformation"{z1->e1,…,zn->en}
    "TransformedSystem"逼近变换系统
    {"OriginalSystemController",κ}原始系统 sys 的控制器
    {"OriginalSystemEstimator",ℓ}原始系统 sys 的估计器
    {"ClosedLoopSystem",κ}具有控制器的闭环系统 sys

范例

打开所有单元 关闭所有单元

基本范例  (1)

对非线性系统进行 Carleman 线性化：

Wolfram Language code: 𝒞ℒ = CarlemanLinearize[AffineStateSpaceModel[{{E^x}, {{1 + x^2}}, {x}, {{0}}}, {x}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None], 3]
Wolfram Language code: tsys = 𝒞ℒ["TransformedSystem"]

基于线性化模型设计控制器：

Wolfram Language code: κ = StateFeedbackGains[StateSpaceModel[tsys], {-0.5, -1 + I, -1 - I}]

闭环系统：

Wolfram Language code: csys = 𝒞ℒ[{"ClosedLoopSystem", κ}]

模拟闭环系统：

Wolfram Language code: OutputResponse[csys, 1, {t, 0, 20}]; Plot[%, {t, 0, 1}, PlotRange -> All]

范围  (10)

基本用法  (6)

对仿射系统进行 Carleman 线性化：

Wolfram Language code: 𝒞ℒ = CarlemanLinearize[AffineStateSpaceModel[{{x^2}, {{1}}, {x}, {{0}}}, {x}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None], 4]

变换后系统是双线性的：

Wolfram Language code: 𝒞ℒ["TransformedSystem"]
Wolfram Language code: SystemsModelLinearity[%]

嵌入变换：

Wolfram Language code: 𝒞ℒ["EmbeddingTransformation"]

指定要用的新变量：

Wolfram Language code: 𝒞ℒ = CarlemanLinearize[AffineStateSpaceModel[{{x^2}, {{1}}, {x}, {{0}}}, {x}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None], {4, {Subscript[z, 1], Subscript[z, 2], Subscript[z, 3], Subscript[z, 4]}}]

现在，结果是以指定变量的形式表示：

Wolfram Language code: 𝒞ℒ[{"TransformedSystem", "EmbeddingTransformation"}]

指定变换的形式：

Wolfram Language code: 𝒞ℒ = CarlemanLinearize[AffineStateSpaceModel[{{x^2}, {{1}}, {x}, {{0}}}, {x}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None], {4, {Subscript[z, 1], Subscript[z, 2], Subscript[z, 3], Subscript[z, 4]}}]
Wolfram Language code: 𝒞ℒ[{"TransformedSystem", "EmbeddingTransformation"}]

指定排序：

Wolfram Language code: 𝒞ℒ = CarlemanLinearize[AffineStateSpaceModel[{{x^2}, {{1}}, {x}, {{0}}}, {x}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None], {4, {Subscript[z, 1], Subscript[z, 2], Subscript[z, 3], Subscript[z, 4]}, "Lexicographic"}]
Wolfram Language code: 𝒞ℒ[{"TransformedSystem", "EmbeddingTransformation"}]

直接指定属性：

Wolfram Language code: CarlemanLinearize[AffineStateSpaceModel[{{x^2}, {{1}}, {x}, {{0}}}, {x}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None], 4, "TransformedSystem"]

直接指定多个属性：

Wolfram Language code: CarlemanLinearize[AffineStateSpaceModel[{{x^2}, {{1}}, {x}, {{0}}}, {x}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None], 4, {"TransformedSystem", "EmbeddingTransformation"}]

NonlinearStateSpaceModel 的线性化：

Wolfram Language code: 𝒞ℒ = CarlemanLinearize[NonlinearStateSpaceModel[{{u + u^2 + x^2}, {x}}, {x}, {u}, {Automatic}, Automatic, SamplingPeriod -> None], {4, {Subscript[z, 1], Subscript[z, 2], Subscript[z, 3], Subscript[z, 4]}}]

变换后的系统在状态中是线性的：

Wolfram Language code: 𝒞ℒ["TransformedSystem"]
Wolfram Language code: SystemsModelLinearity[%]

属性  (4)

所有属性：

Wolfram Language code: CarlemanLinearize[AffineStateSpaceModel[{{x^2}, {{1}}, {x}, {{0}}}, {x}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None], 4, "Properties"]

基本属性：

Wolfram Language code: 𝒞ℒ = CarlemanLinearize[AffineStateSpaceModel[{{x^2}, {{1}}, {x}, {{0}}}, {x}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None], 4];

变换：

Wolfram Language code: 𝒞ℒ["EmbeddingTransformation"]

变换后的系统：

Wolfram Language code: 𝒞ℒ["TransformedSystem"]

复合属性：

Wolfram Language code: asys = AffineStateSpaceModel[{{x + x^2}, {{1}}, {x}, {{0}}}, {{x, -1}}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None];

对系统线性化：

Wolfram Language code: 𝒞ℒ = CarlemanLinearize[asys, {4, {Subscript[z, 1], Subscript[z, 2], Subscript[z, 3], Subscript[z, 4]}}]

基于变换系统的泰勒线性化，设计控制器：

Wolfram Language code: κ = StateFeedbackGains[StateSpaceModel@𝒞ℒ["TransformedSystem"], {-0.5, -1, -2 + I, -2 - I}]

闭环系统是一个复合属性：

Wolfram Language code: csys = 𝒞ℒ[{"ClosedLoopSystem", κ}]//Simplify

输出响应：

Wolfram Language code: or = OutputResponse[{csys, -2}, 0, {t, 0, 5}]; Show[p = Plot[or, {t, 0, 5}, PlotRange -> All], PlotRange -> {{0, 0.5}, All}]

原始系统的控制器：

Wolfram Language code: 𝒞ℒ[{"OriginalSystemController", κ}]

控制作用：

Wolfram Language code: Plot[𝒞ℒ[{"OriginalSystemController", κ}] /. x -> or, {t, 0, 0.5}, PlotRange -> All]

基于泰勒线性化设计的闭环系统：

Wolfram Language code: csys1 = SystemsModelStateFeedbackConnect[asys, StateFeedbackGains[StateSpaceModel[asys], {-3}]]

系统的响应：

Wolfram Language code: or1 = OutputResponse[{csys1, -2}, 0, {t, 0, 5}]; p1 = Plot[or1, {t, 0, 5}, PlotRange -> All, PlotStyle -> Dashed]

比较这两个响应：

Wolfram Language code: Show[p, p1]

使用 Carleman 线性化设计估计器：

Wolfram Language code: asys = AffineStateSpaceModel[{{-2*x + x^2 - y + y^2, x^2 - 2*y}, {{1}, {1}}, {x}, {{0}}}, {{x, -1}, {y, -1}}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: 𝒞ℒ = CarlemanLinearize[asys, {2, {Subscript[z, 1], Subscript[z, 2], Subscript[z, 3], Subscript[z, 4], Subscript[z, 5]}}]

变换后系统的一组估计器增益：

Wolfram Language code: ℓ = EstimatorGains[StateSpaceModel@𝒞ℒ["TransformedSystem"], {-3, -4, -5, -6 + 2 I, -6 - 2I}]

原始系统的估计器：

Wolfram Language code: estim = 𝒞ℒ[{"OriginalSystemEstimator", ℓ}]

估计状态的轨迹：

Wolfram Language code: or = OutputResponse[{asys, {-0.2, 0.1}}, 0, {t, 0, 5}];
Wolfram Language code: res1 = OutputResponse[SystemsModelDelete[estim, None, 3], Join[{0}, or], {t, 0, 5}];
Wolfram Language code: Plot[res1, {t, 0, 5}, PlotRange -> All]

实际状态轨迹：

Wolfram Language code: res = StateResponse[{asys, {-0.2, 0.1}}, 0, {t, 0, 5}];

比较实际和估计的状态轨迹：

Wolfram Language code: Plot[Evaluate@Flatten@{res, res1}, {t, 0, 5}, PlotRange -> All, PlotLegends -> {"State 1", "State 2", "Estimated State 1", "Estimated State 2"}]

应用  (2)

基于 Carleman 线性化设计一个用于治疗 HIV-1 感染的疗法. 参数为健康细胞的衰减率 和产率 ，感染率系数 ，和病毒的衰减率 ： »

Wolfram Language code: pars = {d -> 0.02, s -> 10, θ -> 0.001, μ -> 0.24};

状态是健康细胞的水平 和自由病毒 ，输入是药物剂量：

Wolfram Language code: asys = AffineStateSpaceModel[{{s - d*Subscript[x, 1] - θ*Subscript[x, 1]*Subscript[x, 2], (-μ)*Subscript[x, 2] + θ*Subscript[x, 1]* Subscript[x, 2]}, {{θ*Subscript[x, 1]*Subscript[x, 2]}, {(-θ)*Subscript[x, 1]*Subscript[x, 2]}}}, {{Subscript[x, 1], (s - r*μ)/d}, {Subscript[x, 2], r}}, {{u, (s*θ - d*μ - r*θ*μ)/(θ* (s - r*μ))}}, {Automatic, Automatic}, Automatic, SamplingPeriod -> None] /. pars

在目标水平为10时，低剂量将导致病毒水平提高：

Wolfram Language code: sr = StateResponse[asys /. r -> 10, 0.2, {t, 0, 20}]; Table[Plot[sr, {t, 0, 20}], {sr, sr}]

对系统进行 Carleman 线性化：

Wolfram Language code: 𝒞ℒ = CarlemanLinearize[asys /. r -> 10, {{Subscript[x, 1], Subscript[x, 2], Subscript[x, 1]Subscript[x, 2]}}]

为线性化高阶系统设计控制器：

Wolfram Language code: ssm = StateSpaceModel[𝒞ℒ["TransformedSystem"]];
Wolfram Language code: κ = LQRegulatorGains[ssm, {DiagonalMatrix[{0.1, 50, 25}], {{3000}}}]

闭环系统：

Wolfram Language code: csys = 𝒞ℒ[{"ClosedLoopSystem", κ}]//Simplify

控制器将把健康细胞和病毒的浓度达到所需水平：

Wolfram Language code: sr = StateResponse[{csys, {370, 14}}, 0, {t, 0, 600}]; Table[Plot[sr, {t, 0, 600}], {sr, sr}]

剂量水平：

Wolfram Language code: -𝒞ℒ[{"OriginalSystemController", κ}]; Plot[% /. Thread[{Subscript[x, 1], Subscript[x, 2]} -> sr], {t, 0, 600}]

使用 Carleman 线性化设计一个估计器，根据连续搅拌釜反应器（CSTR）中反应器的温度在来估计反应物浓度： »

组装模型，其中 为输入， 为状态：

Wolfram Language code: aa = With[{c = (1 - Subscript[x, 1])Exp[Subscript[x, 2] / (1 + Subscript[x, 2] / γ)]}, {-Subscript[x, 1] + Subscript[d, a] c, -Subscript[x, 2] + b Subscript[d, a]c - β Subscript[x, 2]}]; bb = {{0}, {β}}; cc = {Subscript[x, 2]};
Wolfram Language code: pars = {β -> 1, Subscript[d, a] -> 1, b -> 1, γ -> 1};
Wolfram Language code: sys = AffineStateSpaceModel[{aa, bb, cc}, {Subscript[x, 1], Subscript[x, 2]}] /. pars

对系统进行 Carleman 线性化：

Wolfram Language code: 𝒞ℒ = CarlemanLinearize[sys, 4]
Wolfram Language code: 𝒞ℒ["TransformedSystem"]

设计估计器：

Wolfram Language code: EstimatorGains[StateSpaceModel[%], -Range[1, 14]//N];
Wolfram Language code: estim = 𝒞ℒ[{"OriginalSystemEstimator", %}]

计算实际反应物浓度：

Wolfram Language code: 𝒸 = StateResponse[{sys, {0.5, 3}}, 1, {t, 0, 7}][[1]]; Plot[𝒸, {t, 0, 7}, PlotRange -> All]

比较实际值和估计值：

Wolfram Language code: ℴ = OutputResponse[{sys, {0.5, 3}}, 1, {t, 0, 7}]; 𝒸ℯ = OutputResponse[estim, Join[{1}, ℴ], {t, 0, 7}][[1]];
Wolfram Language code: Plot[{𝒸, 𝒸ℯ}, {t, 0, 7}, PlotLegends -> {"Actual", "Estimated"}, PlotRange -> All]

属性和关系  (1)

阶数为1的 Carleman 线性化：

Wolfram Language code: assm = AffineStateSpaceModel[ {{ω, (g*m*(m + M)* Sin[θ])/(l*m^2 + l*m* M - l*m^2*Cos[θ]^2) - (l*m^2*ω^2*Cos[θ]*Sin[θ])/ (l*m^2 + l*m*M - l*m^2*Cos[θ]^2), v, (l^2*m^2*ω^2*Sin[θ])/ (l*m^2 + l*m*M - l*m^2*Cos[θ]^2) - (g*l*m^2*Cos[θ]*Sin[θ])/ (l*m^2 + l*m*M - l*m^2*Cos[θ]^2)}, {{0}, {(-m)*(Cos[θ]/(l*m^2 + l*m*M - l*m^2* Cos[θ]^2))}, {0}, {l*(m/(l*m^2 + l*m*M - l*m^2* Cos[θ]^2))}}, {θ, x}, {{0}, {0}}}, {θ, ω, x, v}, {{F, 0}}, {θ, x}, Automatic, SamplingPeriod -> None];
Wolfram Language code: CarlemanLinearize[assm, 1, "TransformedSystem"]

它等价于泰勒线性化：

Wolfram Language code: StateSpaceModel[assm]
Wolfram Research (2014)，CarlemanLinearize，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CarlemanLinearize.html.

文本

Wolfram Research (2014)，CarlemanLinearize，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CarlemanLinearize.html.

CMS

Wolfram 语言. 2014. "CarlemanLinearize." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CarlemanLinearize.html.

APA

Wolfram 语言. (2014). CarlemanLinearize. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CarlemanLinearize.html 年

BibTeX

@misc{reference.wolfram_2026_carlemanlinearize, author="Wolfram Research", title="{CarlemanLinearize}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/CarlemanLinearize.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_carlemanlinearize, organization={Wolfram Research}, title={CarlemanLinearize}, year={2014}, url={https://reference.wolfram.com/language/ref/CarlemanLinearize.html}, note=[Accessed: 06-September-2026]}