WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Cases[{e1,e2,…},pattern]

パターンにマッチする要素 eiをリストにして返す．

Cases[{e1,…},patternrhs]

パターンにマッチし，要素 eiに対応する rhs の値をリストにして返す．

Cases[expr,pattern,levelspec]

levelspec によって指定され，パターンにマッチするレベルにある式 expr のすべての部分をリストにして返す．

Cases[expr,patternrhs,levelspec]

パターンにマッチする rhs の値を返す．

Cases[expr,pattern,levelspec,n]

expr の中でパターンにマッチする最初の n 個の部分を返す．

Cases[pattern]

式に適用可能なCasesの演算子形を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Heads  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連するワークフロー
関連リンク
履歴
引用書式

Cases

Cases[{e1,e2,…},pattern]

パターンにマッチする要素 eiをリストにして返す．

Cases[{e1,…},patternrhs]

パターンにマッチし，要素 eiに対応する rhs の値をリストにして返す．

Cases[expr,pattern,levelspec]

levelspec によって指定され，パターンにマッチするレベルにある式 expr のすべての部分をリストにして返す．

Cases[expr,patternrhs,levelspec]

パターンにマッチする rhs の値を返す．

Cases[expr,pattern,levelspec,n]

expr の中でパターンにマッチする最初の n 個の部分を返す．

Cases[pattern]

式に適用可能なCasesの演算子形を表す．

詳細とオプション

  • Casesの第1引数の頭部がListである必要はない．
  • Associationに用いられた場合，Casesは要素をその値に応じて選び出す．
  • Cases[expr,pattern:>rhs]はパターンが見付かったときにだけ rhs を評価する．
  • Cases[pattern][list]はCases[list,pattern]に等しい．
  • Casesは標準的なレベル指定を使用する．
  • nレベル1からレベル n まで
    Infinityレベル1からInfinityまで
    {n}レベル n のみ
    {n1,n2}レベル n1からレベル n2まで
  • Casesにおける levelspec のデフォルト値は{1}である．
  • 正のレベル n は，n 個の指標で指定される expr のすべての部分からなる．
  • 負のレベル-n は，深度 n の expr のすべての部分からなる．
  • レベル-1は数，記号，それに下位区分を持たないその他のオブジェクトからなる．
  • レベル0は式全体に相当する．
  • オプション設定がHeads->Trueのとき，Casesは式の頭部および式の各部分を見る．
  • Casesは，深度優先の順序で，根の前に葉を訪れ，expr の部分を横断する．
  • Parallelize[Cases[expr,pattern]]あるいはParallelCases[expr,pattern]は，Cases[expr,pattern]をすべてのサブカーネルで並列に計算する． »

例題

すべて開く すべて閉じる

例  (4)

整数に明示的にマッチする場合を求める：

Wolfram Language code: Cases[{1, 1, f[a], 2, 3, y, f[8], 9, f[10]}, _Integer]

整数にはマッチしない場合を求める：

Wolfram Language code: Cases[{1, 1, f[a], 2, 3, y, f[8], 9, f[10]}, Except[_Integer]]

マッチしたそれぞれのf[x_]の中からxを返す：

Wolfram Language code: Cases[{1, 1, f[a], 2, 3, y, f[8], 9, f[10]}, f[x_] -> x]

Casesの演算子形を使う：

Wolfram Language code: Cases[_Integer][{1, 1, f[a], 2, 3, y, f[8], 9, f[10]}]

Associationから要素を取り出す：

Wolfram Language code: Cases[<|1 -> "a", 2 -> "b", 3 -> c, 4 -> d|>, _Symbol]

スコープ  (10)

2要素のリストの場合をすべて求める：

Wolfram Language code: Cases[{{1, 2}, {2}, {3, 4, 1}, {5, 4}, {3, 3}}, {_, _}]

すべての要素ペアの和を求める：

Wolfram Language code: Cases[{{1, 2}, {2}, {3, 4, 1}, {5, 4}, {3, 3}}, {a_, b_} -> a + b]

