WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CoordinateTransformData[t,property]

座標変換 t のための指定された特性の値を与える．

CoordinateTransformData[t,property,{x1,x2,…,xn}]

点{x1,x2,…,xn}で評価された特性の値を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
名前  
特性  
特性値  
特性の詳細  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

CoordinateTransformData

CoordinateTransformData[t,property]

座標変換 t のための指定された特性の値を与える．

CoordinateTransformData[t,property,{x1,x2,…,xn}]

点{x1,x2,…,xn}で評価された特性の値を与える．

詳細

  • 変換は oldchart->newchart の形で与えることができる．oldchart と newchart はCoordinateChartDataから使用できる有効なチャート指定である．
  • 座標変換の標準名は{oldsys->newsys,metric,dim}の形式のトリプルである．ただし，{oldsys,metric,dim}と{newsys,metric,dim}はCoordinateChartDataから使用できる有効なチャートである．
  • CoordinateTransformData[]は，無限族中の低次元メンバーのみを含む使用可能な座標変換のリストを与える．
  • CoordinateTransformData[t]はCoordinateTransformData[t,"StandardName"]と等価である．
  • CoordinateTransformData["Properties"]は使用可能な特性のリストを返す．
  • 評価点{x1,x2,…,xn}が指定されていない場合，特性は一般に長さ n のリストが期待される純関数である．
  • 使用可能な特性
  • "Mapping"古い座標から新しい座標へのマッピング
    "MappingJacobian"マッピングのヤコビ行列
    "MappingJacobianDeterminant"マッピングのヤコビの行列式
    "InverseMappingJacobian"マッピングのヤコビ行列の逆行列
    "OrthonormalBasisRotation"チャートの正規直交基底間の回転行列
    "StandardName"Wolfram言語における標準名

例題

すべて開く すべて閉じる

例  (1)

三次元における球座標と直交座標の変換：

Wolfram Language code: CoordinateTransformData["Spherical" -> "Cartesian", "Mapping", {r, θ, φ}]
Wolfram Language code: CoordinateTransformData["Cartesian" -> "Spherical", "Mapping", {x, y, z}]

スコープ  (12)

名前  (5)

CoordinateTransformData[]は，無限族の低次元のメンバーのみを含む使用可能な座標変換のリストを返す：

Wolfram Language code: CoordinateTransformData[]//Length

ペア{oldsys->newsys,dim}は{oldsys->newsys,"Euclidean",dim}と等価である：

Wolfram Language code: CoordinateTransformData[{ "Cartesian" -> "Polar", 2}]
Wolfram Language code: CoordinateTransformData[{ "Confocal" -> "Cartesian", 2}]

評価点が与えられた場合は，第1引数から次元が省略されることがある：

Wolfram Language code: CoordinateTransformData["Cartesian" -> "Polar", "StandardName", {x, y}]
Wolfram Language code: CoordinateTransformData[{{"Confocal", {a, b}} -> "Cartesian"}, "StandardName", {μ, λ}]

座標チャートの1つが次元の指定なしにCoordinateChartDataに与えられた場合は，CoordinateTransformDataからも次元指定を省くことができる：

Wolfram Language code: CoordinateTransformData["Cartesian" -> "Polar"]

半径 r の球上の2つのグラフ間の変換：

Wolfram Language code: CoordinateTransformData[{"Stereographic" -> "Standard", {"Sphere", r}}, "Mapping", {x, y}]

特性  (1)

使用可能な特性のリストを得る：

Wolfram Language code: CoordinateTransformData["Properties"]
Wolfram Language code: Length[%]

特性値  (2)

特性値には有効な任意のWolfram言語の式を使うことができる：

Wolfram Language code: CoordinateTransformData["Cartesian" -> "Polar", "MappingJacobianDeterminant", {x, y}]
Wolfram Language code: CoordinateTransformData["Cartesian" -> "Polar", "Mapping", {x, y}]
Wolfram Language code: CoordinateTransformData["Cartesian" -> "Polar", "MappingJacobian", {x, y}]

ほとんどの特性の場合，評価点が与えられないとCoordinateTransformDataは純関数を返す：

Wolfram Language code: prop = CoordinateTransformData[{"ProlateSpheroidal" -> "Cartesian", 3}, "Mapping"]

この関数は点に適用することができる：

Wolfram Language code: prop[{u, v, w}]
Wolfram Language code: prop[{2, π / 4, 0}]

明らかに変数に依存しないある種の記述特性が，特性値として純関数を返すことは決してない：

Wolfram Language code: CoordinateTransformData[{"ProlateSpheroidal" -> "Cartesian", "Euclidean", 3}, "StandardName"]

特性の詳細  (4)

直交座標の点を極座標に変換する：

Wolfram Language code: pt = CoordinateTransformData[{"Cartesian" -> "Polar", 2}, "Mapping", {x, y}]

点を直交座標に再変換する：

Wolfram Language code: CoordinateTransformData[{"Polar" -> "Cartesian", 2}, "Mapping", pt]

変換を2つのチャートのRuleとして指定して，極座標の生成点を直交座標に変換する：

Wolfram Language code: CoordinateTransformData["Polar" -> {"Cartesian", 2}, "Mapping", {r, θ}]

極座標から直交座標へのマッピングのためのヤコビ行列を与える：

Wolfram Language code: CoordinateTransformData[{"Polar" -> "Cartesian", "Euclidean", 2}, "MappingJacobian", {r, θ}]

