WOLFRAM

Wolfram 语言与系统参考资料中心

ColumnKeys[data]

给出表格 data 中列的键的列表.

ColumnKeys[data,spatt]

给出 data 与字符模式 spatt 匹配的列的键.

ColumnKeys[data,crit]

给出 data 中 crit[keyi] 为 True 的列的键 keyi.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

ColumnKeys

ColumnKeys[data]

给出表格 data 中列的键的列表.

ColumnKeys[data,spatt]

给出 data 与字符模式 spatt 匹配的列的键.

ColumnKeys[data,crit]

给出 data 中 crit[keyi] 为 True 的列的键 keyi.

更多信息

  • ColumnKeys 通常用于获取一组列的键或搜索特定的键.
  • 在 ColumnKeys[data,…] 中，data 可采用的形式包括：
  • Tabular[…]表格数据，由各种类型的列组成的表格数据
    Dataset[…]普通分层数据
    {assoc1,assoc2,…}含有有公共键的关联列表
    TimeSeries[…]含有多个分量的时间序列
    EventSeries[…]含有多个分量的事件序列
  • ColumnKeys 按照在 Tabular 对象中出现的顺序返回列的键.
  • 如果 Tabular 对象 tab 中的列没有名称，ColumnKeys[tab,…] 返回 None.
  • 对于 TimeSeries 或 EventSeries 对象，ColumnKeys 还包含 "Timestamp" 分量键.
  • 在 ColumnKeys[tab,spatt] 中，可能的字符串模式包括带有通配符的字符串（如 "col*"）和 StringExpression 对象（如 "col"~~__）.
  • 在 ColumnKeys[tab,crit] 中，函数 crit 接受提供列的键的已命名变量 #ColumnKey 和提供列的元素的类型的 #ElementType.

范例

打开所有单元 关闭所有单元

基本范例  (3)

获取列的键：

Wolfram Language code: Tabular[{<|"a" -> 1, "b" -> 2, "c" -> 3|>, <|"a" -> 4, "b" -> 5, "c" -> 6|>}]
Wolfram Language code: ColumnKeys[%]

选择名称与字符串模式匹配的键：

Wolfram Language code: tab = Tabular[{{1, 2, 3}, {4, 5, 6}}, {"ab", "bb", "ac"}]
Wolfram Language code: ColumnKeys[tab, "a*"]
Wolfram Language code: ColumnKeys[tab, "a" ~~ __]
Wolfram Language code: ColumnKeys[tab, "ab" | "ac"]

选择符合筛选函数的键：

