WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CarlsonRF[x,y,z]

Carlsonの楕円積分 TemplateBox[{x, y, z}, CarlsonRF]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
微分と積分  
関数表現  
関数の恒等式と簡約  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CarlsonRF

CarlsonRF[x,y,z]

Carlsonの楕円積分 TemplateBox[{x, y, z}, CarlsonRF]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • ，，のとき TemplateBox[{x, y, z}, CarlsonRF]=1/2int_0^infty(t+x)^(-1/2)(t+y)^(-1/2)(t+z)^(-1/2)dt である．
  • CarlsonRF[x,y,z]は に不連続な分枝切断線を持つ．
  • 特別な引数の場合，CarlsonRFは自動的に厳密値を計算する．
  • CarlsonRFは任意の数値精度で評価できる．
  • CarlsonRFは自動的にリストに縫い込まれる．
  • CarlsonRFは，IntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (3)

数値的に評価する：

Wolfram Language code: CarlsonRF[1., 2., 3.]

引数の範囲上にプロットする：

Wolfram Language code: Plot[{CarlsonRF[t, 2, 3], CarlsonRF[1, t, 3], CarlsonRF[1, 2, t]}, {t, 0, 6}, PlotLegends -> "Expressions"]

CarlsonRFは，のとき，ルジャンドル(Legendre)の第1種楕円積分 TemplateBox[{phi, m}, EllipticF]に関連している：

Wolfram Language code: Sin[ϕ] CarlsonRF[Cos[ϕ]^2, 1 - m Sin[ϕ]^2, 1] /. {ϕ -> Pi / 3, m -> 0.7}
Wolfram Language code: EllipticF[ϕ, m] /. {ϕ -> Pi / 3, m -> 0.7}

スコープ  (17)

数値評価  (6)

数値的に評価する：

Wolfram Language code: N[CarlsonRF[4, 6, 8]]
Wolfram Language code: N[CarlsonRF[4, -6, 8]]

高精度で評価する：

Wolfram Language code: N[CarlsonRF[1, 4, 9], 50]

出力精度は入力精度に従う：

Wolfram Language code: CarlsonRF[5, 3, 1.234567890123456789012345]
Wolfram Language code: CarlsonRF[5, 3, 1.2345678901234567890123456789012345]

複素引数について評価する：

Wolfram Language code: CarlsonRF[I, 1 - 2I, 3. + I]

高精度で効率的に評価する：

Wolfram Language code: Timing[CarlsonRF[2, 6, 7`500]]
Wolfram Language code: Timing[Precision[CarlsonRF[2, 6, 7`100000]]]

CarlsonRFは要素単位でリストに縫い込まれる：

Wolfram Language code: CarlsonRF[{1., 2., 3.}, {2., 3., 1.}, {3., 1., 2.}]

CarlsonRFは，IntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる：

Wolfram Language code: CarlsonRF[Interval[{1.23, 1.24}], Interval[{2.34, 2.35}], Interval[{3.45, 3.46}]]
Wolfram Language code: CarlsonRF[CenteredInterval[3 / 2, 1 / 100], CenteredInterval[5 / 4, 1 / 100], CenteredInterval[7 / 6, 1 / 100]]

特定の値  (4)

単純な厳密値は自動的に生成される：

Wolfram Language code: CarlsonRF[x, x, x]
Wolfram Language code: CarlsonRF[x, 2, 2]

CarlsonRFの一つの引数が0のとき，CarlsonRFは完全楕円積分CarlsonRKに変換される：

Wolfram Language code: CarlsonRF[0, x, y]

CarlsonRFの2つの引数が等しくかつ負の実軸上にはない場合，CarlsonRFはCarlsonRCに変換される：

Wolfram Language code: CarlsonRF[x, 2 + 3I, 2 + 3I]

CarlsonRFのすべての引数が等しくかつ負の実軸上にはない場合， CarlsonRFは初等関数に変換される：

Wolfram Language code: CarlsonRF[2 + 3I, 2 + 3I, 2 + 3I]

微分と積分  (2)

CarlsonRFの導関数はCarlsonRDに比例する：

Wolfram Language code: D[CarlsonRF[x, y, z], z]
Wolfram Language code: D[CarlsonRF[x, y, z], y]

CarlsonRFの不定積分：

Wolfram Language code: Integrate[CarlsonRF[x, y, z], z]

関数表現  (1)

TraditionalFormによる表示：

Wolfram Language code: CarlsonRF[x, y, z]//TraditionalForm