極座標から直交座標へのマッピングのヤコビ行列の逆行列を与える：

Wolfram Language code: CoordinateTransformData[{"Polar" -> "Cartesian", "Euclidean", 2}, "InverseMappingJacobian", {r, θ}]

2つの行列は互いに互いの逆行列である：

Wolfram Language code: %.%%//Simplify

球座標から直交座標へのマッピングの行列式を計算する：

Wolfram Language code: CoordinateTransformData[{"Spherical" -> "Cartesian", 3}, "MappingJacobianDeterminant", {r, θ, φ}]

球面基底ベクトルを直交基底ベクトルに回転する回転行列：

Wolfram Language code: rot = CoordinateTransformData["Spherical" -> "Cartesian", "OrthonormalBasisRotation"][{r, θ, φ}]

この行列が によって表現された に適用された場合，結果は である：

Wolfram Language code: rot . {Sin[θ] Cos[φ], Sin[θ] Sin[φ], Cos[θ]}//Simplify

同様に， によって表現された に適用された行列は を返す：

Wolfram Language code: rot . {-Sin[φ], Cos[φ], 0}//Simplify

アプリケーション  (1)

偏球面座標系の変数の標準名を検索する：

Wolfram Language code: CoordinateChartData[{{"OblateSpheroidal", 1}, 3}, "StandardCoordinateNames"]

直交座標への変換を使って普遍座標面を可視化する：

Wolfram Language code: trans[{ξ_, η_, φ_}] = CoordinateTransformData[{{"OblateSpheroidal", 1}, 3} -> "Cartesian", "Mapping", {ξ, η, φ}]

異なる座標の範囲を求める：

Wolfram Language code: CoordinateChartData[{{"OblateSpheroidal", 1}, 3}, "CoordinateRangeAssumptions", {ξ, η, φ} ]

と が完全範囲で変化するときの 面をプロットする：

Wolfram Language code: ParametricPlot3D[{trans[{1, η, φ}]}, {η, 0, Pi}, {φ, -π, π}, PlotStyle -> Opacity[.5]]

Noneを使って正しい色の列を求め，他の座標系についてこの処理を繰り返す：

Wolfram Language code: ParametricPlot3D[{None, trans[{ξ, Pi / 4, φ}], trans[{ξ, 3Pi / 4, φ}]}, {ξ, 0, 1.4}, {φ, -π, π}, PlotStyle -> Opacity[.8]]

最後のプロットに凡例を加える：

Wolfram Language code: ParametricPlot3D[{None, None, None, trans[{ξ, η, Pi / 4}]}, {ξ, 0, 2}, {η, 0, π}, PlotStyle -> Opacity[.5], PlotLegends -> SwatchLegend[{ξ == 1, θ == Pi / 4, θ == 3Pi / 4, φ == Pi / 4}]]

すべての部分を組み合せる：

Wolfram Language code: Show[{%, %%, %%%}, PlotRange -> 1.5]

特性と関係  (2)

CoordinateTransformData[ent,"Mapping",pt]は，事実上CoordinateTransform[ent,pt]である：

Wolfram Language code: CoordinateTransform["ProlateSpheroidal" -> "Cartesian", {1, Pi / 2, 0}] === CoordinateTransformData["ProlateSpheroidal" -> "Cartesian", "Mapping", {1, Pi / 2, 0}]

CoordinateTransformDataで，入力がチャートの座標範囲の仮定に従うことを確かめる：

Wolfram Language code: CoordinateTransformData["Spherical" -> {"Cartesian", 3}, "Mapping", {1, 0, 0}]

開始点は，縮退計量を持つ単一の点である：

Wolfram Language code: CoordinateChartData["Spherical", "Metric"][{1, 0, 0}]

2つの引数を持つ形式を使って一般式を抽出し，それを適用して単一点に拡張する：

Wolfram Language code: CoordinateTransformData["Spherical" -> {"Cartesian", 3}, "Mapping"][{1, 0, 0}]

考えられる問題  (1)

片方または両方の座標系がパラメータなしで与えられ，デフォルトパラメータを加えるとパラメータの名前が重複してしまう場合，クラッシュを防ぐためにデフォルトパラメータの片方の名前が変えられることがある：

Wolfram Language code: CoordinateTransformData[{"OblateSpheroidal" -> "ProlateSpheroidal", 3}]

両方の座標系にユーザ定義のパラメータ名がある場合は，名前の変更は行われない：

Wolfram Language code: CoordinateTransformData[{{"OblateSpheroidal", {a}} -> {"ProlateSpheroidal", {a}}, 3}]
Wolfram Research (2012), CoordinateTransformData, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoordinateTransformData.html.

テキスト

Wolfram Research (2012), CoordinateTransformData, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoordinateTransformData.html.

CMS

Wolfram Language. 2012. "CoordinateTransformData." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CoordinateTransformData.html.

APA

Wolfram Language. (2012). CoordinateTransformData. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoordinateTransformData.html

BibTeX

@misc{reference.wolfram_2026_coordinatetransformdata, author="Wolfram Research", title="{CoordinateTransformData}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CoordinateTransformData.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coordinatetransformdata, organization={Wolfram Research}, title={CoordinateTransformData}, year={2012}, url={https://reference.wolfram.com/language/ref/CoordinateTransformData.html}, note=[Accessed: 13-September-2026]}