WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ControllabilityMatrix[ssm]

状態空間モデル ssm の可制御性行列を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

ControllabilityMatrix

ControllabilityMatrix[ssm]

状態空間モデル ssm の可制御性行列を与える．

詳細

  • 状態方程式を持つ標準的な状態空間モデル
  • 連続時間系
    離散時間系
  • 可制御性行列はと計算される．ただし， は の次元である．
  • 状態方程式を持つディスクリプタ状態空間モデル
  • 連続時間系
    離散時間系
  • 遅い／速い部分系はKroneckerModelDecompositionに説明されているように分離することができる．
  • 遅い部分系
    速い部分系
  • ControllabilityMatrixは，分離された遅い／速い部分系に基づいた行列のペア{q1,q2}を返す．行列 q1および q2は次のように定義される．ただし，は の次元であり， は のベキ零性指標である．
  • 遅い部分系
    速い部分系
  • 可制御性行列は，ある種の λ についてDet[λ e-a]≠0であるディスクリプタ系についてのみ存在する．

例題

すべて開く すべて閉じる

例  (2)

状態空間モデルの可制御性行列：

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0}, {0, 0, Subscript[a, 3]}}, {{Subscript[b, 1]}, {Subscript[b, 2]}, {Subscript[b, 3]}}, {{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}}, {{Subscript[d, 1]}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

可制御多入力状態空間モデル：

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{-1, 1, 0}, {0, -1, 1}, {0, 0, -1}}, {{1, 0}, {1, 0}, {0, 1}}, {{1, 0, 0}}, {{0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

スコープ  (5)

記号単一入力系の可制御性行列：

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{Subscript[a, 1], Subscript[a, 2]}, {Subscript[a, 3], Subscript[a, 4]}}, {{Subscript[b, 1]}, {Subscript[b, 2]}}, {{Subscript[c, 1], Subscript[c, 2]}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

二入力系の可制御性行列は，2倍の数の列を持つ：

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{Subscript[a, 1], Subscript[a, 2]}, {Subscript[a, 3], Subscript[a, 4]}}, {{Subscript[b, 1], 0}, {0, Subscript[b, 2]}}, {{Subscript[c, 1], Subscript[c, 2]}}, {{0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

可制御ではない単一入力系の可制御性行列：

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{Subscript[λ, 1], 0, 0}, {0, Subscript[λ, 2], 0}, {0, 0, Subscript[λ, 3]}}, {{Subscript[b, 1]}, {Subscript[b, 2]}, {0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

対角多入力系の可制御性行列：

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{Subscript[λ, 1], 0, 0}, {0, Subscript[λ, 2], 0}, {0, 0, Subscript[λ, 3]}}, {{Subscript[b, 1], 0, 0}, {0, Subscript[b, 2], 0}, {0, 0, Subscript[b, 3]}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

三次の系の可制御性行列：

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{1, 1, 1}, {-2, 1, 1}, {0, 1, 2}}, {{0}, {1}, {1}}, {{1, 0, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

特異なデスクリプタ系は，2つの行列を返す：

Wolfram Language code: cm = ControllabilityMatrix[StateSpaceModel[{{{1, 0, 0, 0, 0}, {0, 1, 0, 0, 0}, {0, 0, 1, 0, 0}, {0, 0, 0, 1, 0}, {0, 0, 0, 0, -5}}, {{0}, {0}, {0}, {1}, {1}}, {{-1, 17, -139, 803, 4096}}, {{0}}, {{0, 1, 0, 0, 0}, {0, 0, 1, 0, 0}, {0, 0, 0, 1, 0}, {0, 0, 0, 0, 0}, {0, 0, 0, 0, 1}}}, SamplingPeriod -> None, SystemsModelLabels -> None]];
Wolfram Language code: MatrixForm /@ cm

特性と関係  (8)

計算は，状態行列と入力行列のみに依存する：

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{a[1, 1], a[1, 2]}, {a[2, 1], a[2, 2]}}, {{b[1, 1]}, {b[2, 1]}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]//MatrixForm

系はその可制御性行列が最大階数であるときかつそのときに限り可制御である：

Wolfram Language code: ssm = StateSpaceModel[{{{1, -1, 1}, {-2, 1, 3}, {0, 2, 1}}, {{1}, {-1}, {1}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: MatrixRank[ControllabilityMatrix[ssm]] ControllableModelQ[ssm]

この系は可制御ではないが出力可制御である：

Wolfram Language code: ssm = StateSpaceModel[{{{-3, 1, 0}, {-5, 0, 1}, {-3, 0, 0}}, {{1}, {2}, {3}}, {{1, 0, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]
Wolfram Language code: MatrixRank[ControllabilityMatrix[ssm]] ControllableModelQ[ssm]
Wolfram Language code: OutputControllableModelQ[ssm]

この系は可制御であるが出力は可制御ではない：

Wolfram Language code: ssm = StateSpaceModel[{{{-2.5, -1, -0.5}, {-0.5, -2., 0.5}, {0.5, 1., -1.5}}, {{1.}, {1.}, {-3.}}, {{1, 0, -1}, {-1, 1, 0}, {3, -2, -1}}, {{0}, {0}, {0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: MatrixRank[ControllabilityMatrix[ssm]] ControllableModelQ[ssm]
Wolfram Language code: OutputControllableModelQ[ssm]

離散時間系の可制御性行列はサンプリング周期に依存しない：

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{1, 1, 1}, {-2, 1, 1}, {0, 1, 2}}, {{0}, {1}, {1}}, {{1, 0, 0}}, {{0}}}, SamplingPeriod -> τ, SystemsModelLabels -> None]]//MatrixForm

デスクリプタ系については，可制御性のために遅い系と速い系の行列が最大階数でなければならない：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1}, {2}, {0}}, {{1, 1, 1}}, {{0}}, {{1, 0, 0}, {0, 0, 1}, {0, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]
Wolfram Language code: {qs, qf} = ControllabilityMatrix[ssm]
Wolfram Language code: ControllableModelQ[ssm]

遅い部分系の可制御性は，最初の行列によって決定される：

Wolfram Language code: ControllableModelQ[{ssm, "Slow"}] MatrixRank[qs] === Length[qs]

非特異なデスクリプタ系については，速い系の行列は空である：

Wolfram Language code: ControllabilityMatrix[StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}, {{e}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

それぞれの行列は，クロネッカー(Kronecker)分解からの部分系と関連する：

Wolfram Language code: ssm = StateSpaceModel[{{{0, -1, 0, 0}, {-1, 0, 0, 0}, {10, 0, 0, -1}, {0, 1, 1, 1}}, {{0}, {0}, {0}, {-1}}, {{0, 0, 1, 0}}, {{0}}, {{-1, 0, 0, 0}, {0, 0, -1, 0}, {0, 0, 0, 0}, {0, 0, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]; kssm = Last[KroneckerModelDecomposition[ssm]]

可制御性行列は，もとの系のものと一致する：

Wolfram Language code: slowssm = SystemsModelExtract[kssm, All, All, {1, 2}]; fastssm = SystemsModelExtract[kssm, All, All, {3, 4}];
Wolfram Language code: Simplify[ControllabilityMatrix /@ {slowssm, fastssm}] Simplify[ControllabilityMatrix[ssm]]
Wolfram Research (2010), ControllabilityMatrix, Wolfram言語関数， https://reference.wolfram.com/language/ref/ControllabilityMatrix.html （2012年に更新）.

テキスト

Wolfram Research (2010), ControllabilityMatrix, Wolfram言語関数， https://reference.wolfram.com/language/ref/ControllabilityMatrix.html （2012年に更新）.

CMS

Wolfram Language. 2010. "ControllabilityMatrix." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2012. https://reference.wolfram.com/language/ref/ControllabilityMatrix.html.

APA

Wolfram Language. (2010). ControllabilityMatrix. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ControllabilityMatrix.html

BibTeX

@misc{reference.wolfram_2026_controllabilitymatrix, author="Wolfram Research", title="{ControllabilityMatrix}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/ControllabilityMatrix.html}", note=[Accessed: 18-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_controllabilitymatrix, organization={Wolfram Research}, title={ControllabilityMatrix}, year={2012}, url={https://reference.wolfram.com/language/ref/ControllabilityMatrix.html}, note=[Accessed: 18-July-2026]}