WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CarlsonRE[x,y]

Carlsonの楕円積分 TemplateBox[{x, y}, CarlsonRE]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
微分と積分  
関数表現  
関数の恒等式と簡約  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CarlsonRE

CarlsonRE[x,y]

Carlsonの楕円積分 TemplateBox[{x, y}, CarlsonRE]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 非負の引数について TemplateBox[{x, y}, CarlsonRE]=1/piint_0^infty(t+x)^(-1/2)(t+y)^(-1/2)sqrt(t)( x/(t+x)+y/(t+y))dt である．
  • CarlsonRE[x,y]は に不連続な分枝切断線を持つ．
  • 特別な引数の場合，CarlsonREは自動的に厳密値を計算する．
  • CarlsonREは任意の数値精度で評価できる．
  • CarlsonREは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

数値的に評価する：

Wolfram Language code: CarlsonRE[3., 5.]

関数をプロットする：

Wolfram Language code: Plot3D[CarlsonRE[x, y], {x, 0, 3}, {y, 0, 3}]

CarlsonREはルジャンドル(Legendre)の第2種完全楕円積分に関連している：

Wolfram Language code: (Pi/2)CarlsonRE[1, 1 - m] /. m -> 0.75
Wolfram Language code: EllipticE[0.75]

スコープ  (12)

数値評価  (5)

数値的に評価する：

Wolfram Language code: CarlsonRE[1.0, 1 / GoldenRatio]

高精度で評価する：

Wolfram Language code: N[CarlsonRE[2, 7], 50]

出力精度は入力精度に従う：

Wolfram Language code: CarlsonRE[2, 7.67890123456789012345]
Wolfram Language code: CarlsonRE[2, 7.678901234567890123456789012345]

複素引数について評価する：

Wolfram Language code: CarlsonRE[2. + 0.5 I, 2. - 0.5I]

高精度で効率的に評価する：

Wolfram Language code: Timing[CarlsonRE[11, 3`500]]
Wolfram Language code: Timing[Precision[CarlsonRE[11, 3`100000]]]

CarlsonREは要素単位でリストに縫い込まれる：

Wolfram Language code: CarlsonRE[{1, 2, 3, 4, 5}, {5., 4., 3., 2., 1.}]

特定の値  (1)

単純な厳密値は自動的に生成される：

Wolfram Language code: CarlsonRE[x, x]
Wolfram Language code: CarlsonRE[x, 0]

微分と積分  (2)

についての導関数：

Wolfram Language code: D[CarlsonRE[x, y], x]

についての導関数：

Wolfram Language code: D[CarlsonRE[x, y], y]

についての不定積分：

Wolfram Language code: Integrate[CarlsonRE[x, y], x]

についての不定積分：

Wolfram Language code: Integrate[CarlsonRE[x, y], y]

関数表現  (1)

TraditionalFormによる表示：

Wolfram Language code: CarlsonRE[x, y]//TraditionalForm

関数の恒等式と簡約  (3)

CarlsonREは，オイラー・ポアソン(Euler–Poisson)の編微分方程式を満足する：

Wolfram Language code: (x - y)Subscript[∂, x⁣y]CarlsonRE[x, y] + (1/2) Subscript[∂, y]CarlsonRE[x, y] - (1/2)Subscript[∂, x]CarlsonRE[x, y] == 0//FunctionExpand//FullSimplify

CarlsonREは，オイラーの同次関係を満足する：

Wolfram Language code: x Subscript[∂, x]CarlsonRE[x, y] + y Subscript[∂, y]CarlsonRE[x, y] == (1/2) CarlsonRE[x, y]//FunctionExpand//FullSimplify

CarlsonREが満足する偏微分方程式：

Wolfram Language code: Subscript[∂, x]CarlsonRE[x, y] + Subscript[∂, y]CarlsonRE[x, y] == (1/2) CarlsonRK[x, y]//FunctionExpand//FullSimplify

アプリケーション  (3)

楕円の弧の全長を求める：

Wolfram Language code: With[{a = Sqrt[2], b = 1}, N[2π CarlsonRE[a^2, b^2], 20]]

ArcLengthの結果と比較する：

Wolfram Language code: With[{a = Sqrt[2], b = 1}, ArcLength[{a Cos[t], b Sin[t]}, {t, 0, 2π}, WorkingPrecision -> 20]]

正規分布と相対的なReciprocal Square Root of a Quadratic Form（二次形式の平方根の逆数）の期待値：

Wolfram Language code: MatrixForm[mat = HilbertMatrix[2]]
Wolfram Language code: NExpectation[Sqrt[{u, v}.mat.{u, v} / 2], {u, v}BinormalDistribution[0]]//Quiet

CarlsonREによる閉じた形の結果と比較する：

Wolfram Language code: N[Gamma[(3/2)](CarlsonRE@@Eigenvalues[mat]), 25]

円筒と球の交点を可視化する：

Wolfram Language code: R = 1 / 6;r = 5 / 9;b = 5 / 11; cyl = Cylinder[{{0, 0, 0}, {0, 0, 2r}}, R]; ball = Ball[{b, 0, r}, r];
Wolfram Language code: Show@{ Graphics3D[{Opacity[1 / 2], cyl, ball}], Region[RegionIntersection[cyl, ball], PlotTheme -> "Web"]}

Carlson積分によって表されたCylinder-Ball Intersection（円筒と球の交点）の体積：

Wolfram Language code: N[(2π/9 )(2R(3 R (2 r^2 - R^2) - b (b^2 - 4 r^2 + 5 b R + 7 R^2) + (3 r^4/b - R))CarlsonRK[(b - r + R) (b + r + R), 4b R] + (b^2 - 4 r^2 + 7 R^2)CarlsonRE[(b - r + R) (b + r + R), 4b R] + 6b R r^4(b + r - R) (b + R) (b - r - R)CarlsonRM[(b - R)^2 (b - r + R) (b + r + R), 4 b R(b - R)^2, 4 b R r^2]), 20]

Volumeの結果と比較する：

Wolfram Language code: Volume[RegionIntersection[cyl, ball], WorkingPrecision -> 20]

特性と関係  (2)

CarlsonREは引数を並べ替えても変わらない：

Wolfram Language code: CarlsonRE[x, y] == CarlsonRE[y, x]

CarlsonREとCarlsonRKはルジャンドル(Legendre)の関係式を満足する：

Wolfram Language code: CarlsonRE[y - x, y]CarlsonRK[x, y] + CarlsonRE[x, y]CarlsonRK[y - x, y] - y CarlsonRK[x, y]CarlsonRK[y - x, y] == (2/π) /. {{x -> 5`50, y -> 7`50}, {x -> 5`50, y -> 3`50}}
Wolfram Research (2021), CarlsonRE, Wolfram言語関数， https://reference.wolfram.com/language/ref/CarlsonRE.html.

テキスト

Wolfram Research (2021), CarlsonRE, Wolfram言語関数， https://reference.wolfram.com/language/ref/CarlsonRE.html.

CMS

Wolfram Language. 2021. "CarlsonRE." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CarlsonRE.html.

APA

Wolfram Language. (2021). CarlsonRE. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CarlsonRE.html

BibTeX

@misc{reference.wolfram_2026_carlsonre, author="Wolfram Research", title="{CarlsonRE}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/CarlsonRE.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_carlsonre, organization={Wolfram Research}, title={CarlsonRE}, year={2021}, url={https://reference.wolfram.com/language/ref/CarlsonRE.html}, note=[Accessed: 07-August-2026]}