関数の恒等式と簡約  (4)

CarlsonRF，CarlsonRG，CarlsonRDを関連付ける等式：

Wolfram Language code: 2CarlsonRG[x, y, z] == z CarlsonRF[x, y, z] + (Sqrt[x]Sqrt[y]/Sqrt[z]) - (1/3)(z - x)(z - y)CarlsonRD[x, y, z]//FullSimplify

CarlsonRFは，オイラー・ポアソン(Euler–Poisson)の偏微分方程式を満足する：

Wolfram Language code: (x - y)Subscript[∂, x⁣y]CarlsonRF[x, y, z] + (1/2) Subscript[∂, y]CarlsonRF[x, y, z] - (1/2)Subscript[∂, x]CarlsonRF[x, y, z] == 0//FunctionExpand//FullSimplify

CarlsonRFは，オイラーの同次関係を満足する：

Wolfram Language code: x Subscript[∂, x]CarlsonRF[x, y, z] + y Subscript[∂, y]CarlsonRF[x, y, z] + z Subscript[∂, z]CarlsonRF[x, y, z] == -(1/2)CarlsonRF[x, y, z]//FunctionExpand//FullSimplify

CarlsonRFが満足する偏微分方程式：

Wolfram Language code: Subscript[∂, x]CarlsonRF[x, y, z] + Subscript[∂, y]CarlsonRF[x, y, z] + Subscript[∂, z]CarlsonRF[x, y, z] == -(1/2Sqrt[x]Sqrt[y]Sqrt[z])//FunctionExpand//FullSimplify

アプリケーション  (3)

地球の経線に沿った距離：

Wolfram Language code: With[{a = UnitConvert[GeodesyData["ITRF00", "SemimajorAxis"], $UnitSystem], e = GeodesyData["ITRF00", "Eccentricity"], ϕ = 29°}, a(1 - e^2)(Sin[ϕ]CarlsonRF[Cos[ϕ]^2, 1 - e^2Sin[ϕ]^2, 1] + (e^2/3)Sin[ϕ]^3CarlsonRD[Cos[ϕ]^2, 1 - e^2Sin[ϕ]^2, 1])]

GeoDistanceの結果と比較する：

Wolfram Language code: GeoDistance[GeoPosition[{0, 0}], GeoPosition[{29, 0}]]

正規分布と相対的なReciprocal Square Root of a Quadratic Form（二次形式の平方根の逆数）の期待値：

Wolfram Language code: MatrixForm[mat = HilbertMatrix[3]]
Wolfram Language code: NExpectation[(Sqrt[2]/Sqrt[{u, v, w}.mat.{u, v, w}]), {u, v, w}ProductDistribution[{NormalDistribution[], 3}], Method -> "MonteCarlo"]//Quiet

CarlsonRFによる閉じた形の結果と比較する：

Wolfram Language code: N[(Gamma[(3 - 1/2)]/Gamma[(3/2)])(CarlsonRF@@Eigenvalues[mat]), 25]

EllipticLogをCarlsonRFによって表す：

Wolfram Language code: With[{x = 1, a = 2, b = 6}, N[{-CarlsonRF[x, x + (a + Sqrt[a^2 - 4b]/2), x + (2b/a + Sqrt[a^2 - 4b])], EllipticLog[{x, Sqrt[x^3 + a x^2 + b x]}, {a, b}]}, 25]]

特性と関係  (1)

CarlsonRFはその引数を並べ替えても変わらない：

Wolfram Language code: CarlsonRF[x, y, z] == CarlsonRF[z, x, y]
Wolfram Research (2021), CarlsonRF, Wolfram言語関数， https://reference.wolfram.com/language/ref/CarlsonRF.html （2023年に更新）.

テキスト

Wolfram Research (2021), CarlsonRF, Wolfram言語関数， https://reference.wolfram.com/language/ref/CarlsonRF.html （2023年に更新）.

CMS

Wolfram Language. 2021. "CarlsonRF." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/CarlsonRF.html.

APA

Wolfram Language. (2021). CarlsonRF. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CarlsonRF.html

BibTeX

@misc{reference.wolfram_2026_carlsonrf, author="Wolfram Research", title="{CarlsonRF}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CarlsonRF.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_carlsonrf, organization={Wolfram Research}, title={CarlsonRF}, year={2023}, url={https://reference.wolfram.com/language/ref/CarlsonRF.html}, note=[Accessed: 10-September-2026]}