WOLFRAM

Wolfram 语言与系统参考资料中心

ControllableDecomposition[sys]

产生状态空间系统 sys 的可控制子系统.

ControllableDecomposition[sys,{z1,…}]

指定新状态变量 zi.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
线性系统  
反射系统  
属性和关系  
参见
相关指南
历史
按以下格式引用：

ControllableDecomposition

ControllableDecomposition[sys]

产生状态空间系统 sys 的可控制子系统.

ControllableDecomposition[sys,{z1,…}]

指定新状态变量 zi.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (1)

求可控制子系统和它的变换：

Wolfram Language code: ControllableDecomposition[StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0}, {0, 0, Subscript[a, 3]}}, {{0}, {Subscript[b, 1]}, {Subscript[b, 2]}}, {{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}}, {{Subscript[d, 11]}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

范围  (4)

可控系统的可控子系统是一个完整的系统：

Wolfram Language code: ControllableDecomposition[StateSpaceModel[{{{-1, -2}, {3, -4}}, {{1}, {-1}}, {{1, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

部分可控连续时间系统的可控子系统：

Wolfram Language code: ControllableDecomposition[StateSpaceModel[{{{-3, 0, 0}, {0, -4, 0}, {0, 0, -7}}, {{1}, {-1}, {0}}, {{1, 0, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

描述符系统的可控子系统：

Wolfram Language code: ControllableDecomposition[StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0}, {0, 0, Subscript[a, 3]}}, {{0, 0}, {Subscript[b, 1], 0}, {0, Subscript[b, 2]}}, {{0, Subscript[c, 1], 0}, {0, 0, Subscript[c, 3]}}, {{Subscript[d, 11], Subscript[d, 12]}, {Subscript[d, 21], Subscript[d, 22]}}, {{Subscript[e, 1], 0, 0}, {0, Subscript[e, 2], 0}, {0, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

仿射系统的可控子系统：

Wolfram Language code: asys = AffineStateSpaceModel[{{Subscript[x, 1], Subscript[x, 1], Subscript[x, 1]}, {{1}, {1 + Subscript[x, 1]}, {1}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {{Subscript[, 1], 0}}, {Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: ControllableDecomposition[asys]

指定新的状态变量：

Wolfram Language code: ControllableDecomposition[asys, {Subscript[z, 1], Subscript[z, 2], Subscript[z, 3]}]

应用  (7)

线性系统  (4)

构建卡尔曼可控分解：

Wolfram Language code: ssm = StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0}, {0, 0, Subscript[a, 3]}}, {{0, 0}, {Subscript[b, 1], 0}, {0, Subscript[b, 2]}}, {{Subscript[c, 1], 0, 0}, {0, 0, Subscript[c, 3]}}, {{Subscript[d, 11], Subscript[d, 12]}, {Subscript[d, 21], Subscript[d, 22]}}}, SamplingPeriod -> None, SystemsModelLabels -> None];

ControllableDecomposition 仅挑选出可控子系统：

Wolfram Language code: {p, cssm} = ControllableDecomposition[ssm];
Wolfram Language code: cssm

卡尔曼可控分解将可控子系统放在第一位，并保留其余的子系统：

Wolfram Language code: po = NullSpace[p]; StateSpaceTransform[ssm, ArrayFlatten[{{p, po}}]]

计算可控子空间的维数：

Wolfram Language code: {p, cssm} = ControllableDecomposition[StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0}, {0, 0, Subscript[a, 3]}}, {{0, 0}, {Subscript[b, 1], 0}, {0, Subscript[b, 2]}}, {{Subscript[c, 1], 0, 0}, {0, 0, Subscript[c, 3]}}, {{Subscript[d, 11], Subscript[d, 12]}, {Subscript[d, 21], Subscript[d, 22]}}}, SamplingPeriod -> None, SystemsModelLabels -> None]];

可控子空间是 p 的范围，即列维度：

Wolfram Language code: Dimensions[p]//Last

找到以下系统的可控子空间，并解释能在系统中发生的可能状态轨迹：

Wolfram Language code: ssm = StateSpaceModel[{{{1, -1, -3}, {-3, -1, 3}, {5, -1, -7}}, {{0}, {0}, {-1}}, {{1, -1, -1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];

该系统是不可控的，所以只有一个子空间是可控的：

Wolfram Language code: ControllableModelQ[ssm]

变换矩阵 p 的范围给出了可控子空间：

Wolfram Language code: {p, csys} = ControllableDecomposition[ssm];
Wolfram Language code: cspace = ParametricPlot3D[p.{u, v}, {u, -1.25, 1.25}, {v, -1, 1}, Mesh -> None, PlotStyle -> Opacity[0.3]]

轨迹可以在这个子空间进行控制：

Wolfram Language code: x0 = Flatten[Table[p.{u, v}, {u, -0.8, 0.8, 0.3}, {v, -0.8, 0.8, 0.3}], 1]; sr = Table[StateResponse[{ssm, x}, Sin[2t], {t, 0, 10}], {x, x0}];
Wolfram Language code: Show[ParametricPlot3D[Evaluate[sr], {t, 0, 10}], cspace]

但你无法控制可控子空间的平行副本之间的漂移：

Wolfram Language code: w = First@NullSpace[p]; (* Orthogonal direction to cspace *) x0 = Flatten[Table[p.{u, v} - w, {u, -0.8, 0.8, 0.3}, {v, -0.8, 0.8, 0.3}], 1]; sr = Table[StateResponse[{ssm, x}, Sin[2t], {t, 0, 10}], {x, x0}];
Wolfram Language code: Show[ParametricPlot3D[Evaluate[sr], {t, 0, 10}], cspace]

通过构建可控子系统的控制器，为一个不是完全可控的系统设计一个控制器：

由于施加的力仅作用于第一个质量 上，第二个质量 是不可控的：

Wolfram Language code: pars = {Subscript[k, 1] -> 75, Subscript[k, 2] -> 100, Subscript[m, 1] -> 1, Subscript[m, 2] -> 0.5};
Wolfram Language code: ssm = StateSpaceModel[{{{0, 1, 0, 0, 0, 0}, {-(Subscript[k, 1] + Subscript[k, 2])/Subscript[m, 1], 0, Subscript[k, 2]/Subscript[m, 1], 0, 0, 0}, {0, 0, 0, 1, 0, 0}, {Subscript[k, 2]/Subscript[m, 2], 0, -Subscript[k, 2]/Subscript[m, 2], 0, 0, 0}, {0, 0, 0, 0, 0, 1}, {0, 0, 0, 0, -Subscript[k, 2]/Subscript[m, 2], 0}}, {{0}, {Subscript[m, 1]^(-1)}, {0}, {0}, {0}, {0}}, {{1, 0, 0, 0, 0, 0}, {0, 0, 1, 0, 0, 0}}, {{0}, {0}}}, {{Subscript[y, 2][t], 0}, Subscript[, 1], {Subscript[x, 1][t], 0}, Subscript[, 2], {Subscript[x, 2][t], 0}, Subscript[, 3]}, {{F[t], 0}}, {Subscript[x, 1][t], Subscript[x, 2][t]}, t, SamplingPeriod -> None, SystemsModelLabels -> None] /. pars;
Wolfram Language code: ControllableModelQ[ssm]

设计采用可控子系统的控制器：

Wolfram Language code: {p, csys} = ControllableDecomposition[ssm];
Wolfram Language code: κc = StateFeedbackGains[csys, {-1, -2, -3 + I, -3 - I}]

利用变换获得原系统的控制器：

Wolfram Language code: κ = κc.p

模拟显示出在闭环系统中的控制及振荡模式：

Wolfram Language code: clsys = SystemsModelStateFeedbackConnect[ssm, κ];
Wolfram Language code: Plot[Evaluate[StateResponse[{clsys, {0, 0, 0.1, 0, 0.1, 0}}, 0, {t, 0, 7}]], {t, 0, 7}]

计算该闭环系统的模式：

Wolfram Language code: Eigenvalues[First[Normal[clsys]]]

该振荡模式是不可控的：

Wolfram Language code: Select[Eigenvalues[First[Normal[ssm]]], !ControllableModelQ[{ssm, #}]&]

反射系统  (3)

构建三角可控分解：

Wolfram Language code: assm = AffineStateSpaceModel[{{1, 0, Subscript[x, 2]}, {{1}, {Subscript[x, 2]}, {Subscript[x, 1]}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {Subscript[, 1]}, {Automatic}, Automatic, SamplingPeriod -> None];

ControllableDecomposition 仅挑选出可控的子系统：

Wolfram Language code: {{p1, p2}, csys} = ControllableDecomposition[assm];
Wolfram Language code: csys

三角可控分解将可控子系统放在第一个，并保留其余部分：

Wolfram Language code: StateSpaceTransform[assm, {p1, Flatten[p2]}]

计算可控子空间的维度：

Wolfram Language code: assm = AffineStateSpaceModel[{{Subscript[x, 1], Subscript[x, 1], Subscript[x, 1]}, {{1}, {1 + Subscript[x, 1]}, {1}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {{Subscript[, 1], 0}}, {Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: ControllableModelQ[assm]

维度可以从逆变换 得到：

Wolfram Language code: {{Subscript[p, 1], Subscript[p, 2]}, cssm} = ControllableDecomposition[assm];
Wolfram Language code: cssm
Wolfram Language code: Length[First[Subscript[p, 2]]]

可控分解给出了可达子空间和子系统. 这可以被用于可视化系统从一个子空间到另一个子空间的运动：

Wolfram Language code: asys = AffineStateSpaceModel[{{1, 0, Subscript[x, 2]}, {{1}, {Subscript[x, 2]}, {Subscript[x, 1]}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {Subscript[, 1]}, {Automatic}, Automatic, SamplingPeriod -> None];

一个通用的可达子空间：

Wolfram Language code: {{Subscript[p, 1], {Subscript[p, 21], Subscript[p, 22]}}, csys} = ControllableDecomposition[asys];
Wolfram Language code: rspace[{x1_, x2_, x3_}] := Last /@ Subscript[p, 22] /. {Subscript[x, 1] -> x1, Subscript[x, 2] -> x2, Subscript[x, 3] -> x3}
Wolfram Language code: rspace[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}]

一个具体的可达子空间：

Wolfram Language code: c = 0.2;
Wolfram Language code: rspace0 = ContourPlot3D[Evaluate[rspace[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}] == c], {Subscript[x, 1], 1, 5}, {Subscript[x, 2], 0, 5.5}, {Subscript[x, 3], -7, 7}, Mesh -> None, ContourStyle -> Opacity[0.3]]

在该表面选取几个初始点：

Wolfram Language code: Subscript[x, 10] = Range[1.5, 3, 0.05];
Wolfram Language code: Flatten[Subscript[x, 2] /. Solve[Thread[Last /@ Subscript[p, 22] == c], Subscript[x, 2]] /. Subscript[x, 1] -> Subscript[x, 10]];
Wolfram Language code: Subscript[x, 0] = Thread[{Subscript[x, 10], %, RandomReal[{-1.5, 6.5}, Length@Subscript[x, 10]]}];
Wolfram Language code: Short[Subscript[x, 0], 2]

所有这些初始点均在完全相同的终表面结束，因为该运动是不可控的：

Wolfram Language code: sr = Table[StateResponse[{asys, x}, 0, {t, 0, 1}], {x, Subscript[x, 0]}];
Wolfram Language code: Subscript[x, f] = rspace /@ sr /. t -> 1;
Wolfram Language code: Differences[%]//Chop

三维图形显示了从初表面到终表面的运动：

Wolfram Language code: rspace1 = ContourPlot3D[Evaluate[rspace[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}] == Subscript[x, f][[1, 1]]], {Subscript[x, 1], 1, 5}, {Subscript[x, 2], 0.5, 5}, {Subscript[x, 3], -10, 10}, Mesh -> None, ContourStyle -> Opacity[0.3]];
Wolfram Language code: Show[rspace0, ParametricPlot3D[Evaluate[sr], {t, 0, 1}], rspace1, PlotRange -> All]

属性和关系  (2)

变换矩阵 p 使用 StateSpaceTransform 选择可控子系统：

Wolfram Language code: ssm = StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0}, {0, 0, Subscript[a, 3]}}, {{0, 0}, {Subscript[b, 1], 0}, {0, Subscript[b, 2]}}, {{Subscript[c, 1], 0, 0}, {0, 0, Subscript[c, 3]}}, {{Subscript[d, 11], Subscript[d, 12]}, {Subscript[d, 21], Subscript[d, 22]}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: {p, csys} = ControllableDecomposition[ssm]; tsys = StateSpaceTransform[ssm, {p, p}];
Wolfram Language code: {csys, tsys}

对于仿射系统，转换规则选择可控子系统：

Wolfram Language code: assm = AffineStateSpaceModel[{{-Subscript[x, 4], 0, -Subscript[x, 1], Subscript[x, 2]}, {{1}, {0}, {1 + Subscript[x, 2]}, {0}}, {Subscript[x, 1], Subscript[x, 2]}, {{0}, {0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}, {Subscript[, 1]}, {Automatic, Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: {p, csys} = ControllableDecomposition[assm]; tsys = StateSpaceTransform[assm, p];
Wolfram Language code: {csys, tsys}
Wolfram Research (2010)，ControllableDecomposition，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ControllableDecomposition.html （更新于 2014 年）.

文本

Wolfram Research (2010)，ControllableDecomposition，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ControllableDecomposition.html （更新于 2014 年）.

CMS

Wolfram 语言. 2010. "ControllableDecomposition." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/ControllableDecomposition.html.

APA

Wolfram 语言. (2010). ControllableDecomposition. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ControllableDecomposition.html 年

BibTeX

@misc{reference.wolfram_2026_controllabledecomposition, author="Wolfram Research", title="{ControllableDecomposition}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ControllableDecomposition.html}", note=[Accessed: 14-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_controllabledecomposition, organization={Wolfram Research}, title={ControllableDecomposition}, year={2014}, url={https://reference.wolfram.com/language/ref/ControllableDecomposition.html}, note=[Accessed: 14-October-2026]}