WOLFRAM

Wolfram 语言与系统参考资料中心

Catch[expr]

返回在运行 expr 时产生的第一个 Throw 的参数.

Catch[expr,form]

返回 form 匹配 tag 的第一个 Throw[value,tag] 中的 value.

Catch[expr,form,f]

返回 f[value,tag].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
推广和延伸  
应用  
属性和关系  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Catch

Catch[expr]

返回在运行 expr 时产生的第一个 Throw 的参数.

Catch[expr,form]

返回 form 匹配 tag 的第一个 Throw[value,tag] 中的 value.

Catch[expr,form,f]

返回 f[value,tag].

更多信息

  • 如果在运行时不生成 Throw，则 Catch[expr,…] 总是返回 expr 的值.
  • form 可以是任何表达式，而且经常是一个模式.
  • Throw[value,tag] 中的 tag 在每次与 form 比较时重新运算.

范例

打开所有单元 关闭所有单元

基本范例  (3)

一运行 Throw ，就退出最接近的 Catch：

Wolfram Language code: Catch[a;b;Throw[c];d;e]

定义一个可以“抛出异常”的函数：

Wolfram Language code: f[x_] := If[x > 10, Throw[overflow], x!]

Catch 的结果正是被 Throw 抛出的：

Wolfram Language code: Catch[f[2] + f[11]]
Wolfram Language code: Catch[f[2] + f[3]]

当判别式被满足时，利用 Throw 退出循环：

Wolfram Language code: Catch[Do[If[i! > 10 ^ 10, Throw[i]], {i, 100}]]

范围  (5)

Catch 可以从任何函数内捕捉一个 Throw ：

Wolfram Language code: Catch[If[# < 0, Throw[#]]& /@ {1, 2, 0, -1, 5, 6}]
Wolfram Language code: Catch[{a, Throw[b], c}]
Wolfram Language code: Catch[a ^ 2 + b ^ 2 + c ^ 2 /. b :> Throw[bbb]]

最近的 Catch 捕捉 Throw：

Wolfram Language code: Catch[{Catch[{a, Throw[b], c}], d, e}]

Catch 挑选出第一个被运行的 Throw ：

Wolfram Language code: Catch[{Throw[a], Throw[b], Throw[c]}]
Wolfram Language code: Catch[Throw /@ {a, b, c}]

Throw 不需要词法式地出现于 Catch 内部：

Wolfram Language code: f[x_] := (If[x < 0, Throw["negative"]];Sqrt[x])
Wolfram Language code: Catch[Sum[f[i], {i, 5, -5, -1}]]

一个可以抛出若干不同的异常的函数：

Wolfram Language code: f[x_] := Which[ x < 0, Throw[x, error[negative]], x == 0, Throw[x, error[zero]], True, 1 / Sqrt[x]]

一个用于可能的异常的处理程序：

Wolfram Language code: ff[x_] := Catch[f[x], error[_], Function[{value, tag}, tag /. {error[negative] :> Indeterminate, error[zero] :> Infinity, _ :> Throw[value, tag]}]]
Wolfram Language code: ff /@ {-1, 0, 1}

推广和延伸  (3)

捕捉标记为 u 的 Throw：

Wolfram Language code: Catch[Throw[a, u], u]

内层的 Catch 捕捉到 Throw：

Wolfram Language code: Catch[f[Catch[Throw[a, u], u]], v]

外层的 Catch 捕捉到 Throw：

Wolfram Language code: Catch[f[Catch[Throw[a, u], v]], u]

使标记保持在局部：

Wolfram Language code: Module[{u}, Catch[Throw[a, u], u]]

应用  (3)

给出 1010 以后的第一个质数：

Wolfram Language code: Catch[Do[If[PrimeQ[i], Throw[i]], {i, 10 ^ 10, 10 ^ 10 + 1000}]]

给出模除19等于1的17的第一个幂：

Wolfram Language code: Catch[Do[If[Mod[17 ^ i, 19] == 1, Throw[i]], {i, 19}]]

如果一个迭代变得太大，则停止运算：

Wolfram Language code: NestList[# ^ 2 + 1&, 2, 6]
Wolfram Language code: Catch[NestList[If[# > 1000, Throw[#], # ^ 2 + 1]&, 2, 6]]

属性和关系  (1)

如果产生信息，利用 Check 抛出一个异常：

Wolfram Language code: Catch[2 + Check[1 / (1 + 1 / 0), Throw[error]]]
Wolfram Language code: Catch[2 + Check[1 / (1 + 1 / 2), Throw[error]]]
Wolfram Research (1988)，Catch，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Catch.html （更新于 1996 年）.

文本

Wolfram Research (1988)，Catch，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Catch.html （更新于 1996 年）.

CMS

Wolfram 语言. 1988. "Catch." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 1996. https://reference.wolfram.com/language/ref/Catch.html.

APA

Wolfram 语言. (1988). Catch. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Catch.html 年

BibTeX

@misc{reference.wolfram_2026_catch, author="Wolfram Research", title="{Catch}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/Catch.html}", note=[Accessed: 19-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_catch, organization={Wolfram Research}, title={Catch}, year={1996}, url={https://reference.wolfram.com/language/ref/Catch.html}, note=[Accessed: 19-August-2026]}