WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ControllableDecomposition[sys]

状態空間モデル sys の可制御部分系を与える．

ControllableDecomposition[sys,{z1,…}]

新たな状態変数 ziを指定する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
線形系  
アフィン系  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

ControllableDecomposition

ControllableDecomposition[sys]

状態空間モデル sys の可制御部分系を与える．

ControllableDecomposition[sys,{z1,…}]

新たな状態変数 ziを指定する．

詳細とオプション

例題

すべて開く すべて閉じる

例  (1)

可制御部分系とその変換を求める：

Wolfram Language code: ControllableDecomposition[StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0}, {0, 0, Subscript[a, 3]}}, {{0}, {Subscript[b, 1]}, {Subscript[b, 2]}}, {{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}}, {{Subscript[d, 11]}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

スコープ  (4)

可制御系の可制御部分系は完全な系である：

Wolfram Language code: ControllableDecomposition[StateSpaceModel[{{{-1, -2}, {3, -4}}, {{1}, {-1}}, {{1, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

部分的に可制御な連続時間系の可制御部分系：

Wolfram Language code: ControllableDecomposition[StateSpaceModel[{{{-3, 0, 0}, {0, -4, 0}, {0, 0, -7}}, {{1}, {-1}, {0}}, {{1, 0, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

ディスクリプタ系の可制御部分系：

Wolfram Language code: ControllableDecomposition[StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0}, {0, 0, Subscript[a, 3]}}, {{0, 0}, {Subscript[b, 1], 0}, {0, Subscript[b, 2]}}, {{0, Subscript[c, 1], 0}, {0, 0, Subscript[c, 3]}}, {{Subscript[d, 11], Subscript[d, 12]}, {Subscript[d, 21], Subscript[d, 22]}}, {{Subscript[e, 1], 0, 0}, {0, Subscript[e, 2], 0}, {0, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

アフィン系の可制御部分系：

Wolfram Language code: asys = AffineStateSpaceModel[{{Subscript[x, 1], Subscript[x, 1], Subscript[x, 1]}, {{1}, {1 + Subscript[x, 1]}, {1}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {{Subscript[, 1], 0}}, {Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: ControllableDecomposition[asys]

新たな状態変数を指定する：

Wolfram Language code: ControllableDecomposition[asys, {Subscript[z, 1], Subscript[z, 2], Subscript[z, 3]}]

アプリケーション  (7)

線形系  (4)

Kalman可制御分解を構築する：

Wolfram Language code: ssm = StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0}, {0, 0, Subscript[a, 3]}}, {{0, 0}, {Subscript[b, 1], 0}, {0, Subscript[b, 2]}}, {{Subscript[c, 1], 0, 0}, {0, 0, Subscript[c, 3]}}, {{Subscript[d, 11], Subscript[d, 12]}, {Subscript[d, 21], Subscript[d, 22]}}}, SamplingPeriod -> None, SystemsModelLabels -> None];

ControllableDecompositionは可制御部分系のみを取り出す：

Wolfram Language code: {p, cssm} = ControllableDecomposition[ssm];
Wolfram Language code: cssm

Kalman可制御分解は，最初に可制御部分系を置き，残りはそのままにする：

Wolfram Language code: po = NullSpace[p]; StateSpaceTransform[ssm, ArrayFlatten[{{p, po}}]]

可制御部分空間の次元を計算する：

Wolfram Language code: {p, cssm} = ControllableDecomposition[StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0}, {0, 0, Subscript[a, 3]}}, {{0, 0}, {Subscript[b, 1], 0}, {0, Subscript[b, 2]}}, {{Subscript[c, 1], 0, 0}, {0, 0, Subscript[c, 3]}}, {{Subscript[d, 11], Subscript[d, 12]}, {Subscript[d, 21], Subscript[d, 22]}}}, SamplingPeriod -> None, SystemsModelLabels -> None]];

可制御部分空間は p の範囲である．つまり，列次元である：

Wolfram Language code: Dimensions[p]//Last

以下の系についての可制御部分空間を求め，この系で起り得る可能な状態軌道について説明する：

Wolfram Language code: ssm = StateSpaceModel[{{{1, -1, -3}, {-3, -1, 3}, {5, -1, -7}}, {{0}, {0}, {-1}}, {{1, -1, -1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];

この系は非可制御であり，部分空間のみが可制御である：

Wolfram Language code: ControllableModelQ[ssm]

変換行列 p の範囲が可制御部分空間を与える：

Wolfram Language code: {p, csys} = ControllableDecomposition[ssm];
Wolfram Language code: cspace = ParametricPlot3D[p.{u, v}, {u, -1.25, 1.25}, {v, -1, 1}, Mesh -> None, PlotStyle -> Opacity[0.3]]

この部分空間内では軌道を制御することができる：

Wolfram Language code: x0 = Flatten[Table[p.{u, v}, {u, -0.8, 0.8, 0.3}, {v, -0.8, 0.8, 0.3}], 1]; sr = Table[StateResponse[{ssm, x}, Sin[2t], {t, 0, 10}], {x, x0}];
Wolfram Language code: Show[ParametricPlot3D[Evaluate[sr], {t, 0, 10}], cspace]

しかし，可制御部分空間の平行コピー間のドリフトを制御することはできない：

Wolfram Language code: w = First@NullSpace[p]; (* Orthogonal direction to cspace *) x0 = Flatten[Table[p.{u, v} - w, {u, -0.8, 0.8, 0.3}, {v, -0.8, 0.8, 0.3}], 1]; sr = Table[StateResponse[{ssm, x}, Sin[2t], {t, 0, 10}], {x, x0}];
Wolfram Language code: Show[ParametricPlot3D[Evaluate[sr], {t, 0, 10}], cspace]

可制御部分系の制御器を構築することで，完全に可制御ではない系の制御器を設計する：

力は最初の質量 のみに適用されるので，2番目の質量 は制御することができない：

Wolfram Language code: pars = {Subscript[k, 1] -> 75, Subscript[k, 2] -> 100, Subscript[m, 1] -> 1, Subscript[m, 2] -> 0.5};
Wolfram Language code: ssm = StateSpaceModel[{{{0, 1, 0, 0, 0, 0}, {-(Subscript[k, 1] + Subscript[k, 2])/Subscript[m, 1], 0, Subscript[k, 2]/Subscript[m, 1], 0, 0, 0}, {0, 0, 0, 1, 0, 0}, {Subscript[k, 2]/Subscript[m, 2], 0, -Subscript[k, 2]/Subscript[m, 2], 0, 0, 0}, {0, 0, 0, 0, 0, 1}, {0, 0, 0, 0, -Subscript[k, 2]/Subscript[m, 2], 0}}, {{0}, {Subscript[m, 1]^(-1)}, {0}, {0}, {0}, {0}}, {{1, 0, 0, 0, 0, 0}, {0, 0, 1, 0, 0, 0}}, {{0}, {0}}}, {{Subscript[y, 2][t], 0}, Subscript[, 1], {Subscript[x, 1][t], 0}, Subscript[, 2], {Subscript[x, 2][t], 0}, Subscript[, 3]}, {{F[t], 0}}, {Subscript[x, 1][t], Subscript[x, 2][t]}, t, SamplingPeriod -> None, SystemsModelLabels -> None] /. pars;
Wolfram Language code: ControllableModelQ[ssm]

可制御部分系を使って制御器を設計する：

Wolfram Language code: {p, csys} = ControllableDecomposition[ssm];
Wolfram Language code: κc = StateFeedbackGains[csys, {-1, -2, -3 + I, -3 - I}]

変換を使ってもとの系の制御器を得る：

Wolfram Language code: κ = κc.p

次のシミュレーションは，閉ループ系内の制御されたモードと摂動モードを示している：

Wolfram Language code: clsys = SystemsModelStateFeedbackConnect[ssm, κ];
Wolfram Language code: Plot[Evaluate[StateResponse[{clsys, {0, 0, 0.1, 0, 0.1, 0}}, 0, {t, 0, 7}]], {t, 0, 7}]

閉ループ系のモードを計算する：

Wolfram Language code: Eigenvalues[First[Normal[clsys]]]

摂動モードは非可制御モードである：

Wolfram Language code: Select[Eigenvalues[First[Normal[ssm]]], !ControllableModelQ[{ssm, #}]&]

アフィン系  (3)

三角形可制御分解を構築する：

Wolfram Language code: assm = AffineStateSpaceModel[{{1, 0, Subscript[x, 2]}, {{1}, {Subscript[x, 2]}, {Subscript[x, 1]}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {Subscript[, 1]}, {Automatic}, Automatic, SamplingPeriod -> None];

ControllableDecompositionは可制御の部分系のみを取り出す：

Wolfram Language code: {{p1, p2}, csys} = ControllableDecomposition[assm];
Wolfram Language code: csys

三角形可制御分解は，可制御な部分系を最初に置き，次に残りを置く：

Wolfram Language code: StateSpaceTransform[assm, {p1, Flatten[p2]}]

可制御な部分系の次元を計算する：

Wolfram Language code: assm = AffineStateSpaceModel[{{Subscript[x, 1], Subscript[x, 1], Subscript[x, 1]}, {{1}, {1 + Subscript[x, 1]}, {1}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {{Subscript[, 1], 0}}, {Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: ControllableModelQ[assm]

次元は，逆変換 から得られる：

Wolfram Language code: {{Subscript[p, 1], Subscript[p, 2]}, cssm} = ControllableDecomposition[assm];
Wolfram Language code: cssm
Wolfram Language code: Length[First[Subscript[p, 2]]]

可制御分解は到達可能な部分空間と部分系を与える．これを使って，ある部分系から別の部分系への系の動きを可視化することができる：

Wolfram Language code: asys = AffineStateSpaceModel[{{1, 0, Subscript[x, 2]}, {{1}, {Subscript[x, 2]}, {Subscript[x, 1]}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {Subscript[, 1]}, {Automatic}, Automatic, SamplingPeriod -> None];

一般的な到達可能部分空間：

Wolfram Language code: {{Subscript[p, 1], {Subscript[p, 21], Subscript[p, 22]}}, csys} = ControllableDecomposition[asys];
Wolfram Language code: rspace[{x1_, x2_, x3_}] := Last /@ Subscript[p, 22] /. {Subscript[x, 1] -> x1, Subscript[x, 2] -> x2, Subscript[x, 3] -> x3}
Wolfram Language code: rspace[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}]

特定の到達可能部分空間：

Wolfram Language code: c = 0.2;
Wolfram Language code: rspace0 = ContourPlot3D[Evaluate[rspace[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}] == c], {Subscript[x, 1], 1, 5}, {Subscript[x, 2], 0, 5.5}, {Subscript[x, 3], -7, 7}, Mesh -> None, ContourStyle -> Opacity[0.3]]

この曲面上でいくつかの初期点を選ぶ：

Wolfram Language code: Subscript[x, 10] = Range[1.5, 3, 0.05];
Wolfram Language code: Flatten[Subscript[x, 2] /. Solve[Thread[Last /@ Subscript[p, 22] == c], Subscript[x, 2]] /. Subscript[x, 1] -> Subscript[x, 10]];
Wolfram Language code: Subscript[x, 0] = Thread[{Subscript[x, 10], %, RandomReal[{-1.5, 6.5}, Length@Subscript[x, 10]]}];
Wolfram Language code: Short[Subscript[x, 0], 2]

これらの初期点はすべて，その動きが可制御ではないので，厳密に同じ最終曲面上に残る：

Wolfram Language code: sr = Table[StateResponse[{asys, x}, 0, {t, 0, 1}], {x, Subscript[x, 0]}];
Wolfram Language code: Subscript[x, f] = rspace /@ sr /. t -> 1;
Wolfram Language code: Differences[%]//Chop

3Dプロットは，最初の曲面から最終曲面への動きを示す：

Wolfram Language code: rspace1 = ContourPlot3D[Evaluate[rspace[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}] == Subscript[x, f][[1, 1]]], {Subscript[x, 1], 1, 5}, {Subscript[x, 2], 0.5, 5}, {Subscript[x, 3], -10, 10}, Mesh -> None, ContourStyle -> Opacity[0.3]];
Wolfram Language code: Show[rspace0, ParametricPlot3D[Evaluate[sr], {t, 0, 1}], rspace1, PlotRange -> All]

特性と関係  (2)

変換行列 p はStateSpaceTransformを使って可制御部分系を選ぶ：

Wolfram Language code: ssm = StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0}, {0, 0, Subscript[a, 3]}}, {{0, 0}, {Subscript[b, 1], 0}, {0, Subscript[b, 2]}}, {{Subscript[c, 1], 0, 0}, {0, 0, Subscript[c, 3]}}, {{Subscript[d, 11], Subscript[d, 12]}, {Subscript[d, 21], Subscript[d, 22]}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: {p, csys} = ControllableDecomposition[ssm]; tsys = StateSpaceTransform[ssm, {p, p}];
Wolfram Language code: {csys, tsys}

アフィン系については，変換規則が可制御部分系を選ぶ：

Wolfram Language code: assm = AffineStateSpaceModel[{{-Subscript[x, 4], 0, -Subscript[x, 1], Subscript[x, 2]}, {{1}, {0}, {1 + Subscript[x, 2]}, {0}}, {Subscript[x, 1], Subscript[x, 2]}, {{0}, {0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}, {Subscript[, 1]}, {Automatic, Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: {p, csys} = ControllableDecomposition[assm]; tsys = StateSpaceTransform[assm, p];
Wolfram Language code: {csys, tsys}
Wolfram Research (2010), ControllableDecomposition, Wolfram言語関数， https://reference.wolfram.com/language/ref/ControllableDecomposition.html （2014年に更新）.

テキスト

Wolfram Research (2010), ControllableDecomposition, Wolfram言語関数， https://reference.wolfram.com/language/ref/ControllableDecomposition.html （2014年に更新）.

CMS

Wolfram Language. 2010. "ControllableDecomposition." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/ControllableDecomposition.html.

APA

Wolfram Language. (2010). ControllableDecomposition. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ControllableDecomposition.html

BibTeX

@misc{reference.wolfram_2026_controllabledecomposition, author="Wolfram Research", title="{ControllableDecomposition}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ControllableDecomposition.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_controllabledecomposition, organization={Wolfram Research}, title={ControllableDecomposition}, year={2014}, url={https://reference.wolfram.com/language/ref/ControllableDecomposition.html}, note=[Accessed: 04-September-2026]}