WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ConfirmBy[expr,f]

f[expr]がTrueを返すことを確認する．その他の場合は囲い込んでいる直近のEncloseにエラーをスローする．

ConfirmBy[expr,f,info]

expr が確認できないときは，info を評価してスローするエラーにその値を入れる．

ConfirmBy[expr,f,info,tag]

指定のタグを使って任意のエラーをスローする．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

ConfirmBy

ConfirmBy[expr,f]

f[expr]がTrueを返すことを確認する．その他の場合は囲い込んでいる直近のEncloseにエラーをスローする．

ConfirmBy[expr,f,info]

expr が確認できないときは，info を評価してスローするエラーにその値を入れる．

ConfirmBy[expr,f,info,tag]

指定のタグを使って任意のエラーをスローする．

詳細

  • ConfirmBy[expr,…]は，expr の確認に成功したときは expr を返す．
  • タグが与えられるとConfirmByのスコープは動的になる．その他の場合はスコープが語彙的になる． »
  • info のデフォルト値はNullである．
  • ConfirmByによって生成されたFailureオブジェクトは次のフィールドを含む．
  • "Information"ConfirmBy[expr,f,info,…]からの info
    "Expression"ConfirmBy[expr,…]からの expr
    "Function"ConfirmBy[expr,f,…]からの f
  • これらのフィールドの値は failure["prop"]を使って，あるいは直接Enclose[expr,"prop"]で取り出すことができる．

例題

すべて開く すべて閉じる

例  (2)

ConfirmBy[expr,f]は，f[expr]を評価してTrueになる場合は expr を与える：

Wolfram Language code: Enclose[f[1, ConfirmBy[2, NumberQ], 3]]

"foo"は数ではないので，ConfirmByは評価を中止して囲い込んでいるEncloseにエラーをスローする：

Wolfram Language code: Enclose[f[1, ConfirmBy["foo", NumberQ], 3]]

引数をチェックする関数を作成する：

Wolfram Language code: world[x_] := Enclose[ConfirmBy[x, StringQ] <> ", World!"]
Wolfram Language code: world["Hello"]
Wolfram Language code: world[4]

スコープ  (3)

ConfirmByは，エラーをスローするときは，評価を中止して一致するEncloseに戻る：

Wolfram Language code: Enclose[Echo[1];ConfirmBy[10, LessThan[5]];Echo[2]]

info は，expr が確認できないときしか評価されない：

Wolfram Language code: Enclose[ConfirmBy[2, NumberQ, Echo["info was evaluated"]]]
Wolfram Language code: Enclose[ConfirmBy["NaN", NumberQ, Echo["info was evaluated"]]]

動的にキャッチできるようにタグでConfirmByを呼び出す関数を作成する：

Wolfram Language code: f[x_] := g[StringReverse[ConfirmBy[x, StringQ, Null, "fooTag"]]]
Wolfram Language code: h[y_] := Enclose[f[y], Identity, "fooTag"]
Wolfram Language code: h["reverseme"]
Wolfram Language code: h[42]

タグがないとConfirmByのスコープは語彙的になる：

Wolfram Language code: f2[x_] := g[StringReverse[ConfirmBy[x, StringQ]]]
Wolfram Language code: h2[y_] := Enclose[f2[y]]
Wolfram Language code: h2[2]

アプリケーション  (1)

失敗を検出するとメッセージを出力する：

Wolfram Language code: reverseRoman::nan = "`` is not an integer.";
Wolfram Language code: reverseRoman[n_] := Enclose[ StringReverse[RomanNumeral[ ConfirmBy[n, IntegerQ, Message[reverseRoman::nan, n]] ]], $Failed&]
Wolfram Language code: reverseRoman[21]
Wolfram Language code: reverseRoman["veni, vidi, vici"]

特性と関係  (1)

ConfirmByはConfirmMatchでエミュレートできる：

Wolfram Language code: Enclose[f[ConfirmBy["foo", NumberQ]]]
Wolfram Language code: Enclose[f[ConfirmMatch["foo", _ ? NumberQ]]]

考えられる問題  (3)

ConfirmByにはタグを渡すか語彙的なEncloseの中に置くかしなければならない：

Wolfram Language code: ConfirmBy[5, NumberQ]

タグなしのConfirmByはシンボルConfirmByのインスタンスをタグ付きの異形で置換することで作用する：

Wolfram Language code: Enclose[Hold[ConfirmBy]]

タグ付きのConfirmByには，一致するタグを持つEncloseが必要である：

Wolfram Language code: Enclose[ConfirmBy["hello", NumberQ, Null, "foo"], Identity, "bar"]
Wolfram Research (2020), ConfirmBy, Wolfram言語関数， https://reference.wolfram.com/language/ref/ConfirmBy.html.

テキスト

Wolfram Research (2020), ConfirmBy, Wolfram言語関数， https://reference.wolfram.com/language/ref/ConfirmBy.html.

CMS

Wolfram Language. 2020. "ConfirmBy." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ConfirmBy.html.

APA

Wolfram Language. (2020). ConfirmBy. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ConfirmBy.html

BibTeX

@misc{reference.wolfram_2026_confirmby, author="Wolfram Research", title="{ConfirmBy}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/ConfirmBy.html}", note=[Accessed: 14-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_confirmby, organization={Wolfram Research}, title={ConfirmBy}, year={2020}, url={https://reference.wolfram.com/language/ref/ConfirmBy.html}, note=[Accessed: 14-July-2026]}