Wolfram Language code: tab = Tabular[{{"cat", 1, "foo", 3.5}, {"dog", 3, "bar", -1.1}}, {"name1", "num1", "name2", "num2"}]
Wolfram Language code: ColumnKeys[tab, StringStartsQ[#ColumnKey, "num"]&]
Wolfram Language code: ColumnKeys[tab, #ElementType == "String"&]

范围  (10)

获取 Tabular 对象的列的键：

Wolfram Language code: Tabular[{{"John", 34, Entity["City", {"NewYork", "NewYork", "UnitedStates"}]}, {"Yvonne", 56, Entity["City", {"Paris", "IleDeFrance", "France"}]}}, {"name", "age", "city"}]
Wolfram Language code: ColumnKeys[%]

获取 Dataset 对象的列的键：

Wolfram Language code: ds = Take[ExampleData[{"Dataset", "Titanic"}], 4]
Wolfram Language code: ColumnKeys[ds]

获取关联列表的键：

Wolfram Language code: assocs = {<|"c" -> 0, "a" -> 1, "b" -> 2|>, <|"b" -> 20, "c" -> "30"|>};
Wolfram Language code: ColumnKeys[assocs]

ColumnKeys 给出关联的键未排序的合集：

Wolfram Language code: DeleteDuplicates[Join@@Map[Keys, assocs]]

结果也和对应的 Tabular 对象一致：

Wolfram Language code: Tabular[assocs]

获取含有多个分量的 TimeSeries 对象的分量键：

Wolfram Language code: TimeSeries[{{1, "dog"}, {4, "cat"}, {3, "fox"}}, {Today}, ComponentKeys -> {"number", "animal"}]
Wolfram Language code: ColumnKeys[%]

这些是对应的 Tabular 对象的列键：

Wolfram Language code: Tabular[%%]

通常情况下，一个简单的 TimeSeries 对象的分量键为 "Timestamp" 和 "Value"：

Wolfram Language code: TimeSeries[{2, 3, 1}, {Today}]
Wolfram Language code: ColumnKeys[%]

Tabular 对象中列的键可以是任意表达式：

Wolfram Language code: Tabular[Table[{x, y} ^ n, {n, 5}], {x ^ n, y ^ n}]
Wolfram Language code: ColumnKeys[%]

取一个 Tabular 对象：

Wolfram Language code: tab = ToTabular[<|"num1" -> {1, 2, 3}, "list1" -> {{4, 5}, Missing[], {6, 7}}, "num2" -> {1.3, 4.1, 8.}, "q1" -> Quantity[10, "Days"]|>, "Columns"]

用字符串模式选择键以 "1" 结尾的列：

Wolfram Language code: ColumnKeys[tab, "*1"]
Wolfram Language code: ColumnKeys[tab, __ ~~ "1"]
Wolfram Language code: ColumnKeys[tab, StringEndsQ[#ColumnKey, "1"]&]

用筛选函数选择列为整数的键：

Wolfram Language code: ColumnKeys[tab, StringStartsQ[#ElementType, "Int"]&]

获取多个层级上列的键：

Wolfram Language code: data = {{Today, "fox", 1}, {Tomorrow, "lynx", 2}}; names = {ExtendedKey["obs", "date"], ExtendedKey["obs", "species"], "c"};
Wolfram Language code: Tabular[data, names]
Wolfram Language code: ColumnKeys[%]

ColumnKeys 的结果中包括 Key Columns：

Wolfram Language code: Tabular[{{1, "foo"}, {3, "bar"}}, <|"ColumnKeys" -> {"col1", "col2"}, "KeyColumns" -> {"col1"}|>]
Wolfram Language code: ColumnKeys[%]

对于具有未指定列的键的 Tabular 对象，ColumnKeys 返回 None：

Wolfram Language code: Tabular[{{1, 2}, {3, 4}, {5, 6}}]
Wolfram Language code: ColumnKeys[%]

应用  (1)

下面是 Palmer 企鹅数据组成的 Tabular 对象：

Wolfram Language code: penguins = ResourceData["Sample Tabular Data: Palmer Penguins"]

重组表格：

Wolfram Language code: pt = PivotTable[penguins, Length[#species]&, {"sex"}, {"species", "island"}]

某些列的键为 ExtendedKey：

Wolfram Language code: ColumnKeys[pt]

求所有包含 "Adelie" 企鹅的列键：

Wolfram Language code: ColumnKeys[pt, MatchQ[#ColumnKey, ExtendedKey["Adelie", _]]&]

属性和关系  (1)

如果 key 出现在列表 ColumnKeys[tab] 中，ColumnKeyExistsQ[tab,key] 返回 True：

Wolfram Language code: tab = Tabular[{{"a1", "b1"}, {"a2", "b2"}}, {"colA", "colB"}]
Wolfram Language code: {ColumnKeyExistsQ[tab, "colB"], MemberQ[ColumnKeys[tab], "colB"]}
Wolfram Language code: {ColumnKeyExistsQ[tab, "B"], MemberQ[ColumnKeys[tab], "B"]}
Wolfram Research (2025)，ColumnKeys，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ColumnKeys.html （更新于 2026 年）.

文本

Wolfram Research (2025)，ColumnKeys，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ColumnKeys.html （更新于 2026 年）.

CMS

Wolfram 语言. 2025. "ColumnKeys." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2026. https://reference.wolfram.com/language/ref/ColumnKeys.html.

APA

Wolfram 语言. (2025). ColumnKeys. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ColumnKeys.html 年

BibTeX

@misc{reference.wolfram_2026_columnkeys, author="Wolfram Research", title="{ColumnKeys}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/ColumnKeys.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_columnkeys, organization={Wolfram Research}, title={ColumnKeys}, year={2026}, url={https://reference.wolfram.com/language/ref/ColumnKeys.html}, note=[Accessed: 14-September-2026]}