WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CoordinateTransform[t,pt]

点 pt において座標変換 t を行う．

CoordinateTransform[t,{pt1,pt2,…}]

複数の点を変換する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

CoordinateTransform

CoordinateTransform[t,pt]

点 pt において座標変換 t を行う．

CoordinateTransform[t,{pt1,pt2,…}]

複数の点を変換する．

詳細

  • 変換は，oldchart->newchart の形で入力することができる．oldchart および newchart は，CoordinateChartDataから使用可能な有効なグラフ指定である．
  • 変換は，CoordinateTransformData標準名{oldsys->newsys,metric,dim}としても与えることができる．{oldsys,metric,dim}および{newsys,metric,dim}は，CoordinateChartDataから使用可能な有効なグラフである．次元を省略した短縮形を使うことができる．
  • CoordinateTransform[t,pt]は事実上CoordinateTransformData[t,"Mapping",pt]と等価である．
  • CoordinateTransformは，座標リストの配列に自動的に縫い込まれる．

例題

すべて開く すべて閉じる

例  (2)

極座標の生成点を直交座標に変える：

Wolfram Language code: CoordinateTransform[ "Polar" -> "Cartesian", {r, θ}]

直交座標の特定の点を極座標に変える：

Wolfram Language code: CoordinateTransform[{"Cartesian" -> "Polar", 2}, {1, -1}]

スコープ  (5)

球座標で表された点の{x,y,z}の値を与える：

Wolfram Language code: CoordinateTransform["Spherical" -> "Cartesian", {1, π / 4, π / 2}]

偏長楕円座標のパラメータを指定して，偏長楕円座標の点を球座標に変換する：

Wolfram Language code: CoordinateTransform[{{"ProlateSpheroidal", 1}} -> "Spherical", {1, 1, 1}]

より冗長に表現された同じ変換：

Wolfram Language code: CoordinateTransform[{{"ProlateSpheroidal", 1} -> "Spherical", "Euclidean", 3}, {1, 1, 1} ]

半径 r の球の上の座標を立体射影の対応する値に変換する：

Wolfram Language code: CoordinateTransformData[{"Standard" -> "Stereographic", {"Sphere", r}}, "Mapping", {θ, φ}]

いくつかの点を円柱座標から直交座標に一度に変換する：

Wolfram Language code: CoordinateTransform["Cylindrical" -> "Cartesian", {{r, θ, z}, {1, 0, 2}, {2, π, 1}, {1, π / 2, 0}}]

点の行列を直交座標から球座標に変換する：

Wolfram Language code: CoordinateTransform["Cartesian" -> "Spherical", {{{x, y, z}, {1, 0, 1}}, {{2, 3.5, -1.5}, {1, 1, 0}}}]

アプリケーション  (1)

非直交座標の曲線を可視化のために対応する直交式に変換する：

Wolfram Language code: cSpherical[t_] := {t, Pi((1 + Sin[16t + 4t ^ 2]/2)), 1 + 2t + 3t ^ 2}
Wolfram Language code: cCartesian[t_] = CoordinateTransform["Spherical" -> "Cartesian", cSpherical[t]]
Wolfram Language code: Show[Graphics3D[{Opacity[.25], Sphere[]}], ParametricPlot3D[cCartesian[t], {t, 0, 1}, ColorFunction -> (Hue[.8#4]&)]]

この曲線は半径の長さがおよそ11.2である：

Wolfram Language code: ArcLength[cCartesian[t], {t, 0., 1}]

特性と関係  (8)

CoordinateTransformData[ent,"Mapping",pt]は，事実上，CoordinateTransform[ent,pt]である：

Wolfram Language code: CoordinateTransform["Bipolar" -> "Cartesian", {1, 0}] === CoordinateTransformData["Bipolar" -> "Cartesian", "Mapping", {1, 0}]

CoordinateTransformは，入力がチャートの座標仮定に従うかどうかをチェックする：

Wolfram Language code: CoordinateTransform["Spherical" -> "Cartesian", {1, 0, 0}]

この点は極角 についての座標範囲仮定に違反している：

Wolfram Language code: CoordinateChartData["Spherical", "CoordinateRangeAssumptions", {r, θ, φ}]

CoordinateTransformDataから記号変換を抽出し，これを特異点に適用する：

Wolfram Language code: transform = CoordinateTransformData["Spherical" -> {"Cartesian", 3}, "Mapping"]; transform[{1, 0, 0}]

逆マッピングはこの点ではうまく定義されていない：

Wolfram Language code: CoordinateTransformData[{"Cartesian", 3} -> "Spherical", "Mapping"][{0, 0, 1}]

CoordinateTransformは配列の形を保存する：

Wolfram Language code: CoordinateTransform["Cartesian" -> "Polar", {{{1, -1}}}]

これは，空配列を含む：

Wolfram Language code: CoordinateTransform["Spherical" -> "Toroidal", {{} , {}}]

CoordinateTransformは点の座標値を変える：

Wolfram Language code: CoordinateTransform["Cartesian" -> "Polar", {x, y}]

TransformedFieldは場の座標式を変える：

Wolfram Language code: TransformedField["Cartesian" -> "Polar", {x, y}, {x, y} -> {r, θ}]//Simplify

FromPolarCoordinatesはCoordinateTransformの特殊ケースである：

Wolfram Language code: CoordinateTransform["Polar" -> "Cartesian", {r, θ}] == FromPolarCoordinates[{r, θ}]
Wolfram Language code: CoordinateTransform["Hyperspherical" -> "Cartesian", {r, θ, φ}] == FromPolarCoordinates[{r, θ, φ}]

ToPolarCoordinatesはCoordinateTransformの特殊ケースである：

Wolfram Language code: CoordinateTransform["Cartesian" -> "Polar", {x, y}] == ToPolarCoordinates[{x, y}]
Wolfram Language code: CoordinateTransform["Cartesian" -> "Hyperspherical", {x, y, z}] == ToPolarCoordinates[{x, y, z}]

FromSphericalCoordinatesはCoordinateTransformの特殊ケースである：

Wolfram Language code: CoordinateTransform["Spherical" -> "Cartesian", {r, θ, φ}] == FromSphericalCoordinates[{r, θ, φ}]

ToSphericalCoordinatesはCoordinateTransformの特殊ケースである：

Wolfram Language code: CoordinateTransform["Cartesian" -> "Spherical", {x, y, z}] == ToSphericalCoordinates[{x, y, z}]
Wolfram Research (2012), CoordinateTransform, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoordinateTransform.html （2015年に更新）.

テキスト

Wolfram Research (2012), CoordinateTransform, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoordinateTransform.html （2015年に更新）.

CMS

Wolfram Language. 2012. "CoordinateTransform." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2015. https://reference.wolfram.com/language/ref/CoordinateTransform.html.

APA

Wolfram Language. (2012). CoordinateTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoordinateTransform.html

BibTeX

@misc{reference.wolfram_2026_coordinatetransform, author="Wolfram Research", title="{CoordinateTransform}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/CoordinateTransform.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coordinatetransform, organization={Wolfram Research}, title={CoordinateTransform}, year={2015}, url={https://reference.wolfram.com/language/ref/CoordinateTransform.html}, note=[Accessed: 16-September-2026]}