WOLFRAM

Wolfram 语言与系统参考资料中心

ConcaveHullMesh[{p1,p2,…}]

给出点 p1,p2,… 的凹包网格.

ConcaveHullMesh[{p1,p2,…},α]

给出指定参数 α 的凹包网格.

ConcaveHullMesh[{p1,p2,…},α,d]

给出维度为 d 的单元的凹包网格.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基础用法  
Specifications  
应用  
曲面重建  
曲面重建  
实体重建  
点聚类  
属性和关系  
互动范例  
参见
相关指南
历史
按以下格式引用：

ConcaveHullMesh

ConcaveHullMesh[{p1,p2,…}]

给出点 p1,p2,… 的凹包网格.

ConcaveHullMesh[{p1,p2,…},α]

给出指定参数 α 的凹包网格.

ConcaveHullMesh[{p1,p2,…},α,d]

给出维度为 d 的单元的凹包网格.

更多信息和选项

  • ConcaveHullMesh 也称为 α 形状.
  • 凹包网格通常用于从点构建区域以及点聚类方法.
  • ConcaveHullMesh[{p1,p2,…},α,d] 通过选择包含在半径为 α 的球体中维数为 d 的单元格的方法从 DelaunayMesh[{p1,p2,…}] 中生成，且不包括其他点 pi.
  • ConcaveHullMesh[{p1,p2,…},α] 选择维度为 d 的单元格，其中 d 是点 pi 的嵌入维度.
  • ConcaveHullMesh 采用与 MeshRegion 相同的选项.

范例

打开所有单元 关闭所有单元

基本范例  (2)

从 Annulus 随机采样的点的凹包网格：

Wolfram Language code: ConcaveHullMesh[RandomPoint[Annulus[], 2000]]

求其面积：

Wolfram Language code: Area[%]

根据顶点重建一个三维模型：

Wolfram Language code: ConcaveHullMesh[MeshCoordinates[ResourceData["Horse"]], Automatic, 2]

范围  (6)

基础用法  (3)

一维凹包网格：

Wolfram Language code: ConcaveHullMesh[{{0}, {1}, {3}, {4}}]

二维凹包网格：

Wolfram Language code: ConcaveHullMesh[{{0, 0}, {0, 1}, {-1, (1/3)}, {-1, (2/3)}, {-2, 0}, {-2, 1}}]

三维凹包网格：

Wolfram Language code: ConcaveHullMesh[{{0, 0, 0}, {0, 1, 0}, {0, 0, 1}, {0, 1, 1}, {1, 1 / 3, 1 / 3}, {1, 2 / 3, 1 / 3}, {1, 1 / 3, 2 / 3}, {1, 2 / 3, 2 / 3}, {2, 0, 0}, {2, 1, 0}, {2, 0, 1}, {2, 1, 1}}]

Specifications  (3)

ConcaveHullMesh 取一组点：

Wolfram Language code: pts = {{-1, -1, -1}, {-1, -1, 1}, {-1, 1, -1}, {-1, 1, 1}, {1, -1, -1}, {1, -1, 1}, {1, 1, -1}, {1, 1, 1}};
Wolfram Language code: ConcaveHullMesh[pts]

使用 Point 列表：

Wolfram Language code: ConcaveHullMesh[Point[pts]]

指定单纯形的最大半径：

Wolfram Language code: ConcaveHullMesh[pts, #]& /@ {0.05, 0.4, 1.0}

指定单纯形的维数：

Wolfram Language code: pts = RandomPoint[Ball[], 300];
Wolfram Language code: ConcaveHullMesh[pts, 0.2, #] & /@ {1, 2, 3}
Wolfram Language code: RegionDimension /@ %

使用 All 获得点集的完整 数：

Wolfram Language code: ConcaveHullMesh[pts, 0.2, All]

应用  (7)

曲面重建  (1)

ConcaveHullMesh 可在一维空间中重建一维曲线：

Wolfram Language code: pts = List /@ Range[10]; ConcaveHullMesh[pts]

二维：

Wolfram Language code: pts = Table[{t, Cos[t]}, {t, 0, 4Pi, Pi / 20}]; ConcaveHullMesh[pts, Automatic, 1]

三维：

Wolfram Language code: pts = Table[{t, Cos[t], Sin[t]}, {t, 0, 8Pi, Pi / 20}]; ConcaveHullMesh[pts, Automatic, 1]

曲面重建  (4)

ConcaveHullMesh 可在一维中重建曲面：

Wolfram Language code: pts = RandomPoint[RegionUnion[Ball[{-2}], Ball[{2}]], 30]; ConcaveHullMesh[pts, 1, 0]
Wolfram Language code: RegionMeasure[%]

二维

Wolfram Language code: pts = RandomPoint[RegionBoundary[Annulus[]], 500]; ConcaveHullMesh[pts, 0.1, 1]
Wolfram Language code: ArcLength[%]

三维：

Wolfram Language code: pts = RandomPoint[RegionBoundary[DiscretizeRegion[Torus[]]], 1000]; ConcaveHullMesh[pts, Automatic, 2]
Wolfram Language code: Area[%]

ConcaveHullMesh 可重建三维模型：

Wolfram Language code: ConcaveHullMesh[MeshCoordinates[ResourceData[#]], Automatic, 2]& /@ {"Stanford Bunny", "Horse", "Cow"}

ConcaveHullMesh 可以逼近参数曲面：

Wolfram Language code: pts = Flatten[#, 1]&@Table[{...}, {θ, 0.001, π, 0.05}, {ϕ, 0.001, 2 π, 0.05}];
Wolfram Language code: ConcaveHullMesh[pts, Automatic, 2]

ConcaveHullMesh 可以重建不可定向的表面：

Wolfram Language code: pts = Flatten[#, 1]&@Table[{Cos[t] (3 + r Cos[t / 2]), Sin[t] (3 + r Cos[t / 2]), r Sin[t / 2]}, {r, -1, 1, 0.4}, {t, 0, 2 Pi, 0.1}];
Wolfram Language code: ConcaveHullMesh[pts]

实体重建  (1)

ConcaveHullMesh 可在一维中重构实体：

Wolfram Language code: pts = RandomPoint[Ball[{0}], 10]; ConcaveHullMesh[pts, 1]
Wolfram Language code: ArcLength[%]

二维：

Wolfram Language code: pts = RandomPoint[Annulus[], 500]; ConcaveHullMesh[pts, 0.3]
Wolfram Language code: Area[%]

三维：

Wolfram Language code: pts = RandomPoint[DiscretizeRegion[Torus[]], 1000]; ConcaveHullMesh[pts, 0.3]
Wolfram Language code: Volume[%]

点聚类  (1)

生成正态分布数据并将其可视化：

Wolfram Language code: SeedRandom[123]; Dis = MixtureDistribution[...]; data = RandomVariate[Dis, 500]; ListPlot[data]

找到数据的凹包：

Wolfram Language code: ConcaveHullMesh[data, Automatic, All]

使用 ConnectedMeshComponents 可将点分成聚类：

Wolfram Language code: ConnectedMeshComponents[%]

可视化单独的聚类：

Wolfram Language code: ListPlot[MeshCoordinates[#]& /@ %]

属性和关系  (4)

ConcaveHullMesh 给出与点集的嵌入维度相同维度的 MeshRegion：

Wolfram Language code: pts = RandomPoint[Ball[], 100];
Wolfram Language code: RegionDimension[ConcaveHullMesh[pts]]

ConvexHullMesh 等价于 α 足够大的 ConcaveHullMesh：

Wolfram Language code: pts = ExampleData[{"Geometry3D", "Beethoven"}, "VertexData"];
Wolfram Language code: ConcaveHullMesh[pts, Infinity]

凸包是全维区域：

Wolfram Language code: ConvexHullMesh[pts]
Wolfram Language code: RegionDimension[{%%, %}]

凹包网格可能有多个连接的分量：

Wolfram Language code: ℛ = RandomPoint[RegionUnion[Ball[{0, 0, 0}, .2], FilledTorus[]], 1000];
Wolfram Language code: ConcaveHullMesh[ℛ]

凸包：

Wolfram Language code: ConvexHullMesh[ℛ]

ConcaveHullMesh 给出来自 DelaunayMesh 的单元子集：

Wolfram Language code: pts = RandomPoint[Annulus[], 100];
Wolfram Language code: {ConcaveHullMesh[pts], DelaunayMesh[pts]}

互动范例  (1)

创建一个带有可拖动点的交互式范例以实时查看凹包：

Wolfram Language code: DynamicModule[{pts = Join[CirclePoints[4], CirclePoints[{0.5, Pi / 2}, 4]]}, LocatorPane[Dynamic[pts], Dynamic[Graphics[{Locator[Dynamic[#]]& /@ pts, LightGray, EdgeForm[Gray], ConcaveHullMesh[pts]}, PlotRange -> 1]], LocatorAutoCreate -> True]]
Wolfram Research (2021)，ConcaveHullMesh，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ConcaveHullMesh.html （更新于 2022 年）.

文本

Wolfram Research (2021)，ConcaveHullMesh，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ConcaveHullMesh.html （更新于 2022 年）.

CMS

Wolfram 语言. 2021. "ConcaveHullMesh." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/ConcaveHullMesh.html.

APA

Wolfram 语言. (2021). ConcaveHullMesh. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ConcaveHullMesh.html 年

BibTeX

@misc{reference.wolfram_2026_concavehullmesh, author="Wolfram Research", title="{ConcaveHullMesh}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ConcaveHullMesh.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_concavehullmesh, organization={Wolfram Research}, title={ConcaveHullMesh}, year={2022}, url={https://reference.wolfram.com/language/ref/ConcaveHullMesh.html}, note=[Accessed: 09-September-2026]}