Wolfram 语言与系统参考资料中心

CliffordAlgebra

CliffordAlgebra[{pvars,nvars,zvars}]

给出具有生成元 pvars（其平方为）、nvars（其平方为）以及 zvars（其平方为）的克利福德代数.

CliffordAlgebra[{pvars,nvars,zvars},alg]

从非交换代数 alg 中继承运算名称和单项式顺序设置.

范例

打开所有单元关闭所有单元

基本范例 (2)

创建一个广义的克利福德代数 :

Wolfram Language code: alg = CliffordAlgebra[{{x}, {y}, {z}}]

计算代数中某个元素的标准形：

Wolfram Language code: NonCommutativeExpand[(x + 2y + 3z)**(4x + 5y + 6z), alg]

创建一个克利福德代数下标：

Wolfram Language code: alg = CliffordAlgebra[{{e1, e2}, {e3, e4}}]

计算该代数中一个左理想的 Gröbner 基：

Wolfram Language code: NonCommutativeGroebnerBasis[{e1**e2 - e3**e4}, alg, Left]

范围 (1)

指定非默认的乘法运算、单位元和零元：

Wolfram Language code:

alg = CliffordAlgebra[{{i}, {j}}, <|"Multiplication" -> Dot, "Unity" -> SymbolicIdentityArray[2], "Zero" -> SymbolicZerosArray[2]|>]

Wolfram Language code: NonCommutativeExpand[(i - j).(i - j), alg]

应用 (3)

克利福德代数与四元数同构：

Wolfram Language code: alg = CliffordAlgebra[{{}, {e1, e2}}]

Wolfram Language code: NonCommutativeExpand[GeneralizedPower[NonCommutativeMultiply, (1 + 2 e1 + 3 e2 + 4 e1**e2), 5], alg]

使用四元数包进行相同的计算：