0ではない要素を抽出する：

Wolfram Language code: Cases[{1, 0, 2, 0, 3, 5, 6, 7, 0, 0, 0}, Except[0]]

整数の場合をレベル2まで抽出する：

Wolfram Language code: Cases[{{1, 4, a, 0}, {b, 3, 2, 2}, {c, c, 5, 5}}, _Integer, 2]

マッチする最初の3要素のみを返す：

Wolfram Language code: Cases[Sqrt[Range[100]], _Integer, {1}, 3]

明示的な要素が見付かってはじめて:>を使って評価するようにする：

Wolfram Language code: Cases[{f[{a, b}], f[{a}], g[{a}], f[{a, b, c, d}]}, f[x_] :> Length[x]]

任意レベルの可能なすべての部分式を求める：

Wolfram Language code: Cases[{1, 2, f[a, b]}, _, {0, Infinity}]

式の頭部を含む任意レベルの可能なすべての部分式を求める：

Wolfram Language code: Cases[{1, 2, f[a, b]}, _, {0, Infinity}, Heads -> True]

ネストした連想から要素を取り出す：

Wolfram Language code: Cases[<|1 -> c, 2 -> <|3 -> 1, a -> b|>|>, _Symbol, Infinity]

Associationにマッチする要素をListから取り出す：

Wolfram Language code: Cases[{<|a -> 1|>, <|b -> 2|>}, <|a -> _|>]

マッチする各Associationのキーを求める：

Wolfram Language code: Cases[{<|a -> 1|>, <|b -> 2|>, <|c -> 1|>}, <|x_ -> 1|> -> x]

リスト中の各連想からキーのペアを取り出す：

Wolfram Language code: Cases[{<|x -> 1, z -> 1|>, <|x -> 1, y -> 2|>}, <|a_ -> _, b_ -> _|> :> {a, b}]

条件を満たすキーがある連想を求める：

Wolfram Language code: Cases[{<|1 -> x|>, <|2 -> x|>}, <|a_ /; EvenQ[a] -> _|>]
Wolfram Language code: Cases[{<|1 -> x|>, <|2 -> x|>}, <|a_ -> _|> /; EvenQ[a]]

オプション  (1)

Heads  (1)

式の要素の中の記号を求める：

Wolfram Language code: Cases[{a, 5, π}, _Symbol]

検索に式の頭部も含める：

Wolfram Language code: Cases[{a, 5, π}, _Symbol, Heads -> True]

特性と関係  (2)

Countは，Casesが与える結果の長さを返す：

Wolfram Language code: Length[Cases[{1, "f", g, "h", "7"}, _ ? StringQ]]
Wolfram Language code: Count[{1, "f", g, "h", "7"}, _ ? StringQ]

Casesを並列に計算する：

Wolfram Language code: Parallelize[Cases[Range[100], _ ? PrimeQ]]

考えられる問題  (1)

規則ではマッチする要素が右辺に変換される：

Wolfram Language code: Cases[{1, b -> Automatic, c -> 3}, _ -> Automatic]

HoldPatternを使って規則それ自身をパターンとして扱う：

Wolfram Language code: Cases[{1, b -> Automatic, c -> 3}, HoldPattern[_ -> Automatic]]
Wolfram Research (1988), Cases, Wolfram言語関数， https://reference.wolfram.com/language/ref/Cases.html （2014年に更新）.

テキスト

Wolfram Research (1988), Cases, Wolfram言語関数， https://reference.wolfram.com/language/ref/Cases.html （2014年に更新）.

CMS

Wolfram Language. 1988. "Cases." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/Cases.html.

APA

Wolfram Language. (1988). Cases. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Cases.html

BibTeX

@misc{reference.wolfram_2026_cases, author="Wolfram Research", title="{Cases}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Cases.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_cases, organization={Wolfram Research}, title={Cases}, year={2014}, url={https://reference.wolfram.com/language/ref/Cases.html}, note=[Accessed: 10-August-2026]}