Wolfram 语言与系统参考资料中心

Chebyshev2FilterModel

Chebyshev2FilterModel[n]

创建阶数为 n 的第二类切比雪夫低通滤波器.

Chebyshev2FilterModel[{n,ω_c}]

使用截止频率 ω_c.

Chebyshev2FilterModel[{"type",spec}]

使用完整滤波器规范 {"type",spec}.

Chebyshev2FilterModel[{"type",spec},var]

以变量 var 表示模型.

范例

打开所有单元关闭所有单元

基本范例 (2)

三阶切比雪夫 2 型滤波器模型：

Wolfram Language code: tf = Chebyshev2FilterModel[3]

用变量表示滤波器模型：

Wolfram Language code: tf = Chebyshev2FilterModel[3, s]

模拟滤波器的波特图：

Wolfram Language code: BodePlot[tf, GridLines -> Automatic, PlotLayout -> "Magnitude"]

根据详细指标设计低通切比雪夫 II 型滤波器：

Wolfram Language code: tf = Chebyshev2FilterModel[{"Lowpass", {1., 2.}, {1., 20.}}, s]//Chop

滤波器的幅频响应展示出理想的滤波器特性：

Wolfram Language code:

Plot[Abs[tf[I * ω]], {ω, 0, 3}, PlotRange -> All, Epilog -> {Pink, Dashed, Line[{{0, 0.89}, {1, 0.89}, {1, 0.1}}], Line[{{2., 0.89}, {2., 0.1}, {3., 0.1}}]}]

范围 (5)

二阶低通滤波器的符号表示：

Wolfram Language code: Chebyshev2FilterModel[{2, ω}, s]//N//Chop

提取模型的计算：

Wolfram Language code: Chebyshev2FilterModel[{2, 1}, s]

用 24 位精度计算模型：

Wolfram Language code: Chebyshev2FilterModel[{2, N[1, 24]}, s]

设计第二类切比雪夫高通滤波器：

Wolfram Language code: BodePlot[Chebyshev2FilterModel[{"Highpass", {1., 2.}, {20., 1.}}], GridLines -> Automatic, PlotLayout -> "Magnitude"]

设计第二类切比雪夫带通滤波器：

Wolfram Language code:

BodePlot[Chebyshev2FilterModel[{"Bandpass", {1., 10., 100., 1000.}, {20., 1.}}], GridLines -> Automatic, PlotLayout -> "Magnitude"]

设计第二类切比雪夫带阻滤波器：

Wolfram Language code:

BodePlot[Chebyshev2FilterModel[{"Bandstop", {1., 10., 100., 1000.}, {1, 20}}], GridLines -> Automatic, PlotLayout -> "Magnitude"]

应用 (5)

设计第二类切比雪夫低通滤波器：

Wolfram Language code: tf = Chebyshev2FilterModel[{"Lowpass", {1., 2.}, {1, 40}}, s];

滤除正弦信号中的高频噪声：：

Wolfram Language code:

ω = 1 / 5;input = (Sin[ω t] + 1 / 2 Sin[25ω t]) UnitStep[t];
response1 = OutputResponse[tf, input, {t, 0, 100}];

第二类切比雪夫滤波器把响应的相位平移了 Arg[tf[ω ]]，其中 ω 是输入正弦波的频率：

Wolfram Language code: Plot[{input, response1}, {t, 20, 100}]

对相位平移进行校正：

Wolfram Language code:

delay = Arg[tf[I ω]] / ω//First//First;
Plot[Evaluate[Flatten[{input, response1 /. t -> (t - delay)}]], {t, 20, 100}]

根据低通原型设计第二类切比雪夫高通滤波器：

