WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DateSelect[list,crit]

crit[datei]がTrueになるすべての日付 dateiをリストから取り出す．

DateSelect[int,crit]

DateInterval int の中で crit[datei]がTrueになるすべての日付を取り出す．

DateSelect[crit]

式に適用可能なDateSelectの演算子形を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

DateSelect

DateSelect[list,crit]

crit[datei]がTrueになるすべての日付 dateiをリストから取り出す．

DateSelect[int,crit]

DateInterval int の中で crit[datei]がTrueになるすべての日付を取り出す．

DateSelect[crit]

式に適用可能なDateSelectの演算子形を表す．

詳細

  • DateSelectは，一般に，特定の月あるいは曜日に当るというような基準を満たす日付を除去するために使われる．
  • DateSelect[list,crit]の crit は，一般に，#Month==8や#DayName==Mondayのような要素検定からなるブール式である．
  • DateSelectは，#Yearや#Monthのような名前付きSlotで表された，"Year"，"Month"，"DayName"，"Week"を含むDateValue内の使用可能なすべての日付要素をサポートする．
  • DateInterval入力については，DateSelectは日付のリストを区間で指定された暦の粒度を使って返す．

例題

すべて開く すべて閉じる

例  (4)

指定された日付のリスト内の5月の日付をすべて選択する：

Wolfram Language code: DateSelect[{DateObject[{2022, 5, 1}, "Day"], DateObject[{2023, 5, 30}, "Day"], DateObject[{2024, 6, 23}, "Day"]}, #Month == 5&]

ある年の第8週にあるすべての日付を入手する：

Wolfram Language code: DateSelect[DateRange[DateObject[{2022, 1, 1}, "Day"], DateObject[{2022, 12, 31}, "Day"]], #Week == 8&]

指定された日付範囲にあるすべての水曜日を入手する：

Wolfram Language code: DateSelect[DateInterval[{{{2020, 4, 1}, {2020, 4, 30}}}, "Day", "Gregorian", -5.], #DayName == Wednesday&]

指定された範囲にある2月4日の任意の例をすべての木曜日とともに選択する：

Wolfram Language code: DateSelect[DateRange[DateObject[{2022, 1, 1}, "Day"], DateObject[{2022, 3, 31}, "Day"]], ((#Month == 2 && #Day == 4) || #DayName == Thursday)&]

各奇数月の4日目を抽出する選択関数を作成する：

Wolfram Language code: fun = DateSelect[(OddQ[#Month] && #Day == 4)&];

特定の日付範囲に関数を適用する：

Wolfram Language code: fun[DateRange[DateObject[{2022, 1, 1}, "Day"], DateObject[{2022, 3, 31}, "Day"]]]

スコープ  (2)

選択基準はSlot式を使った参照日付要素であることが多いが，任意のブール基準を使うこともできる：

Wolfram Language code: DateSelect[DateRange[DateObject[{2022, 1, 1}, "Day"], DateObject[{2022, 3, 31}, "Day"]], StringContainsQ[DateString[#], "Tue 1"]&]

DateSelectは，暦を変換したり時刻帯を変更したりせずに要素の値を抽出する：

Wolfram Language code: dates = CalendarConvert[{DateObject[{2020, 9, 21}, "Day", "Gregorian", -5.], DateObject[{2020, 9, 22}, "Day", "Gregorian", -5.], DateObject[{2020, 9, 23}, "Day", "Gregorian", -5.]}, "Jewish"]

#Dayの値は入力の日付に関連付けられた暦によって決定される：

Wolfram Language code: DateSelect[dates, #Day > 20&]
Wolfram Language code: DateSelect[dates, #Day < 6&]

#Hourの値は時刻帯の違いを考慮することなしに検討される：

Wolfram Language code: DateSelect[{DateObject[{2020, 9, 23, 0, 54, 53.816753}, "Instant", "Gregorian", 5.], DateObject[{2020, 9, 22, 19, 54, 53.816941}, "Instant", "Gregorian", 0.], DateObject[{2020, 9, 22, 14, 54, 53.817006}, "Instant", "Gregorian", -5.]}, #Hour == 14&]

標準時刻帯を使って日付を選択する場合は，まずTimeZoneConvertを使う：

Wolfram Language code: DateSelect[TimeZoneConvert[{DateObject[{2020, 9, 23, 0, 54, 53.816753}, "Instant", "Gregorian", 5.], DateObject[{2020, 9, 22, 19, 54, 53.816941}, "Instant", "Gregorian", 0.], DateObject[{2020, 9, 22, 14, 54, 53.817006}, "Instant", "Gregorian", -5.]}, -5], #Hour == 14&]

アプリケーション  (1)

DateSelectは，スケジューリング目的や指定の月の第1月曜日といった指定のパターンと一致する日付の取出しに使うことができる：

Wolfram Language code: criteria = #DayName == Monday && #DayNameInstanceInMonth == 1&;
Wolfram Language code: DateSelect[DateInterval[{DateObject[{2020, 1, 1}], DateObject[{2020, 12, 31}]}], criteria]

特性と関係  (1)

DateSelect[dates,crit]はSelect[dates,DateValue[#,elem]==value&]と等価である：

Wolfram Language code: dates = {DateObject[{2020, 9, 20}, "Day", "Gregorian", -5.], DateObject[{2020, 9, 21}, "Day", "Gregorian", -5.], DateObject[{2020, 9, 22}, "Day", "Gregorian", -5.]};
Wolfram Language code: DateSelect[dates, #DayName == Monday&]
Wolfram Language code: Select[dates, DateValue[#, "DayName"] == Monday&]

考えられる問題  (1)

すべての暦がすべての要素を選択基準として含んでいる訳ではない：

Wolfram Language code: DateSelect[{DateObject[{1442, 2, 4}, "Day", "Islamic", -5.]}, #Quarter < 5&]
Wolfram Language code: DateValue[DateObject[{1442, 2, 4}, "Day", "Islamic", -5.], "Quarter"]

CalendarConvertを使って選択前に日付を別の暦に変換してもよい：

Wolfram Language code: DateSelect[CalendarConvert[{DateObject[{1442, 2, 4}, "Day", "Islamic", -5.]}, "Gregorian"], #Quarter < 5&]

おもしろい例題  (3)

グレゴリオ暦では，13日が金曜日になる確率は他の曜日になる確率よりも高い：

Wolfram Language code: SortBy[Tally[DateValue[DateSelect[DateInterval[{{2001, 1, 1}, {2400}}, "Day"], #Day == 13&], "DayName"]], Last]

アメリカ合衆国大統領選挙（4年ごとの11月の最初の月曜日の次の火曜日）の基準を作る：

Wolfram Language code: election = Divisible[#Year, 4] && #Month == 11 && #DayName == Tuesday && Or[#DayNameInstanceInMonth == 1 && #Day =!= 1, #DayNameInstanceInMonth == 2 && #Day == 8]&;

この基準を使って20年間のすべての大統領選挙の日を求める：

Wolfram Language code: DateSelect[DateInterval[{{2020}, {2040}}, "Day"], election]

グレゴリオ暦の世紀の初めの日は，0年始まりか1年始まりかにかかわらず，決して日曜日には始まらない：

Wolfram Language code: DateSelect[DateInterval[{{2000}, {2400}}, "Day"], Divisible[#Year, 100] && #Month == 1 && #Day == 1 && #DayName == Sunday&]
Wolfram Language code: DateSelect[DateInterval[{{2001}, {2401}}, "Day"], Divisible[#Year - 1, 100] && #Month == 1 && #Day == 1 && #DayName == Sunday&]
Wolfram Research (2020), DateSelect, Wolfram言語関数， https://reference.wolfram.com/language/ref/DateSelect.html.

テキスト

Wolfram Research (2020), DateSelect, Wolfram言語関数， https://reference.wolfram.com/language/ref/DateSelect.html.

CMS

Wolfram Language. 2020. "DateSelect." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DateSelect.html.

APA

Wolfram Language. (2020). DateSelect. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DateSelect.html

BibTeX

@misc{reference.wolfram_2026_dateselect, author="Wolfram Research", title="{DateSelect}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/DateSelect.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dateselect, organization={Wolfram Research}, title={DateSelect}, year={2020}, url={https://reference.wolfram.com/language/ref/DateSelect.html}, note=[Accessed: 06-September-2026]}