Wolfram 语言与系统参考资料中心

Coth

Coth[z]

给出 z 的双曲余切.

背景

Coth 是双曲余切函数，是三角学中普遍使用的 Cot 圆函数的双曲类比. Coth[α] 定义为对应的双曲余弦和双曲正弦函数的比值，即 . Coth 也可以定义为，其中是自然对数 Log 的底数.
当变量是有理数的（自然）对数时，Coth 会自动计算出精确值. 当给出精确数值表达式作为变量时，Coth 可以算出任意精度的数值结果. TrigFactorList 可将包含 Coth 的表达式因式分解为包含 Sinh、Cosh、Sin 和 Cos 的单项式. 对包含 Coth 的符号表达式，其他适用的操作运算有 TrigToExp、TrigExpand、Simplify 和 FullSimplify.
Coth 自动逐项作用于列表和矩阵. 相比之下，MatrixFunction 则可用于给出整个方阵的双曲余切值（即用矩阵幂次代替普通幂次的双曲余切函数的幂级数）而不是单个矩阵元素的双曲余切值.
对小的负的 x 值 Coth[x] 趋向于而对大的正的 x 值则趋向于 . Coth 和 Cot 类似，也满足勾股恒等式，即 . 双曲余切函数的定义可由等式和扩展到复数变量上. Coth 在且是整数的这些点处取得极值 ComplexInfinity. Coth[z] 在原点处的级数展开为 $sum_(k=0)^infty(2^(2 k) TemplateBox[{{2, , k}}, BernoulliB] )/((2 k)!)z^(2 k-1)$ ，可由伯努利数 BernoulliB 构成的项表示.
Coth 的反函数是 ArcCoth. 其他相关的数学函数有 Tanh、Cot 和 Cosh.

范例

打开所有单元关闭所有单元

基本范例 (5)

数值运算：

Wolfram Language code: Coth[1.2]

在一实数子集上绘图：

