WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Catch[expr]

式 expr の評価において発生したThrowの第1引数を返す．

Catch[expr,form]

form を tag に照合させる最初のThrow[value,tag]の呼出しにおける value を返す．

Catch[expr,form,f]

f[value,tag]を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Catch

Catch[expr]

式 expr の評価において発生したThrowの第1引数を返す．

Catch[expr,form]

form を tag に照合させる最初のThrow[value,tag]の呼出しにおける value を返す．

Catch[expr,form,f]

f[value,tag]を返す．

詳細

  • 評価中にThrowが発生しない場合，Catch[expr,…]は，expr の値を返す．
  • form にはどんな式でも指定可能であるが，よく使われるのはパターンである．
  • Throw[value,tag]では，form との比較が行われるたびに tag の評価が行われる．

例題

すべて開く すべて閉じる

例  (3)

Throwが評価され次第囲み込んでいるCatchに退避する：

Wolfram Language code: Catch[a;b;Throw[c];d;e]

「例外処理を実行する」ことができる関数を定義する：

Wolfram Language code: f[x_] := If[x > 10, Throw[overflow], x!]

Catchの結果はThrowが投げた（実行した）ものである：

Wolfram Language code: Catch[f[2] + f[11]]
Wolfram Language code: Catch[f[2] + f[3]]

Throwを使って基準が満たされた場合にループから退避する：

Wolfram Language code: Catch[Do[If[i! > 10 ^ 10, Throw[i]], {i, 100}]]

スコープ  (5)

Catchは基本的にどんな関数の中からでもThrowをキャッチできる：

Wolfram Language code: Catch[If[# < 0, Throw[#]]& /@ {1, 2, 0, -1, 5, 6}]
Wolfram Language code: Catch[{a, Throw[b], c}]
Wolfram Language code: Catch[a ^ 2 + b ^ 2 + c ^ 2 /. b :> Throw[bbb]]

最も近くで囲み込んでいるCatchがThrowをキャッチする：

Wolfram Language code: Catch[{Catch[{a, Throw[b], c}], d, e}]

Catchは最初に評価されたThrowを拾う：

Wolfram Language code: Catch[{Throw[a], Throw[b], Throw[c]}]
Wolfram Language code: Catch[Throw /@ {a, b, c}]

Throwは文字通りCatchの内側で起る必要はない：

Wolfram Language code: f[x_] := (If[x < 0, Throw["negative"]];Sqrt[x])
Wolfram Language code: Catch[Sum[f[i], {i, 5, -5, -1}]]

さまざまな例外を投げる（実行する）ことができる関数：

Wolfram Language code: f[x_] := Which[ x < 0, Throw[x, error[negative]], x == 0, Throw[x, error[zero]], True, 1 / Sqrt[x]]

考えられる例外のためのハンドラ：

Wolfram Language code: ff[x_] := Catch[f[x], error[_], Function[{value, tag}, tag /. {error[negative] :> Indeterminate, error[zero] :> Infinity, _ :> Throw[value, tag]}]]
Wolfram Language code: ff /@ {-1, 0, 1}

一般化と拡張  (3)

タグuが付いたThrowをキャッチする：

Wolfram Language code: Catch[Throw[a, u], u]

内側のCatchがThrowをキャッチする：

Wolfram Language code: Catch[f[Catch[Throw[a, u], u]], v]

外側のCatchがThrowをキャッチする：

Wolfram Language code: Catch[f[Catch[Throw[a, u], v]], u]

タグは局所的にしておく：

Wolfram Language code: Module[{u}, Catch[Throw[a, u], u]]

アプリケーション  (3)

1010の後の最初の素数を求める：

Wolfram Language code: Catch[Do[If[PrimeQ[i], Throw[i]], {i, 10 ^ 10, 10 ^ 10 + 1000}]]

19を法とした1と等価になる17の最初のベキを求める：

Wolfram Language code: Catch[Do[If[Mod[17 ^ i, 19] == 1, Throw[i]], {i, 19}]]

反復が大きくなり過ぎる場合は停止する：

Wolfram Language code: NestList[# ^ 2 + 1&, 2, 6]
Wolfram Language code: Catch[NestList[If[# > 1000, Throw[#], # ^ 2 + 1]&, 2, 6]]

特性と関係  (1)

メッセージが生成された場合にはCheckを使って例外を投げる（実行する）：

Wolfram Language code: Catch[2 + Check[1 / (1 + 1 / 0), Throw[error]]]
Wolfram Language code: Catch[2 + Check[1 / (1 + 1 / 2), Throw[error]]]
Wolfram Research (1988), Catch, Wolfram言語関数， https://reference.wolfram.com/language/ref/Catch.html （1996年に更新）.

テキスト

Wolfram Research (1988), Catch, Wolfram言語関数， https://reference.wolfram.com/language/ref/Catch.html （1996年に更新）.

CMS

Wolfram Language. 1988. "Catch." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 1996. https://reference.wolfram.com/language/ref/Catch.html.

APA

Wolfram Language. (1988). Catch. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Catch.html

BibTeX

@misc{reference.wolfram_2026_catch, author="Wolfram Research", title="{Catch}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/Catch.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_catch, organization={Wolfram Research}, title={Catch}, year={1996}, url={https://reference.wolfram.com/language/ref/Catch.html}, note=[Accessed: 12-August-2026]}