WOLFRAM

Wolfram 语言与系统参考资料中心

CoordinateTransform[t,pt]

在点 pt 上执行坐标变换 t.

CoordinateTransform[t,{pt1,pt2,…}]

对一些点进行变换.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
技术笔记
相关指南
历史
按以下格式引用：

CoordinateTransform

CoordinateTransform[t,pt]

在点 pt 上执行坐标变换 t.

CoordinateTransform[t,{pt1,pt2,…}]

对一些点进行变换.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (2)

把极坐标中的普通点变换为标准坐标：

Wolfram Language code: CoordinateTransform[ "Polar" -> "Cartesian", {r, θ}]

把标准坐标中的特定点变换为极坐标：

Wolfram Language code: CoordinateTransform[{"Cartesian" -> "Polar", 2}, {1, -1}]

范围  (5)

对于以球面坐标表示的点给出 {x,y,z} 值：

Wolfram Language code: CoordinateTransform["Spherical" -> "Cartesian", {1, π / 4, π / 2}]

把椭球体中的点变换为球体坐标，指定椭球坐标中的参数：

Wolfram Language code: CoordinateTransform[{{"ProlateSpheroidal", 1}} -> "Spherical", {1, 1, 1}]

相同的变换，用更长的表达式表示：

Wolfram Language code: CoordinateTransform[{{"ProlateSpheroidal", 1} -> "Spherical", "Euclidean", 3}, {1, 1, 1} ]

将半径为 r 的球面上的坐标变换为赤平投影中的相应值：

Wolfram Language code: CoordinateTransformData[{"Standard" -> "Stereographic", {"Sphere", r}}, "Mapping", {θ, φ}]

一次性把几个点从圆柱坐标变换为直角坐标：

Wolfram Language code: CoordinateTransform["Cylindrical" -> "Cartesian", {{r, θ, z}, {1, 0, 2}, {2, π, 1}, {1, π / 2, 0}}]

将一个点阵从笛卡尔坐标转换到球面坐标：

Wolfram Language code: CoordinateTransform["Cartesian" -> "Spherical", {{{x, y, z}, {1, 0, 1}}, {{2, 3.5, -1.5}, {1, 1, 0}}}]

应用  (1)

为了实现可视化，将非直角坐标中的曲线变换为相应的直角坐标中的表达式：

Wolfram Language code: cSpherical[t_] := {t, Pi((1 + Sin[16t + 4t ^ 2]/2)), 1 + 2t + 3t ^ 2}
Wolfram Language code: cCartesian[t_] = CoordinateTransform["Spherical" -> "Cartesian", cSpherical[t]]
Wolfram Language code: Show[Graphics3D[{Opacity[.25], Sphere[]}], ParametricPlot3D[cCartesian[t], {t, 0, 1}, ColorFunction -> (Hue[.8#4]&)]]

这个曲线的半径长度近似 11.2：

Wolfram Language code: ArcLength[cCartesian[t], {t, 0., 1}]

属性和关系  (8)

CoordinateTransformData[ent,"Mapping",pt] 实际上是 CoordinateTransform[ent,pt]：

Wolfram Language code: CoordinateTransform["Bipolar" -> "Cartesian", {1, 0}] === CoordinateTransformData["Bipolar" -> "Cartesian", "Mapping", {1, 0}]

CoordinateTransform 检查输入是否服从图表坐标范围的假设：

Wolfram Language code: CoordinateTransform["Spherical" -> "Cartesian", {1, 0, 0}]

该点违反了关于极角 的坐标范围假设：

Wolfram Language code: CoordinateChartData["Spherical", "CoordinateRangeAssumptions", {r, θ, φ}]

从 CoordinateTransformData 提取符号式变换，并将其应用于奇异点：

Wolfram Language code: transform = CoordinateTransformData["Spherical" -> {"Cartesian", 3}, "Mapping"]; transform[{1, 0, 0}]

反向映射在该点不是明确的：

Wolfram Language code: CoordinateTransformData[{"Cartesian", 3} -> "Spherical", "Mapping"][{0, 0, 1}]

CoordinateTransform 保留数组的形状：

Wolfram Language code: CoordinateTransform["Cartesian" -> "Polar", {{{1, -1}}}]

这包括空数组：

Wolfram Language code: CoordinateTransform["Spherical" -> "Toroidal", {{} , {}}]

CoordinateTransform 改变点的坐标值：

Wolfram Language code: CoordinateTransform["Cartesian" -> "Polar", {x, y}]

TransformedField 改变场的坐标表达式：

Wolfram Language code: TransformedField["Cartesian" -> "Polar", {x, y}, {x, y} -> {r, θ}]//Simplify
Wolfram Language code: CoordinateTransform["Polar" -> "Cartesian", {r, θ}] == FromPolarCoordinates[{r, θ}]
Wolfram Language code: CoordinateTransform["Hyperspherical" -> "Cartesian", {r, θ, φ}] == FromPolarCoordinates[{r, θ, φ}]

ToPolarCoordinates 是 CoordinateTransform 的一个特例：

Wolfram Language code: CoordinateTransform["Cartesian" -> "Polar", {x, y}] == ToPolarCoordinates[{x, y}]
Wolfram Language code: CoordinateTransform["Cartesian" -> "Hyperspherical", {x, y, z}] == ToPolarCoordinates[{x, y, z}]

FromSphericalCoordinates 是 CoordinateTransform 的一个特例：

Wolfram Language code: CoordinateTransform["Spherical" -> "Cartesian", {r, θ, φ}] == FromSphericalCoordinates[{r, θ, φ}]

ToSphericalCoordinates 是 CoordinateTransform 的一个特例：

Wolfram Language code: CoordinateTransform["Cartesian" -> "Spherical", {x, y, z}] == ToSphericalCoordinates[{x, y, z}]
Wolfram Research (2012)，CoordinateTransform，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoordinateTransform.html （更新于 2015 年）.

文本

Wolfram Research (2012)，CoordinateTransform，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoordinateTransform.html （更新于 2015 年）.

CMS

Wolfram 语言. 2012. "CoordinateTransform." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2015. https://reference.wolfram.com/language/ref/CoordinateTransform.html.

APA

Wolfram 语言. (2012). CoordinateTransform. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CoordinateTransform.html 年

BibTeX

@misc{reference.wolfram_2026_coordinatetransform, author="Wolfram Research", title="{CoordinateTransform}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/CoordinateTransform.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coordinatetransform, organization={Wolfram Research}, title={CoordinateTransform}, year={2015}, url={https://reference.wolfram.com/language/ref/CoordinateTransform.html}, note=[Accessed: 15-September-2026]}