WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ColumnTypes[tab]

Tabularオブジェクト tab の列の要素型を与える．

ColumnTypes[tab,tsel]

tsel で選択された列の要素型を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値型  
ブール型  
文字列型  
Show More Show More
Quantity型  
日付と時間の型  
GeoPosition型  
リストとタプル  
一般的な式  
データ形式  
列選択器  
アプリケーション  
関連項目
関連するガイド
履歴
引用書式

ColumnTypes

ColumnTypes[tab]

Tabularオブジェクト tab の列の要素型を与える．

ColumnTypes[tab,tsel]

tsel で選択された列の要素型を与える．

詳細

  • ColumnTypesは，一般に，型変換あるいは使用可能な操作についての情報を得るために使われる．例えば，文字列に対して日付操作は行えない．
  • ColumnTypes[tab,…]は，名前付きの列を持つTabularオブジェクト tab に対してペア coltype の連想を返す．
  • ColumnTypes[tab,…]は，名前がない列を持つTabularオブジェクト tab に対しては型のリストを返す．
  • 列型の選択器 tsel は以下の形式でよい．
  • tpatt型のパターン
    tclass型の名前付きのクラス
  • 使用可能な型のパターン tpatt には，"String"，"Integer*"や"Quantity"::["Real64",_]のようなケースが含まれる．
  • 次は，使用可能な型のクラス tclass である．
  • "Numbers"数の型
    "MachineNumbers"機械サイズの数の型
    "Reals"整数を含む実数値型
    "MachineReals"整数を含む機械サイズの実数値型
    "Integers"整数型
    "MachineIntegers"機械サイズの整数型
    "FloatingPoint"浮動小数点表現の数
    "MachineFloatingPoint"機械サイズの実数と複素数
    "FloatingPointReals"浮動小数点表現の実数
    "MachineFloatingPointReals"機械サイズの実数
    "FloatingPointComplexes"浮動小数表現の複素数
    "Lists"各要素はリストである
    "Strings"各要素は文字列である
  • ColumnTypesは，TimeSeriesオブジェクトとEventSeriesオブジェクトの成分型も与えることができる．

例題

すべて開く すべて閉じる

例  (3)

次のTabularオブジェクトに対して自動的に選択される型を求める：

Wolfram Language code: Tabular[{{1, "dog", True}, {2, "cat", False}}, {"col1", "col2", "col3"}]
Wolfram Language code: ColumnTypes[%]

実数列の型を求める：

Wolfram Language code: Tabular[{{3.1, 4, False}, {2.5, -3, True}}, {"number", "symbol", "boolean"}]
Wolfram Language code: ColumnTypes[%, "Real*"]

数値行列からキーがないTabularオブジェクトを構築する：

Wolfram Language code: Tabular[{{1, 2.}, {3, 4.}, {5, 6.}}]

各列の型のリストを求める：

Wolfram Language code: ColumnTypes[%]

スコープ  (15)

数値型  (1)

整数または欠落値の集合を取る：

Wolfram Language code: data = ReplacePart[RandomInteger[{-100, 100}, 6], 4 -> Missing[]];
Wolfram Language code: ToTabular[<|"col" -> data|>, "Columns"]

デフォルトで，このマシンでは整数は"Integer64"型を使って解釈される：

Wolfram Language code: ColumnTypes[%]

同じデータを使って異なる整数型で3つの列を構築する：

Wolfram Language code: tab = ToTabular[<|"col8" -> data, "col16" -> data, "col32" -> data|>, "Columns", <|"ElementType" -> {"col8" -> "Integer8", "col16" -> "Integer16", "col32" -> "Integer32"}|>]

保存された型をチェックする：

Wolfram Language code: ColumnTypes[tab]

ブール型  (1)

ブール値あるいは欠落値の集合を取る：

Wolfram Language code: data = RandomChoice[{True, False, Missing[]}, 6]

ToTabularは，データを"Boolean"型の列として自動的に解釈する：

Wolfram Language code: ToTabular[{"col" -> data}, "Columns"]
Wolfram Language code: ColumnTypes[%]

文字列型  (1)

単語または欠落値の集合を取る：