Wolfram Language code: tf2 = TransferFunctionTransform[1 / #&, tf];

滤除输入中的低频正弦波：

Wolfram Language code: Plot[Evaluate[Flatten[{input, OutputResponse[tf2, input, {t, 0, 100}]}]], {t, 20, 100}]

用 Chebyshev 2 型近似设计一个数字低通滤波器，满足以下通带和阻带频率以及衰减要求：

Wolfram Language code:

Subscript[ω, p] = 0.4π;Subscript[ω, s] = 0.6π;
Subscript[a, p] = 1;Subscript[a, s] = 20;

假定采样周期为 1，获取等价模拟频率：

Wolfram Language code: {Subscript[Ω, p] = 2 Tan[(0.4π/2)], Subscript[Ω, s] = 2 Tan[(0.6π/2)]}

计算模拟 Chebyshev 2 型转换函数：

Wolfram Language code: tf = Chebyshev2FilterModel[{"Lowpass", {Subscript[Ω, p], Subscript[Ω, s]}, {Subscript[a, p], Subscript[a, s]}}, s]

转换成离散时间模型：

Wolfram Language code: dtf = ToDiscreteTimeModel[tf, 1, z]//Chop

绘制幅值：

Wolfram Language code:

BodePlot[dtf, {0.1 π, π}, PlotLayout -> "Magnitude", GridLines -> {{Subscript[ω, p], Subscript[ω, s]}, {10^-Subscript[a, p] / 20, 10^-Subscript[a, s] / 20}}, ScalingFunctions -> {"Linear", "Absolute"}, PlotRange -> All]

创建一个长度为 21 的 FIR 滤波器，用于近似离散时间切比雪夫 2 型 IIR 滤波器：

Wolfram Language code: OutputResponse[dtf, KroneckerDelta[n], {n, 0, 20}]//Chop

绘制 FIR 滤波器：

Wolfram Language code: ListPlot[%, PlotRange -> All, Filling -> 0]

用切比雪夫滤波器的 FIR 近似平滑金融数据：

Wolfram Language code:

data = Transpose[FinancialData["GE", {"Jan. 1, 2012", "Jan. 1, 2013"}]["Path"]];
fir = OutputResponse[ToDiscreteTimeModel[Chebyshev2FilterModel[{3, 0.5}], 1], KroneckerDelta[n], {n, 0, 40}]//Chop//Flatten;
DateListPlot[{Transpose[data], Transpose[{data[[1]], -ListConvolve[fir, data[[2]], 4]}]}, PlotRange -> All, PlotLegends -> {"original", "smoothed"}]

使用第二类切比雪夫低通滤波器对图像进行滤波：

Wolfram Language code:

h = ToDiscreteTimeModel[Chebyshev2FilterModel[3], 1];
RecurrenceFilter[h, [image]]

使用第二类切比雪夫高通滤波器对图像进行滤波：

Wolfram Language code:

h = ToDiscreteTimeModel[Chebyshev2FilterModel[{"Highpass", {.5, 1}, {20, 1}}], 1];
RecurrenceFilter[h, [image]]

属性和关系 (5)

比较第一类和第二类切比雪夫低通滤波器：

Wolfram Language code: t1 = Chebyshev1FilterModel[{"Lowpass", {1., 2.}, {1., 20.}}]

Wolfram Language code: t2 = Chebyshev2FilterModel[{"Lowpass", {1., 2.}, {1., 20.}}]

Wolfram Language code:

Plot[{Abs[t1[I * ω]], Abs[t2[I * ω]]}, {ω, 0, 3}, PlotRange -> All, Epilog -> {Pink, Dashed, Line[{{0, 0.89}, {1, 0.89}, {1, 0.1}}], Line[{{2., 0.89}, {2., 0.1}, {3., 0.1}}]}]

提取第二类切比雪夫多项式的次数：

Wolfram Language code: SystemsModelOrder[StateSpaceModel[Chebyshev2FilterModel[{"Lowpass", {1., 2.}, {1., 20.}}]]]

求 Chebyshev 2 型滤波器的极点和零点：

Wolfram Language code: tfm = Chebyshev2FilterModel[11];

Wolfram Language code: {poles, zeros} = Through[{TransferFunctionPoles, TransferFunctionZeros}[tfm]]

Plot poles and zeros of the Chebyshev filter:

Wolfram Language code: PoleZeroPlot[tfm]

实现低通数字 Chebyshev 2 型滤波器：

Wolfram Language code: dtfm = ToDiscreteTimeModel[Chebyshev2FilterModel[11], 1]

绘制数字 Chebyshev 2 型滤波器的极点和零点：

Wolfram Language code: PoleZeroPlot[dtfm]

把低通滤波器转化为高通滤波器：

Wolfram Language code:

lo = Chebyshev2FilterModel[3];
hi = TransferFunctionTransform[(1 / #&), lo]

Wolfram Language code: Plot[{Abs[lo[I w]], Abs[hi[I w]]}, {w, 0, 3}, PlotRange -> All]

可能存在的问题 (1)

由于无法算出阶数，所以不能返回有完整说明的符号式滤波器：

Wolfram Language code: Chebyshev2FilterModel[{"Lowpass", {ωp, ωs}, {ap, as}}]

Top

		{"Lowpass",{ω_p,ω_s},{a_p,a_s}}	使用通带和阻带的频率和衰减来构建低通滤波器
		{"Highpass",{ω_s,ω_p},{a_s,a_p}}	高通滤波器
		{"Bandpass",{ω_s1,ω_p1,ω_p2,ω_s2},{a_s,a_p}}	带通滤波器
		{"Bandstop",{ω_p1,ω_s1,ω_s2,ω_p2},{a_p,a_s}}	带阻滤波器

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Chebyshev2FilterModel

更多信息

范例

基本范例 (2)

范围 (5)

应用 (5)

属性和关系 (5)

可能存在的问题 (1)

文本

CMS

APA

BibTeX

BibLaTeX

Chebyshev2FilterModel

更多信息

范例

基本范例 (2)

范围 (5)

应用 (5)

属性和关系 (5)

可能存在的问题 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX