WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DateFormat

日付形式を定めるオプションである．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
関連項目
関連するガイド
履歴
引用書式

DateFormat

DateFormat

日付形式を定めるオプションである．

詳細

  • DateFormatは，日付がどのように表示されるべきかを，表示される要素や順序を含めて示す．
  • DateFormat指定には，表示する日付要素，テキストに使用する言語，使用する文字体系，形式要素を区切るための日付区切り文字が含まれる．
  • 次は，よく使われる設定である．
  • Automatic日付形式を自動的に決定する
    "format"名前付きの日付形式（例："ISODateTime"）
    {elem1,elem2,…}含める順序付き要素
    assoc日付形式パラメータのAssociation
    localeロケールに基づくデフォルトパラメータ
  • DateFormatassoc 指定で以下のパラメータが指定できる．
  • "Elements"Automatic含める日付文字列要素
    "Language"$Languageテキスト要素の言語
    "WritingScript"Automaticテキスト要素の文字体系
    "Delimiters"Automatic日付要素間に使う区切り文字
  • DateFormatlocale は，与えられたロケールで指定されたデフォルトの日付形式情報を，要素順，言語，文字体系，区切り文字を含めて使う．ロケールは，"en_US"のようなロケール文字列，"LanguageLocale"，あるいは"Language"実体を使って指定できる．
  • "Language"lang 指定には，言語文字列（例："Spanish"），ISO-639言語コード（例："es"），"Language" Entity，あるいは"LanguageLocale" Entity実体が使える．
  • "WritingScript"script 指定には，文字体系の文字列（例："Latin"），ISO-15924文字体系コード（例： "Latn"） あるいは"WritingScript" Entity 式が使える．
  • DateFormat<|"Delimiters"delim|>指定については，delim が文字列なら各日付要素間にそれが挿入されれ（例：{elem1,delim,elem2,delim,…}），区切り文字のリストなら各要素間にそれらが散在させられる（例：{elem1,delim1,elem2,delim2,…}）．
  • DateFormatは，デフォルトで，$DateStringFormatに設定されている．
  • DateFormat要素指定はDateStringがサポートする任意の形式指定に設定できる．
  • DateFormatは，DateObject，DateIntervalおよびその他の日付コンテナの出力形式を制御する．Interpreterについては，構造化データに関連付けられた入力形式を示すために使われる．

例題

すべて開く すべて閉じる

例  (3)

省略のない日付形式を使う：

Wolfram Language code: DateObject[{2022, 4, 1, 8, 0, 14}]

ユーザ定義の形式を指定する：

Wolfram Language code: DateObject[{2022, 4, 1, 8, 0, 14}, DateFormat -> {"Day", "/", "Month", "/", "Year"}]
Wolfram Language code: DateObject[{2022, 4, 1, 8, 0, 14}, DateFormat -> {"Hour", ":", "Minute", " (on ", "Month", "/", "Day", ")"}]

与えられたロケールに基づいた日付形式を使う：

Wolfram Language code: DateObject[{2020, 8, 4, 13, 4, 32}, DateFormat -> Entity["LanguageLocale", "ja-JP"]]

特定の言語とテキスト要素がある形式を使う：

Wolfram Language code: DateObject[{2020, 12, 14}, DateFormat -> <|"Elements" -> {"DayName", ", ", "DayShort", " de ", "MonthName", " de ", "Year"}, "Language" -> Entity["Language", "Spanish"]|>]

スコープ  (1)

形式指定としてAutomaticが与えられた場合は，入力粒度が形式を決定する：

Wolfram Language code: date = {2020, 12, 21}; DateObject[date, DateFormat -> Automatic]
Wolfram Language code: DateObject[{2020, 12, 21, 8, 4}, DateFormat -> Automatic]

日付指定は，名前付きの日付形式または単一の日付要素でよい：

Wolfram Language code: DateObject[date, DateFormat -> "Date"]
Wolfram Language code: DateObject[date, DateFormat -> "DayName"]

日付形式要素の明示的なリストを使うこともできる：

Wolfram Language code: DateObject[date, DateFormat -> {"DayName", " ", "Day", " ", "MonthName", " ", "Year"} ]

DateFormat{elemi,…}はDateFormat<|"Elements"{elemi,…}|>に等しい：

Wolfram Language code: DateObject[date, DateFormat -> <|"Elements" -> {"DayName", " ", "Day", " ", "MonthName", " ", "Year"}|> ]
Wolfram Language code: DateObject[{2020, 12, 21}, "Day", "Gregorian", -6., {"DayName", " ", "Day", " ", "MonthName", " ", "Year"}]

日付形式のテキスト要素に使われる言語は，"Language" Entityを使って指定してもよい：

Wolfram Language code: DateObject[date, DateFormat -> <|"Elements" -> {"DayNameShort", " ", "Day", " ", "MonthName", " ", "Year"}, "Language" -> Entity["Language", "Serbian::9593r"]|> ]

言語の中にはよく使われる文字体系が複数あるものもあるが，これは"WritingScript" Entityで区別することができる：

Wolfram Language code: DateObject[date, DateFormat -> <|"Elements" -> {"DayNameShort", " ", "Day", " ", "MonthName", " ", "Year"}, "Language" -> Entity["Language", "Serbian::9593r"], "WritingScript" -> Entity["WritingScript", "Latin::6tr5q"]|> ]

単一の区切り文字が与えられた場合は，各日付形式要素の間にこれが挿入される：

Wolfram Language code: DateObject[date, DateFormat -> <|"Elements" -> {"DayNameShort", "Day", "MonthName", "Year"}, "Language" -> Entity["Language", "Serbian::9593r"], "WritingScript" -> Entity["WritingScript", "Latin::6tr5q"], "Delimiters" -> "-"|> ]

区切り文字のリストが与えられた場合は，それらが日付形式要素の間に散在させられる：

Wolfram Language code: DateObject[date, DateFormat -> <|"Elements" -> {"DayNameShort", "Day", "MonthName", "Year"}, "Language" -> Entity["Language", "Serbian::9593r"], "WritingScript" -> Entity["WritingScript", "Latin::6tr5q"], "Delimiters" -> {", ", " ", "/"}|> ]

ロケールを形式指定として使うと，そのロケールに適した要素，順序，言語，文字体系，区切り文字が使われる：

Wolfram Language code: DateObject[date, DateFormat -> "zh_Hant"]
Wolfram Research (2014), DateFormat, Wolfram言語関数， https://reference.wolfram.com/language/ref/DateFormat.html （2021年に更新）.

テキスト

Wolfram Research (2014), DateFormat, Wolfram言語関数， https://reference.wolfram.com/language/ref/DateFormat.html （2021年に更新）.

CMS

Wolfram Language. 2014. "DateFormat." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/DateFormat.html.

APA

Wolfram Language. (2014). DateFormat. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DateFormat.html

BibTeX

@misc{reference.wolfram_2026_dateformat, author="Wolfram Research", title="{DateFormat}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/DateFormat.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dateformat, organization={Wolfram Research}, title={DateFormat}, year={2021}, url={https://reference.wolfram.com/language/ref/DateFormat.html}, note=[Accessed: 09-September-2026]}