Wolfram Language code: <<Quaternions`

Wolfram Language code: Quaternion[1, 2, 3, 4] ^ 5

克利福德代数通常被称为狄拉克代数，并在物理学和数学中具有重要应用，尤其是在相对论场论中. 该代数作为矩阵代数具有多种表示，其中最为人所熟知的是涉及伽马矩阵或狄拉克矩阵的表示. 首先，定义抽象代数：

Wolfram Language code: dirac = CliffordAlgebra[{{Γ^0}, {Γ^1, Γ^2, Γ^3}}]

将矩阵定义为生成元的反对易子的二分之一；注意它是时间样正的闵可夫斯基度量：

Wolfram Language code:

Table[Subscript[η, μ⁣ν] = (1/2)NonCommutativeExpand[Anticommutator[Γ^μ, Γ^ν, dirac], dirac], {μ, 0, 3}, {ν, 0, 3}]

一个简单但重要的恒等式给出 $sum_(mu=0)^3eta_(mu⁣mu)TemplateBox[{Gamma, mu}, Superscript]TemplateBox[{Gamma, mu}, Superscript]=4$ :

Wolfram Language code: NonCommutativeExpand[Underoverscript[∑, μ = 0, 3]Subscript[η, μ⁣μ]Γ^μ**Γ^μ, dirac]

另一个恒等式是 $sum_(mu=0)^3eta_(mu⁣mu)TemplateBox[{Gamma, mu}, Superscript]TemplateBox[{Gamma, nu}, Superscript]TemplateBox[{Gamma, mu}, Superscript]=-2TemplateBox[{Gamma, nu}, Superscript]$ ：

Wolfram Language code: Table[NonCommutativeExpand[Underoverscript[∑, μ = 0, 3]Subscript[η, μ⁣μ]Γ^μ**Γ^ν**Γ^μ, dirac], {ν, 0, 3}]

将逆变伽马矩阵用恒等矩阵以及泡利矩阵表示为 :

Wolfram Language code: γ^0 = BlockDiagonalMatrix[{IdentityMatrix[2], -IdentityMatrix[2]}];

并且，其中表示 KroneckerProduct:

Wolfram Language code: Table[γ^i = I KroneckerProduct[PauliMatrix[2], PauliMatrix[i]], {i, 3}];

写出伽玛矩阵：

Wolfram Language code: Table[MatrixForm[γ^μ], {μ, 0, 3}]

确认定义关系 $TemplateBox[{{gamma, ^, mu}, {gamma, ^, nu}}, Anticommutator]=2 eta_(mu⁣nu) I$ ；由于这是一个具体的矩阵代数，此处的乘法现在是 Dot（而不是 NonCommutativeMultiply），并且单位元是单位矩阵（而不是）：

Wolfram Language code: Table[Anticommutator[γ^μ, γ^ν, Dot] == 2Subscript[η, μ⁣ν] IdentityMatrix[4], {μ, 0, 3}, {ν, 0, 3}]

确认 $gamma^mugamma_mu=sum_(mu=0)^3eta_(mu⁣mu)TemplateBox[{gamma, mu}, Superscript]TemplateBox[{gamma, mu}, Superscript]=4 I$ ：

Wolfram Language code: Underoverscript[∑, μ = 0, 3]Subscript[η, μ⁣μ]γ^μ.γ^μ

最后，确认 $gamma^mugamma^nugamma_mu=sum_(mu=0)^3eta_(mu⁣mu)TemplateBox[{gamma, mu}, Superscript]gamma^nuTemplateBox[{gamma, mu}, Superscript]=- 2gamma^nu$ ：

Wolfram Language code: Table[Underoverscript[∑, μ = 0, 3]Subscript[η, μ⁣μ]γ^μ.γ^ν.γ^μ == -2γ^ν, {ν, 0, 3}]

本示例确立了前一个示例中引入的狄拉克代数的维数，并说明了为什么用狄拉克矩阵来表示是特殊的. 首先，像之前一样定义狄拉克代数，但使用一个外观更美观的算符：

Wolfram Language code: dirac = CliffordAlgebra[{{Γ^0}, {Γ^1, Γ^2, Γ^3}}, <|"Multiplication" -> CenterDot|>]

默认情况下，Sort 会将单个狄拉克项放在此类项的乘积之后：

Wolfram Language code: Sort[{Γ^0, Γ^1·Γ^2}]

这是因为 CenterDot 在字母顺序上排在 Superscript 之前（而且同样也排在之前）：

Wolfram Language code: FullForm[Γ^0]

定义一个排序函数，根据单个术语对产品进行排序：

Wolfram Language code:

order = Which[Head[#1] === CenterDot && Head[#2] === Superscript, -1, Head[#1] === Superscript && Head[#2] === CenterDot, 1, True, Order[#1, #2]]&;
Sort[{Γ^0, Γ^1·Γ^2}, order]

构造一个由生成元的乘积组成、次数不超过 4 的一般线性组合；任何包含更多因子的乘积都会包含生成元的平方，而其平方等于 :

Wolfram Language code:

lincomb = Table[Subscript[c, i], {i, 341}].Join[{1}, Table[Γ^μ, {μ, 0, 3}], Flatten@Table[Γ^μ·Γ^ν, {μ, 0, 3}, {ν, 0, 3}], Flatten@Table[Γ^μ·Γ^ν·Γ^ρ, {μ, 0, 3}, {ν, 0, 3}, {ρ, 0, 3}], Flatten@Table[Γ^μ·Γ^ν·Γ^ρ·Γ^σ, {μ, 0, 3}, {ν, 0, 3}, {ρ, 0, 3}, {σ, 0, 3}]];

使用 NonCommutativeExpand 简化代数中的表达式：

Wolfram Language code: Short[lincomb = NonCommutativeExpand[lincomb, dirac], 5]

这个线性组合包含60项：

Wolfram Language code: Length[lincomb]

然而表象可能具有误导性。由于生成元的平方运算，许多项实际上仅是单位向量的倍数；删除所有不含的项并用单位元替换：

Wolfram Language code: Short[unitized = DeleteCases[lincomb, _ ? (FreeQ[Γ])] + 1]

该向量包含16个基向量，因此其代数运算属于16维空间：

Wolfram Language code: Length[unitized]

将向量与系数分离并排序；基底由所有下标递增的生成元乘积构成：

Wolfram Language code: Sort[List@@Replace[unitized, v_ ? (FreeQ[c]) _ :> v, {1}], order]

定义四个伽马矩阵；作为矩阵，它们处于一个 16 维向量空间中，因此其矩阵代数的维数是包含狄拉克代数的所有矩阵代数中最小的：

Wolfram Language code:

γ^0 = BlockDiagonalMatrix[{IdentityMatrix[2], -IdentityMatrix[2]}];
Table[γ^i = I KroneckerProduct[PauliMatrix[2], PauliMatrix[i]], {i, 3}];
Table[γ^μ//MatrixForm, {μ, 0, 3}]

构造相应基底元素的一般线性组合：

Wolfram Language code:

Table[Subscript[a, i], {i, 16}].Join[{IdentityMatrix[4]}, Table[γ^μ, {μ, 0, 3}], Flatten[Table[If[μ < ν, γ^μ.γ^ν, Nothing], {μ, 0, 3}, {ν, 0, 3}], 1], Flatten[Table[If[μ < ν < ρ, γ^μ.γ^ν.γ^ρ, Nothing], {μ, 0, 3}, {ν, 0, 3}, {ρ, 0, 3}], 2], { Dot@@Table[γ^μ, {μ, 0, 3}]}]//MatrixForm

$sum_(i=1)^(16)a_i e_i=TemplateBox[{TemplateBox[{{4, ,, 4}}, ImplicitList]}, SymbolicZerosArray]$ 的唯一解是，这表明这 16 个矩阵在具体矩阵代数中是线性无关的，正如预期：

Wolfram Language code: Solve[% == ConstantArray[0, {4, 4}]]

属性和关系 (1)

CliffordAlgebra 提供一个具有克利福德代数结构的 NonCommutativeAlgebra：

Wolfram Language code: CliffordAlgebra[{{x, y}, {z, t}, {}}]

Wolfram Language code: % === NonCommutativeAlgebra["Structure" -> {"Clifford", {{x, y}, {z, t}, {}}}]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

CliffordAlgebra

更多信息

范例

基本范例 (2)

范围 (1)

应用 (3)

属性和关系 (1)

文本

CMS

APA

BibTeX

BibLaTeX

CliffordAlgebra

更多信息

范例

基本范例 (2)

范围 (1)

应用 (3)

属性和关系 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX