WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ColumnKeys[data]

表形式データ data の列のキーのリストを与える．

ColumnKeys[data,spatt]

文字列パターン spatt にマッチする data の列のキーを与える．

ColumnKeys[data,crit]

crit[keyi]がTrueとなる data の列のキー keyiを与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

ColumnKeys

ColumnKeys[data]

表形式データ data の列のキーのリストを与える．

ColumnKeys[data,spatt]

文字列パターン spatt にマッチする data の列のキーを与える．

ColumnKeys[data,crit]

crit[keyi]がTrueとなる data の列のキー keyiを与える．

詳細

  • ColumnKeysは，一般に，列キーのリストを得るためあるいは特定のキーを検索するために使われる．
  • ColumnKeys[data,…]の data の可能な形式には以下がある．
  • Tabular[…]型付きの列のリストとしての表形式データ
    Dataset[…]一般的な階層データ
    {assoc1,assoc2,…}共通のキーを持つ連想のリスト
    TimeSeries[…]複数の成分を持つ時系列
    EventSeries[…]複数の成分を持つ事象系列
  • ColumnKeys は，入力された表形式データにおいて出現するのと同一の順序で列キーを返す．
  • ColumnKeys[tab,…]は，無記名の列があるTabularオブジェクト tab に対してはNoneを返す．
  • TimeSeriesオブジェクトまたはEventSeriesオブジェクトについては，ColumnKeysは"Timestamp"成分キーも含む．
  • ColumnKeys[data,spatt]で使用可能な文字列パターンには，"col*"のようにワイルドカードを含む文字列や"col"~~__のようなStringExpressionオブジェクトがある．
  • ColumnKeys[data,crit]の関数 crit は，列のキーを与える名前付きの変数#ColumnKeyや列の要素型を与える#ElementTypeを取る．

例題

すべて開く すべて閉じる

例  (3)

列のキーのリストを入手する：

Wolfram Language code: Tabular[{<|"a" -> 1, "b" -> 2, "c" -> 3|>, <|"a" -> 4, "b" -> 5, "c" -> 6|>}]
Wolfram Language code: ColumnKeys[%]

文字列パターンにマッチする名前のキーを選択する：

Wolfram Language code: tab = Tabular[{{1, 2, 3}, {4, 5, 6}}, {"ab", "bb", "ac"}]
Wolfram Language code: ColumnKeys[tab, "a*"]
Wolfram Language code: ColumnKeys[tab, "a" ~~ __]
Wolfram Language code: ColumnKeys[tab, "ab" | "ac"]

基準関数に従ってキーを選択する：

Wolfram Language code: tab = Tabular[{{"cat", 1, "foo", 3.5}, {"dog", 3, "bar", -1.1}}, {"name1", "num1", "name2", "num2"}]
Wolfram Language code: ColumnKeys[tab, StringStartsQ[#ColumnKey, "num"]&]
Wolfram Language code: ColumnKeys[tab, #ElementType == "String"&]

スコープ  (10)

Tabularオブジェクトの列のキーを取得する：

Wolfram Language code: Tabular[{{"John", 34, Entity["City", {"NewYork", "NewYork", "UnitedStates"}]}, {"Yvonne", 56, Entity["City", {"Paris", "IleDeFrance", "France"}]}}, {"name", "age", "city"}]
Wolfram Language code: ColumnKeys[%]

Datasetオブジェクトの列のキーを取得する：

Wolfram Language code: ds = Take[ExampleData[{"Dataset", "Titanic"}], 4]
Wolfram Language code: ColumnKeys[ds]

連想のリストのキーを取得する：

Wolfram Language code: assocs = {<|"c" -> 0, "a" -> 1, "b" -> 2|>, <|"b" -> 20, "c" -> "30"|>};
Wolfram Language code: ColumnKeys[assocs]

ColumnKeysは，連想のキーの未分類の和集合を与える：

Wolfram Language code: DeleteDuplicates[Join@@Map[Keys, assocs]]

結果は対応するTabularオブジェクトとも合致している：

Wolfram Language code: Tabular[assocs]

複数の成分を持つTimeSeriesオブジェクトの成分キーを取得する：

Wolfram Language code: TimeSeries[{{1, "dog"}, {4, "cat"}, {3, "fox"}}, {Today}, ComponentKeys -> {"number", "animal"}]
Wolfram Language code: ColumnKeys[%]

以下は，Tabularオブジェクトに対応する列キーである：

Wolfram Language code: Tabular[%%]

単純なTimeSeriesオブジェクトの成分キーは，"Timestamp"と"Value"である：

Wolfram Language code: TimeSeries[{2, 3, 1}, {Today}]
Wolfram Language code: ColumnKeys[%]

Tabularオブジェクトの列キーは任意の式でよい：

Wolfram Language code: Tabular[Table[{x, y} ^ n, {n, 5}], {x ^ n, y ^ n}]
Wolfram Language code: ColumnKeys[%]

Tabularオブジェクトを取得する：

Wolfram Language code: tab = ToTabular[<|"num1" -> {1, 2, 3}, "list1" -> {{4, 5}, Missing[], {6, 7}}, "num2" -> {1.3, 4.1, 8.}, "q1" -> Quantity[10, "Days"]|>, "Columns"]

文字列パターンを使ってキーが「1」で終る列を選択する：

Wolfram Language code: ColumnKeys[tab, "*1"]
Wolfram Language code: ColumnKeys[tab, __ ~~ "1"]
Wolfram Language code: ColumnKeys[tab, StringEndsQ[#ColumnKey, "1"]&]

基準関数を使って整数を含む列のキーを選択する：

Wolfram Language code: ColumnKeys[tab, StringStartsQ[#ElementType, "Int"]&]

マルチレベルの列名の列のキーを取得する：

Wolfram Language code: data = {{Today, "fox", 1}, {Tomorrow, "lynx", 2}}; names = {ExtendedKey["obs", "date"], ExtendedKey["obs", "species"], "c"};
Wolfram Language code: Tabular[data, names]
Wolfram Language code: ColumnKeys[%]

キーの列はColumnKeysの結果に含まれる：

Wolfram Language code: Tabular[{{1, "foo"}, {3, "bar"}}, <|"ColumnKeys" -> {"col1", "col2"}, "KeyColumns" -> {"col1"}|>]
Wolfram Language code: ColumnKeys[%]

ColumnKeysは，未指定の列のキーがあるTabularオブジェクトに対してはNoneを返す：

Wolfram Language code: Tabular[{{1, 2}, {3, 4}, {5, 6}}]
Wolfram Language code: ColumnKeys[%]

アプリケーション  (1)

パーマーペンギンについてのデータのTabularオブジェクトを取得する：

Wolfram Language code: penguins = ResourceData["Sample Tabular Data: Palmer Penguins"]

ピボット表を作成する：

Wolfram Language code: pt = PivotTable[penguins, Length[#species]&, {"sex"}, {"species", "island"}]

列キーのいくつかはExtendedKeyである：

Wolfram Language code: ColumnKeys[pt]

"Adelie"ペンギンについてのすべての列キーを求める：

Wolfram Language code: ColumnKeys[pt, MatchQ[#ColumnKey, ExtendedKey["Adelie", _]]&]

考えられる問題  (1)

key がリストColumnKeys[tab]のとき，ColumnKeyExistsQ[tab,key]はTrueを返す：

Wolfram Language code: tab = Tabular[{{"a1", "b1"}, {"a2", "b2"}}, {"colA", "colB"}]
Wolfram Language code: {ColumnKeyExistsQ[tab, "colB"], MemberQ[ColumnKeys[tab], "colB"]}
Wolfram Language code: {ColumnKeyExistsQ[tab, "B"], MemberQ[ColumnKeys[tab], "B"]}
Wolfram Research (2025), ColumnKeys, Wolfram言語関数， https://reference.wolfram.com/language/ref/ColumnKeys.html （2026年に更新）.

テキスト

Wolfram Research (2025), ColumnKeys, Wolfram言語関数， https://reference.wolfram.com/language/ref/ColumnKeys.html （2026年に更新）.

CMS

Wolfram Language. 2025. "ColumnKeys." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/ColumnKeys.html.

APA

Wolfram Language. (2025). ColumnKeys. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ColumnKeys.html

BibTeX

@misc{reference.wolfram_2026_columnkeys, author="Wolfram Research", title="{ColumnKeys}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/ColumnKeys.html}", note=[Accessed: 07-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_columnkeys, organization={Wolfram Research}, title={ColumnKeys}, year={2026}, url={https://reference.wolfram.com/language/ref/ColumnKeys.html}, note=[Accessed: 07-October-2026]}