WOLFRAM

Wolfram 语言与系统参考资料中心

Clip[x]

给出剪切在 和 之间的 x.

Clip[x,{min,max}]

当 min≤x≤max 时，给出 x；当 x<min 时，给出 min；当 x>max 时，给出 max.

Clip[x,{min,max},{vmin,vmax}]

当 x<min 时，给出 vmin；当 x>max 时给出 vmax.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
函数属性  
微分和积分  
应用  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

Clip

Clip[x]

给出剪切在 和 之间的 x.

Clip[x,{min,max}]

当 min≤x≤max 时，给出 x；当 x<min 时，给出 min；当 x>max 时，给出 max.

Clip[x,{min,max},{vmin,vmax}]

当 x<min 时，给出 vmin；当 x>max 时给出 vmax.

更多信息

  • Clip[x] 实际相当于 Piecewise[{{-1,x<-1},{+1,x>+1}},x].
  • vi 同 Clip 的其它自变量一样，不需要为数字.
  • 对于确切的数值量， Clip 在内部用数值近似法确定其结果. 这个过程可能被全局变量 $MaxExtraPrecision 的设置所影响.

范例

打开所有单元 关闭所有单元

基本范例  (3)

数值化计算：

Wolfram Language code: Clip[8.5]

在实数的子集上绘制单位剪切函数：

Wolfram Language code: Plot[Clip[x], {x, -3, 3}]

利用不同的剪切级别：

Wolfram Language code: Plot[Evaluate@Table[Clip[x, {-a, a}], {a, 3}], {x, -5, 5}]

范围  (28)

数值计算  (5)

数值化计算：

Wolfram Language code: Clip[7.5]
Wolfram Language code: Clip[-5 / 2, {-2, 2}]
Wolfram Language code: Clip[Pi, {-9, 7}, {11, 28}]

高精度计算：

Wolfram Language code: N[Clip[1 / 11, {1 / 7, 5}], 50]

输出的精度与输入的精度一致：

Wolfram Language code: Clip[8, {-9, 7.111111111111111111111}]

高精度的高效计算：

Wolfram Language code: Clip[1 / 8, {1 / 17, 1 / 11`100}]//Timing
Wolfram Language code: Clip[91 / 1131, {92 / 173, 72 / 531`100000000}];//Timing

Clip 在其第一个参数中遍历列表：

Wolfram Language code: Clip[{-2, 0, 2}]

或用 MatrixFunction 计算矩阵形式的 FresnelC 函数：

Wolfram Language code: Clip[ Around[-5, 0.01], {2, 5}]

特殊值  (5)

在固定点的 Clip 的值：

Wolfram Language code: Table[Clip[n ], {n, {1 / 7, 1 / 3, 5 / 2, π}}]

零处的值：

Wolfram Language code: Clip[0]

在无穷处的值：

Wolfram Language code: Clip[∞]

符号式计算：

Wolfram Language code: PiecewiseExpand[Clip[x, {0, 4}]]
Wolfram Language code: PiecewiseExpand[Clip[x, {0, 4}, {0, 2}]]

求满足 Clip[x,{-2,2}]=1 的 x 值：

Wolfram Language code: xval = x /. FindRoot[Clip[x, {-2, 2}] == 1, {x, 1.5}]
Wolfram Language code: Plot[Clip[x, {-2, 2}], {x, -5, 5}, Epilog -> Style[Point[{xval, Clip[xval, {-2, 2}]}], PointSize[Large], Red]]

可视化  (3)

可视化 Clip 的三参数形式：

Wolfram Language code: Plot[Clip[x, {0, 2}, {-E, Pi}], {x, -5, 5}]

用周期函数绘制 Clip 的组合：

Wolfram Language code: Plot[Clip[Sin[x], {-(1/2), 1}], {x, -2π, 2π}]

绘制三维的 Clip：

Wolfram Language code: Plot3D[Clip[x + y], {x, -3, 3}, {y, -3, 3}, ColorFunction -> "BlueGreenYellow"]

函数属性  (9)

Clip 对所有实数输入有定义：

Wolfram Language code: FunctionDomain[Clip[x], x]
Wolfram Language code: FunctionDomain[Clip[x, {min, max}, {vmin, max}], {x, min, max, vmin, max}]

它仅限于实数输入：

Wolfram Language code: FunctionDomain[Clip[x], x, Complexes]

Clip[x] 的函数值域：

Wolfram Language code: FunctionRange[Clip[x], x, y]

Clip[x,{min,max},{vmin,vmax}] 的值域：

Wolfram Language code: FunctionRange[Clip[x, {min, max}, {vmin, vmax}], x, y]//Simplify

Clip 的单参数形式是一个奇函数：

Wolfram Language code: FullSimplify[Clip[-x] == -Clip[x]]

通常，双参数和三参数形式不是这样：

Wolfram Language code: Clip[-2, {0, 1}] == -Clip[2, {0, 1}]

Clip 不是解析函数：

Wolfram Language code: FunctionAnalytic[Clip[x], x]

Clip[x] 有奇点但无断点：

Wolfram Language code: FunctionSingularities[Clip[x], x]
Wolfram Language code: FunctionDiscontinuities[Clip[x], x]

三参数的格式可能有断点：

Wolfram Language code: FunctionDiscontinuities[Clip[x, {min, max}, {vmin, max}], x]

Clip[x] 为非递减：

Wolfram Language code: FunctionMonotonicity[Clip[x], x]

Clip[x] 不是单射函数：

Wolfram Language code: FunctionInjective[Clip[x], x]
Wolfram Language code: Plot[{Clip[x], 1}, {x, -4, 4}]

Clip[x] 不是满射函数：

Wolfram Language code: FunctionSurjective[Clip[x], x]
Wolfram Language code: Plot[{Clip[x], -2.5}, {x, -4, 4}]

Clip[x] 不是非负也不是非正：

Wolfram Language code: FunctionSign[Clip[x], x]

Clip[x] 不是凸函数也不是凹函数：

Wolfram Language code: FunctionConvexity[Clip[x], x]

微分和积分  (6)

关于 x 的一阶导：

Wolfram Language code: D[Clip[x], x]//Simplify

关于 x 的一阶和二阶导数：

Wolfram Language code: Table[D[Clip[x, {-2, 2}, {-∞, ∞}], {x, k}], {k, 1, 2}]//FullSimplify

关于 x 的 阶导数的公式：

Wolfram Language code: D[Clip[x], {x, k}]// PiecewiseExpand

使用 Integrate 计算不定积分：

Wolfram Language code: Integrate[Clip[x], x]

验证反导数：

Wolfram Language code: FullSimplify[D[%, x] == Clip[x]]

定积分：

Wolfram Language code: Integrate[Clip[x], {x, 0, 3}]

更多积分：

Wolfram Language code: Integrate[Clip[(1/x - 1)], x]
Wolfram Language code: Integrate[x ^ 2Clip[x], {x, 0, 10}]

应用  (1)

一个剪切的或饱和的正弦曲线：

Wolfram Language code: Plot[Clip[3 / 2 Sin[x]], {x, 0, 30}]

可能存在的问题  (1)

对于复数值，Clip 没有定义：

Wolfram Language code: Clip[2 - 3I]

分别剪切实部和虚部：

Wolfram Language code: Clip[Re[2 - 3I]] + Clip[Im[2 - 3I]]I
Wolfram Research (2004)，Clip，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Clip.html.

文本

Wolfram Research (2004)，Clip，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Clip.html.

CMS

Wolfram 语言. 2004. "Clip." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Clip.html.

APA

Wolfram 语言. (2004). Clip. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Clip.html 年

BibTeX

@misc{reference.wolfram_2026_clip, author="Wolfram Research", title="{Clip}", year="2004", howpublished="\url{https://reference.wolfram.com/language/ref/Clip.html}", note=[Accessed: 20-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_clip, organization={Wolfram Research}, title={Clip}, year={2004}, url={https://reference.wolfram.com/language/ref/Clip.html}, note=[Accessed: 20-June-2026]}