Wolfram Language code: data = ReplacePart[RandomWord[6], 5 -> Missing[]]

ToTabularはデータを"String"型の列として自動的に解釈する：

Wolfram Language code: ToTabular[<|"col" -> data|>, "Columns"]
Wolfram Language code: ColumnTypes[%]

Quantity型  (2)

Quantity期間と欠落値の集合を取る：

Wolfram Language code: data = {Quantity[3.2, "Minutes"], Quantity[90., "Seconds"], Missing[], Quantity[0., "Seconds"]}
Wolfram Language code: tab = ToTabular[<|"col" -> data|>, "Columns"]

値は"Real64"の大きさと共通単位"Seconds"で保存される：

Wolfram Language code: ColumnTypes[%]

Tabularオブジェクトが十分に小さい場合は，デフォルトでもとの入力データがキャッシュされるので，Normalで回復できる：

Wolfram Language code: Normal[tab]

使用する大きさの型と単位を指定する：

Wolfram Language code: tab = CastColumns[tab, "col" -> "Quantity"::["Real32", "Minutes"]]
Wolfram Language code: ColumnTypes[%]

もとの入力はキャッシュされなかった：

Wolfram Language code: Normal[tab]

次元が異なる数量は"InertExpression"型を使って保存できる：

Wolfram Language code: data = {Quantity[2, "Years"], Quantity[1, "LightYears"]}
Wolfram Language code: tab = ToTabular[<|"col" -> data|>, "Columns"]
Wolfram Language code: ColumnTypes[tab]

特定の"Quantity"型を強制しようとすると欠落値になる：

Wolfram Language code: CastColumns[tab, "col" -> "Quantity"::["Integer64", "Years"]]
Wolfram Language code: Normal[%]

日付と時間の型  (3)

日付の集合を取る：

Wolfram Language code: data = RandomDate[6]

自動型検出を使ってTabularオブジェクトを作成する：

Wolfram Language code: tab1 = ToTabular[<|"col" -> data|>, "Columns"]
Wolfram Language code: ColumnTypes[tab1]

日付が抽出する際に粒度"Day"に変換する型を指定する：

Wolfram Language code: tab2 = ToTabular[<|"col" -> data|>, "Columns", <|"ElementType" -> {"Date"::["Integer64", "Day"]}|>]
Wolfram Language code: ColumnTypes[tab2]
Wolfram Language code: Normal[tab2]

時間の集合を取る：

Wolfram Language code: data = RandomTime[6]

自動型検出を使ってTabularオブジェクトを作成する：

Wolfram Language code: tab1 = ToTabular[<|"col" -> data|>, "Columns"]
Wolfram Language code: ColumnTypes[tab1]

日付が抽出する際に粒度"Hour"に変換する型を指定する：

Wolfram Language code: tab2 = ToTabular[<|"col" -> data|>, "Columns", <|"ElementType" -> {"Time"::["Integer64", "Hour"]}|>]
Wolfram Language code: ColumnTypes[tab2]
Wolfram Language code: Normal[tab2]

異なる暦の日付を指定する：

Wolfram Language code: data = RandomDate[6, CalendarType -> "Jewish"]
Wolfram Language code: tab = ToTabular[<|"col" -> data|>, "Columns"]
Wolfram Language code: ColumnTypes[tab]
Wolfram Language code: Normal[tab]

GeoPosition型  (1)

南アメリカ諸国の中心となる地理的位置の集合を取得する：

Wolfram Language code: EntityValue[EntityClass["Country", "SouthAmerica"], "Position"]

ToTabularはデータを自動的に"GeoPosition"型の列として解釈する：

Wolfram Language code: tab = ToTabular[<|"col" -> %|>, "Columns"]
Wolfram Language code: ColumnTypes[tab]
Wolfram Language code: GeoGraphics[{Red, PointSize[Large], Point[tab -> "col"]}, GeoBackground -> "Plain"]

リストとタプル  (2)

整数のタプルを取る：

Wolfram Language code: data = Tuples[{1, 2, 3}, 3]
Wolfram Language code: tab1 = ToTabular[data]
Wolfram Language code: ColumnTypes[%]

タプルの要素の型を指定する：