Wolfram Language code: Plot[Coth[x], {x, -5, 5}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[Coth[z], {z, -π / 2 - 3I, π / 2 + 3I}, PlotLegends -> Automatic]

在 0级数展开：

Wolfram Language code: Series[Coth[x], {x, 0, 10}]

在奇点处的渐近展开式：

Wolfram Language code: Series[Coth[x], {x, 2I π, 3}]

范围 (47)

数值计算 (6)

数值运算：

Wolfram Language code: Coth[1.2]

高精度求值：

Wolfram Language code: N[Coth[12 / 10], 50]

输出精度与输入精度一致：

Wolfram Language code: Coth[1.20000000000000000000000]

Coth 可接受复数：

Wolfram Language code: Coth[2.5 + I]

在高精度条件下高效计算 Coth：

Wolfram Language code: Coth[1.2`500]//Timing

Wolfram Language code: Coth[1.2`100000];//Timing

自动逐项计算数组中每个元素的值：

Wolfram Language code: Coth[{{(π/3)I, -(π/3)I}, {0, -(π/6)I}}]

或用 MatrixFunction 计算矩阵形式的 Coth 函数：

Wolfram Language code: MatrixFunction[Coth[#]&, {{(π/3)I, -(π/3)I}, {0, -(π/6)I}}]

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: Coth[Interval[{Log[2], Log[7]}]]

Wolfram Language code: Coth[CenteredInterval[1, 1 / 100]]

Wolfram Language code: Coth[CenteredInterval[2 + 3I, (1 + I) / 100]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: Coth[Around[Sqrt[3], 0.1]]

特殊值 (5)

Coth 在纯虚数点上的值：

Wolfram Language code: Table[Coth[I(π/12)n], {n, 1, 6}]

无穷处的值：

Wolfram Language code: Coth[Infinity]

Wolfram Language code: Coth[ComplexInfinity]

Coth 的奇点：

Wolfram Language code: Coth[0]

求满足方程的值：

Wolfram Language code: f[x_] := Coth[x] - Log[3];

Wolfram Language code: sol = Solve[f[x] == 0 && 0 < x, x]

替换为值：

Wolfram Language code: xzero = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[f[x], {x, 0, 4}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

自动生成简单精确值：

Wolfram Language code: Coth[I Pi / 3]

更复杂的情形需要使用 FunctionExpand：

Wolfram Language code: Coth[I Pi / 24]

Wolfram Language code: FunctionExpand[%]

可视化 (3)

绘制 Coth 函数：

Wolfram Language code: Plot[Coth[x], {x, -5, 5}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[Coth[z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[Coth[z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

，绘制极坐标图：

Wolfram Language code:

Table[PolarPlot[Coth[k ϕ], {ϕ, -π / 2, 3π}, Sequence[Frame -> True, Exclusions -> All, FrameTicks -> {{{-1, 0, 1}, None}, {{-1, 0, 1}, None}}, PlotRange -> {{-2, 2}, {-1.5, 1.5}}, PlotLabel -> "k=" <> ToString[k]]], {k, 1, 6}]

函数属性 (12)

Coth 是针对除 0 之外的所有实数定义的：

Wolfram Language code: FunctionDomain[Coth[x], x]

复定义域：

Wolfram Language code: FunctionDomain[Coth[z], z, Complexes]

Coth 的值域是开区间之外的所有实数：

Wolfram Language code: FunctionRange[Coth[x], x, y]

Coth 是一个奇函数：

Wolfram Language code: Coth[-x]

Coth 具有镜像属性：

Wolfram Language code: FullSimplify[Coth[Conjugate[z]] == Conjugate[Coth[z]]]

Coth 不是解析函数：

Wolfram Language code: FunctionAnalytic[Coth[x], x]

但是，它是亚纯函数：

Wolfram Language code: FunctionMeromorphic[Coth[x], x]

Coth 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[Coth[x], x]

Coth 是单射函数：

Wolfram Language code: FunctionInjective[Coth[x], x]

Wolfram Language code: Plot[{Coth[x], 2}, {x, -4, 4}]

Coth 不是满射函数：

Wolfram Language code: FunctionSurjective[Coth[x], x]

Wolfram Language code: Limit[Coth[x], x -> ∞]

Wolfram Language code: Plot[{Coth[x], .5}, {x, -4, 4}]

Coth 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[Coth[x], x]

函数在零处有奇点和断点：

Wolfram Language code: FunctionSingularities[Coth[x], x]

Wolfram Language code: FunctionDiscontinuities[Coth[x], x]

Coth 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[Coth[x], x]

TraditionalForm 格式：

Wolfram Language code: Coth[x]//TraditionalForm

微分 (3)

一阶导数：

Wolfram Language code: D[Coth[x], x]

高阶导数：

Wolfram Language code: Table[D[Coth[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

第阶导的公式：

Wolfram Language code: D[Coth[x], {x, n}]

积分 (3)

Coth 的不定积分：

Wolfram Language code: Integrate[Coth[x], x]

奇函数在以原点为中心的区间上的定积分为 0：

Wolfram Language code: Integrate[Coth[x], {x, -1, 1}, PrincipalValue -> True]

更多积分：

Wolfram Language code: Integrate[Coth[x]Sinh[x], x]

Wolfram Language code: Integrate[x ^ 2Coth[x], x]

级数展开式 (3)

使用 Series 求泰勒级数展开：

Wolfram Language code: Series[Coth[x], {x, Log[2], 7}]

在周围绘制 Coth 的前三个近似值：

Wolfram Language code:

terms = Normal@Table[Series[Coth[x], {x, Log[2], m}], {m, 0, 5, 2}];
Plot[{Coth[x], terms}, {x, .5, 1.5}]

Coth 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[Coth[x], {x, 0, n}]

Coth 可被应用于幂级数：

Wolfram Language code: Coth[x + (x^2/2) + (x^3/9) + O[x]^4]

积分变换 (2)

使用 LaplaceTransform 计算拉普拉斯变换：

Wolfram Language code: LaplaceTransform[Coth[t], t, s]

FourierTransform:

Wolfram Language code: FourierTransform[Coth[ω], ω, t]

函数恒等式和化简 (6)

倍角的 Coth：

Wolfram Language code: Expand[Coth[2x], Trig -> True]

转换多倍角表达式：

Wolfram Language code: TrigExpand[Coth[4x]]

Wolfram Language code: TrigReduce[%]

和的 Coth：

Wolfram Language code: TrigExpand[Coth[x + y]]

把双曲函数的和转换为积：

Wolfram Language code: TrigFactor[Coth[x] + Coth[y]]

Wolfram Language code: TrigExpand[%]

假定变量为实数进行展开：

Wolfram Language code: ComplexExpand[Coth[x + I y]]

转换为指数：

Wolfram Language code: TrigToExp[Coth[z]]

函数表示 (4)

用 Cot 表示：

Wolfram Language code: Simplify[I Cot[I y]]

用贝塞尔函数来表示：

Wolfram Language code: Simplify[BesselI[-(1/2), x] / BesselI[(1/2), x]]

用 Jacobi 函数来表示：

Wolfram Language code: JacobiNS[z, 1]

Wolfram Language code: I JacobiSC[(π/2) - I z, 0]

用 Mathieu 函数来表示：

Wolfram Language code: (I MathieuC[1, 0, I z]/MathieuS[1, 0, I z])

应用 (5)

在复平面上绘制绝对值：

Wolfram Language code: Plot3D[Abs[Coth[x + I y]], {x, -2, 2}, {y, -2Pi, 2Pi}]

整数二次方根的牛顿迭代的解析解：

Wolfram Language code: With[{n = 3.}, Table[Sqrt[n]Coth[2 ^ k ArcTanh[Sqrt[n]]], {k, 0, 5}]]//Chop

与显式迭代的比较：

Wolfram Language code: NestList[(# + 3 / #) / 2&, 1., 5]

通过对与 Coth 的乘积进行积分，求玻色子松源（Matsubara）频率的和：

Wolfram Language code: NIntegrate[Coth[x] / (x + 2), {x, 1 + 11Pi / 2I, -1 + 11Pi / 2I, -1 - 11Pi / 2I, 1 - 11Pi / 2I, 1 + 11Pi / 2I}]//Chop

Wolfram Language code: 2Pi I Sum[Residue[Coth[x] / (x + 2), {x, k I Pi}], {k, -5, 5}]//N//Chop

磁场中与温度相关的偶极矩的布里渊 (Brillouin) 函数：

Wolfram Language code: bf[j_, T_] := (1 + (1/2j))Coth[(1 + (1/2j))(1/T)] - (1/2j)Coth[(1/2j)(1/T)]

低温行为和高温行为：

Wolfram Language code: Series[bf[j, T], {T, Infinity, 2}]

Wolfram Language code: Limit[bf[j, T], T -> 0, Assumptions -> j > 0, Direction -> -1]

用 Coth 函数作为非齐次部分，解微分方程：

Wolfram Language code: DSolve[y'[x] - x y[x] - Coth[x] == 0, y[x], x]

属性和关系 (11)

自动应用 Coth 的基本奇偶性和周期性：

Wolfram Language code: Coth[x + Pi I]

Wolfram Language code: Coth[-x]

Wolfram Language code: Coth[I x]

用 Simplify 和 FullSimplify 化简包含 Coth 的表达式：

Wolfram Language code: Simplify[2Coth[2z] / (1 + Coth[z] ^ 2)]

Wolfram Language code: FullSimplify[Coth[Log[GoldenRatio]]]

用 FunctionExpand 将特殊值表示为根式：

Wolfram Language code: FunctionExpand[Coth[I Pi / 16]]

由反函数组合：

Wolfram Language code: {Coth[ArcCoth[z]], Coth[2ArcCoth[z]], Coth[3ArcCoth[z]]}

Wolfram Language code: FunctionExpand[%]//Simplify

求解双曲函数方程：

Wolfram Language code: Reduce[Coth[z]^2 + Coth[z + 2] == 1, z]

求超越方程的数值根：

Wolfram Language code: FindRoot[Coth[z]^3 - 3Coth[z + 1] + z == 3, {z, 1}]

约化双曲函数方程：

Wolfram Language code: Reduce[Coth[a x + b] == c, x, Complexes]

积分变换：

Wolfram Language code: FourierTransform[Coth[t], t, s]//FullSimplify

从求和和积分获得 Coth：

Wolfram Language code: Sum[1 / (z ^ 2 + k ^ 2 Pi ^ 2), {k, 1, Infinity}]//Simplify

Wolfram Language code: Integrate[Csch[t] ^ 2, {t, I Pi / 2, z}]

Coth 出现在特殊函数的特例中：

Wolfram Language code: {WeierstrassP[I z, {3, 1}], JacobiCS[I z, 0]}

Coth 是一个数值函数：

Wolfram Language code: Attributes[Coth]

Wolfram Language code: NumericQ[Coth[2 + E]]

可能存在的问题 (4)

机器精度输入不足以给出正确的结果：

Wolfram Language code: Coth[10. ^ 30 I]

使用精确输入时，得到的答案是正确的：

Wolfram Language code: N[Coth[10 ^ 30I], 20]

有时需要增大 $MaxExtraPrecision 的值：

Wolfram Language code: N[Coth[10 ^ 100 I], 20]

Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[Coth[10 ^ 100I], 20]]

在无穷大处不存在幂级数，此时 Coth 有一个本质奇点：

Wolfram Language code: Series[Coth[x], {x, Infinity, 2}]

在 TraditionalForm 中，需要在自变量外加圆括号：

Wolfram Language code: coth x

Wolfram Language code: coth(x)

巧妙范例 (1)

绘制无穷大处 Coth 的图形：

Wolfram Language code:

ContourPlot[Arg[Coth[1 / (x + I y)]], {x, -1 / 4, 1 / 4}, {y, -1 / 2, 1 / 2}, Exclusions -> {}, PlotPoints -> 60, MaxRecursion -> 1, Contours -> 10]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Coth

更多信息

背景

范例

基本范例 (5)

范围 (47)

数值计算 (6)

特殊值 (5)

可视化 (3)

函数属性 (12)

微分 (3)

积分 (3)

级数展开式 (3)

积分变换 (2)

函数恒等式和化简 (6)

函数表示 (4)

应用 (5)

属性和关系 (11)

可能存在的问题 (4)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

Coth

更多信息

背景

范例

基本范例 (5)

范围 (47)

数值计算 (6)

特殊值 (5)

可视化 (3)

函数属性 (12)

微分 (3)

积分 (3)

级数展开式 (3)

积分变换 (2)

函数恒等式和化简 (6)

函数表示 (4)

应用 (5)

属性和关系 (11)

可能存在的问题 (4)

巧妙范例 (1)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX