CliffordAlgebra

CliffordAlgebra[{pvars,nvars,zvars}]

平方するとになる生成器 pvars，2乗するとになる nvars，2乗するとになる zvars を持つクリフォード(Clifford)代数を与える．

CliffordAlgebra[{pvars,nvars,zvars},alg]

非可換代数 alg から演算名と単項式順序の設定を取得する．

詳細

CliffordAlgebraは，クリフォード代数を表すNonCommutativeAlgebraオブジェクトを与える．
CliffordAlgebra[{{x₁,…,x_p},{x_p+1,…,x_p+q},{x_p+q+1,…,x_p+q+r}}]は，生成元{x₁,…,x_p+q+r}と関係で与えられるユニタリ代数である一般化されたクリフォード代数を表すNonCommutativeAlgebraオブジェクトを返す．ただし，のとき，のとき，のとき，のときである．
零因子がないとき，つまり zvars が空のとき，クリフォード代数を表すためにとという表記がよく使われる．
CliffordAlgebra[{pvars,nvars}]はCliffordAlgebra[{pvars,nvars,{}}]に等しい．
CliffordAlgebra[{pvars}]はCliffordAlgebra[{pvars,{},{}}]に等しい．
クリフォード代数の元はすべて，の線形結合として正準表現できる．ただし，である．NonCommutativeExpandはクリフォード代数の元の正準表現を計算する．

例題

すべて開くすべて閉じる

例 (2)

一般化されたクリフォード代数を作成する：

Wolfram Language code: alg = CliffordAlgebra[{{x}, {y}, {z}}]

代数の元の正準形式を計算する：

Wolfram Language code: NonCommutativeExpand[(x + 2y + 3z)**(4x + 5y + 6z), alg]

クリフォード代数を作成する：

Wolfram Language code: alg = CliffordAlgebra[{{e1, e2}, {e3, e4}}]

代数の左イデアルのグレブナー基底を計算する：

Wolfram Language code: NonCommutativeGroebnerBasis[{e1**e2 - e3**e4}, alg, Left]

スコープ (1)

デフォルトではない乗算演算（1と0）を指定する：

Wolfram Language code:

alg = CliffordAlgebra[{{i}, {j}}, <|"Multiplication" -> Dot, "Unity" -> SymbolicIdentityArray[2], "Zero" -> SymbolicZerosArray[2]|>]

Wolfram Language code: NonCommutativeExpand[(i - j).(i - j), alg]

アプリケーション (3)

クリフォード代数は四元数と同型である：

Wolfram Language code: alg = CliffordAlgebra[{{}, {e1, e2}}]

Wolfram Language code: NonCommutativeExpand[GeneralizedPower[NonCommutativeMultiply, (1 + 2 e1 + 3 e2 + 4 e1**e2), 5], alg]

四元数パッケージを使って同じ計算を行う：