Wolfram Language code: tab2 = ToTabular[<|"col" -> data|>, "Columns", <|"ElementType" -> {"ListVector"["Integer8", 3]}|>]
Wolfram Language code: ColumnTypes[tab2]

さまざまな型のオブジェクトのタプルの集合を取る：

Wolfram Language code: data = Tuples[{{"cat", "dog", "fox"}, {1, 2, 3}, {True, False}}]

自動型検出を使ってTabularオブジェクトを作成する：

Wolfram Language code: tab1 = ToTabular[<|"col1" -> data|>, "Columns"]
Wolfram Language code: ColumnTypes[tab1]

タプルの要素の型を指定する：

Wolfram Language code: tab2 = ToTabular[<|"col" -> data|>, "Columns", <|"ElementType" -> {"ListTuple"["String", "Integer8", "Boolean"]}|>]
Wolfram Language code: ColumnTypes[tab2]

一般的な式  (1)

領域の集合を取る：

Wolfram Language code: data = Region[RegularPolygon[#]]& /@ Range[3, 8]

Tabularオブジェクトを作成すると，型"Expression"が一般的なWolfram言語式に割り当てられる：

Wolfram Language code: ToTabular[<|"col" -> data|>, "Columns"]
Wolfram Language code: ColumnTypes[%]

データ形式  (2)

TimeSeriesオブジェクトの成分型を抽出する：

Wolfram Language code: TimeSeries[{{1, "dog"}, {4, "cat"}, {3, "fox"}}, {Today}, ComponentKeys -> {"number", "animal"}]
Wolfram Language code: ColumnTypes[%]

連想は，対応するTabularオブジェクトの"Timestamp"列の型を含んでいる：

Wolfram Language code: Tabular[%%]

単純なTimeSeriesオブジェクトを取る：

Wolfram Language code: TimeSeries[Quantity[{2.5, 3.2, 1.9}, "Volts"], {0}]

タイムスタンプ成分は数値型または日付型を持つが，値成分は任意の型でよい：

Wolfram Language code: ColumnTypes[%]

列選択器  (1)

すべての列の型を取得する：

Wolfram Language code: tab = Tabular[{{1, 2.3, "dog", True}, {2, 1.8, "cat", False}}, {"col1", "col2", "col3", "col4"}]
Wolfram Language code: ColumnTypes[tab]

2列の型を抽出する：

Wolfram Language code: ColumnTypes[tab][[{"col1", "col3"}]]

ブール型の列を抽出する：

Wolfram Language code: ColumnTypes[tab, "Boolean"]

任意の整数型の列を抽出する：

Wolfram Language code: ColumnTypes[tab, "Integer*"]

文字列またはブール型の列を抽出する：

Wolfram Language code: ColumnTypes[tab, "String" | "Boolean"]

アプリケーション  (1)

入力型を自動検出するTabularRowを作成する：

Wolfram Language code: TabularRow[{1, "cat", Today}]

列の型：

Wolfram Language code: ColumnTypes[%]

型を指定する：

Wolfram Language code: TabularRow[{1, "cat", Today}, <|"ElementType" -> {"Integer8", "Categorical"[{"cat", "dog", "fox"}], Automatic}|>]

列の型：

Wolfram Language code: ColumnTypes[%]
Wolfram Research (2025), ColumnTypes, Wolfram言語関数， https://reference.wolfram.com/language/ref/ColumnTypes.html （2026年に更新）.

テキスト

Wolfram Research (2025), ColumnTypes, Wolfram言語関数， https://reference.wolfram.com/language/ref/ColumnTypes.html （2026年に更新）.

CMS

Wolfram Language. 2025. "ColumnTypes." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/ColumnTypes.html.

APA

Wolfram Language. (2025). ColumnTypes. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ColumnTypes.html

BibTeX

@misc{reference.wolfram_2026_columntypes, author="Wolfram Research", title="{ColumnTypes}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/ColumnTypes.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_columntypes, organization={Wolfram Research}, title={ColumnTypes}, year={2026}, url={https://reference.wolfram.com/language/ref/ColumnTypes.html}, note=[Accessed: 08-September-2026]}