Wolfram Language code: <<Quaternions`

Wolfram Language code: Quaternion[1, 2, 3, 4] ^ 5

クリフォード代数はしばしばディラック代数と呼ばれ，物理学と数学，特に相対論的場の理論に貴重な応用を持つ．この代数は．行列代数としての多くの表現を持つが，その中でも最もよく知られたものはガンマ行列またはディラック行列を含む．まず，抽象代数を定義する：

Wolfram Language code: dirac = CliffordAlgebra[{{Γ^0}, {Γ^1, Γ^2, Γ^3}}]

行列を母関数の反交換子の半分として定義する．これは時間的正ミンコフスキー計量である点に注意のこと：

Wolfram Language code:

Table[Subscript[η, μ⁣ν] = (1/2)NonCommutativeExpand[Anticommutator[Γ^μ, Γ^ν, dirac], dirac], {μ, 0, 3}, {ν, 0, 3}]

単純だが重要な恒等式は $sum_(mu=0)^3eta_(mu⁣mu)TemplateBox[{Gamma, mu}, Superscript]TemplateBox[{Gamma, mu}, Superscript]=4$ を与える：

Wolfram Language code: NonCommutativeExpand[Underoverscript[∑, μ = 0, 3]Subscript[η, μ⁣μ]Γ^μ**Γ^μ, dirac]

$sum_(mu=0)^3eta_(mu⁣mu)TemplateBox[{Gamma, mu}, Superscript]TemplateBox[{Gamma, nu}, Superscript]TemplateBox[{Gamma, mu}, Superscript]=-2TemplateBox[{Gamma, nu}, Superscript]$ は別の恒等式である：

Wolfram Language code: Table[NonCommutativeExpand[Underoverscript[∑, μ = 0, 3]Subscript[η, μ⁣μ]Γ^μ**Γ^ν**Γ^μ, dirac], {ν, 0, 3}]

反変ガンマ行列を単位行列とパウリ行列でとして定義する：

Wolfram Language code: γ^0 = BlockDiagonalMatrix[{IdentityMatrix[2], -IdentityMatrix[2]}];

，ただし，はKroneckerProductを意味する：

Wolfram Language code: Table[γ^i = I KroneckerProduct[PauliMatrix[2], PauliMatrix[i]], {i, 3}];

ガンマ行列を書き出す：

Wolfram Language code: Table[MatrixForm[γ^μ], {μ, 0, 3}]

定義関係 $TemplateBox[{{gamma, ^, mu}, {gamma, ^, nu}}, Anticommutator]=2 eta_(mu⁣nu) I$ を確認する．これは具体的な行列代数であるため，乗算はDot（NonCommutativeMultiplyではない）になり，単位元は単位行列（ではない）になる：

Wolfram Language code: Table[Anticommutator[γ^μ, γ^ν, Dot] == 2Subscript[η, μ⁣ν] IdentityMatrix[4], {μ, 0, 3}, {ν, 0, 3}]

$gamma^mugamma_mu=sum_(mu=0)^3eta_(mu⁣mu)TemplateBox[{gamma, mu}, Superscript]TemplateBox[{gamma, mu}, Superscript]=4 I$ であることを確認する：

Wolfram Language code: Underoverscript[∑, μ = 0, 3]Subscript[η, μ⁣μ]γ^μ.γ^μ

最後に， $gamma^mugamma^nugamma_mu=sum_(mu=0)^3eta_(mu⁣mu)TemplateBox[{gamma, mu}, Superscript]gamma^nuTemplateBox[{gamma, mu}, Superscript]=- 2gamma^nu$ であることを確認する：

Wolfram Language code: Table[Underoverscript[∑, μ = 0, 3]Subscript[η, μ⁣μ]γ^μ.γ^ν.γ^μ == -2γ^ν, {ν, 0, 3}]

以下の例では，上の例で導入したディラック代数の次元性を確立し，ディラック行列を用いた表現がなぜ特別なのかを示す．まず，前と同じようにディラック代数を定義するが，より見栄えのよい演算子を使う：

Wolfram Language code: dirac = CliffordAlgebra[{{Γ^0}, {Γ^1, Γ^2, Γ^3}}, <|"Multiplication" -> CenterDot|>]

デフォルトで，Sortは一つのディラック項をそのような項の積の後ろに置く：

Wolfram Language code: Sort[{Γ^0, Γ^1·Γ^2}]

これは，CenterDotがアルファベット順でSuperscriptの（そしての）後ろになるからである：

Wolfram Language code: FullForm[Γ^0]

単一の項の後ろに積を置く順序関数を定義する：

Wolfram Language code:

order = Which[Head[#1] === CenterDot && Head[#2] === Superscript, -1, Head[#1] === Superscript && Head[#2] === CenterDot, 1, True, Order[#1, #2]]&;
Sort[{Γ^0, Γ^1·Γ^2}, order]

次数4までの母関数の積の一般的な線形結合を構築する．より多くの項を持つ任意の積はと等しい母関数の平方を含む：

Wolfram Language code:

lincomb = Table[Subscript[c, i], {i, 341}].Join[{1}, Table[Γ^μ, {μ, 0, 3}], Flatten@Table[Γ^μ·Γ^ν, {μ, 0, 3}, {ν, 0, 3}], Flatten@Table[Γ^μ·Γ^ν·Γ^ρ, {μ, 0, 3}, {ν, 0, 3}, {ρ, 0, 3}], Flatten@Table[Γ^μ·Γ^ν·Γ^ρ·Γ^σ, {μ, 0, 3}, {ν, 0, 3}, {ρ, 0, 3}, {σ, 0, 3}]];

NonCommutativeExpandを使って代数の式を簡約する：

Wolfram Language code: Short[lincomb = NonCommutativeExpand[lincomb, dirac], 5]

この線形結合には60の項がある：

Wolfram Language code: Length[lincomb]

しかし，見た目は誤解を招くことがある．多くの項は，生成元を2乗したため，単位ベクトルの倍数になっている．を含まない項をすべて削除し，単位ベクトル1に置き換える：

Wolfram Language code: Short[unitized = DeleteCases[lincomb, _ ? (FreeQ[Γ])] + 1]

このベクトルは16個の基底ベクトルを含むので，代数は16次元である：

Wolfram Language code: Length[unitized]

ベクトルと係数を分離し，ソートする．基底は増分インデックスを持つ生成元すべての積から構成される：

Wolfram Language code: Sort[List@@Replace[unitized, v_ ? (FreeQ[c]) _ :> v, {1}], order]

4つのガンマ行列を定義する．行列なので，それらは16次元のベクトル空間に存在し，ディラック代数を含む任意の行列代数で最低の次元性をもつことになる：

Wolfram Language code:

γ^0 = BlockDiagonalMatrix[{IdentityMatrix[2], -IdentityMatrix[2]}];
Table[γ^i = I KroneckerProduct[PauliMatrix[2], PauliMatrix[i]], {i, 3}];
Table[γ^μ//MatrixForm, {μ, 0, 3}]

対応する基底要素の一般的な線形結合を形成する：

Wolfram Language code:

Table[Subscript[a, i], {i, 16}].Join[{IdentityMatrix[4]}, Table[γ^μ, {μ, 0, 3}], Flatten[Table[If[μ < ν, γ^μ.γ^ν, Nothing], {μ, 0, 3}, {ν, 0, 3}], 1], Flatten[Table[If[μ < ν < ρ, γ^μ.γ^ν.γ^ρ, Nothing], {μ, 0, 3}, {ν, 0, 3}, {ρ, 0, 3}], 2], { Dot@@Table[γ^μ, {μ, 0, 3}]}]//MatrixForm

$sum_(i=1)^(16)a_i e_i=TemplateBox[{TemplateBox[{{4, ,, 4}}, ImplicitList]}, SymbolicZerosArray]$ の唯一の解はで，16個の行列は，予想通り，具体的な行列台数において線形独立であることを示している：

Wolfram Language code: Solve[% == ConstantArray[0, {4, 4}]]

特性と関係 (1)

CliffordAlgebraは，クリフォード代数の構造を持つNonCommutativeAlgebraを与える：

Wolfram Language code: CliffordAlgebra[{{x, y}, {z, t}, {}}]

Wolfram Language code: % === NonCommutativeAlgebra["Structure" -> {"Clifford", {{x, y}, {z, t}, {}}}]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

CliffordAlgebra

詳細

例題

例 (2)

スコープ (1)

アプリケーション (3)

特性と関係 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

CliffordAlgebra

詳細

例題

例 (2)

スコープ (1)

アプリケーション (3)

特性と関係 (1)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX