WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DayName[]

現行日の曜日を与える．

DayName[date]

指定された日の曜日を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
オプション  
CalendarType  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

DayName

DayName[]

現行日の曜日を与える．

DayName[date]

指定された日の曜日を与える．

詳細とオプション

  • 使用可能なオプション
  • CalendarType "Gregorian"日付の指定に使われた暦

例題

すべて開く すべて閉じる

例  (4)

今日の曜日を取得する：

Wolfram Language code: DayName[]

特定の日付の曜日：

Wolfram Language code: DayName[DateObject[{1959, 8, 29}]]

今日の曜日：

Wolfram Language code: DayName[Today]

時，分，秒は曜日に影響を与えない：

Wolfram Language code: {DayName[{2022, 1, 1}], DayName[{2022, 1, 1, 1, 1, 1}], DayName[{2022, 1, 1, 23, 59, 59}]}

オプション  (4)

CalendarType  (4)

ルイ16世は日曜日に生まれた：

Wolfram Language code: DayName[DateObject[{1638, 9, 5}, CalendarType -> "Gregorian"]]

ギリシャ正教の礼拝にはユリウス歴が使われている．2000年の正教のクリスマスは日曜日であった：

Wolfram Language code: DayName[DateObject[{2000, 12, 25}, CalendarType -> "Julian"]]

定義により，ヨムキプールが金曜日あるいは日曜日になることはない：

Wolfram Language code: Union[DayName[DateObject[{#, 7, 10}, CalendarType -> "Jewish"]]& /@ Range[5700, 5800]]

先発グレゴリオ暦1年1月1日は月曜日だった：

Wolfram Language code: DayName[{1, 1, 1}]

この日はユリウス暦では土曜日だった：

Wolfram Language code: DayName[{1, 1, 1}, CalendarType -> "Julian"]

アプリケーション  (2)

グレゴリオ暦の400年サイクルには整数の週が含まれる：

Wolfram Language code: DayName[DateObject[{2022, 1, 1}]] == DayName[DateObject[{2422, 1, 1}]]

400年のサイクルには97日の閏日があるので，この400年間には20871週が含まれる：

Wolfram Language code: (365 400 + 97) / 7

世紀が日曜日に始まることはない：

Wolfram Language code: DayName /@ {{2001, 1, 1}, {2101, 1, 1}, {2201, 1, 1}, {2301, 1, 1}}

世紀の始まりをどのように定義しても同じである：

Wolfram Language code: DayName /@ {{2000, 1, 1}, {2100, 1, 1}, {2200, 1, 1}, {2300, 1, 1}}

特性と関係  (2)

ConwayのDoomsday規則は，グレゴリオ暦の特定の日付，例えば2月の最終日，4番目の月の4番目の日，6番目の月の6番目の日等が常に同じ曜日になることに注目した：

Wolfram Language code: doomsdayNames[year_Integer] := DayName /@ {{year, 2, If[LeapYearQ[{year}], 29, 28]}, {year, 4, 4}, {year, 6, 6}, {year, 8, 8}, {year, 10, 10}, {year, 12, 12}, {year, 5, 9}, {year, 9, 5}, {year, 7, 11}, {year, 11, 7}}

Conwayはこれを1年の最後の審判の日と呼んだ．2017年のその日は火曜日である：

Wolfram Language code: doomsdayNames[2017]
Wolfram Language code: doomsdayNames[2018]
Wolfram Language code: doomsdayNames[2025]

ユリウス暦の10月4日木曜日の次の日は，グレゴリオ暦の10月15日金曜日だった：

Wolfram Language code: DayName[{1582, 10, 4}, CalendarType -> "Julian"]
Wolfram Language code: DayName[{1582, 10, 15}, CalendarType -> "Gregorian"]

おもしろい例題  (1)

次は西欧（グレゴリオ）暦の1つの400年サイクル全体で，13日が何曜日に当るかを計算するものである：

Wolfram Language code: Tally[DayName /@ Tuples[{Range[2001, 2400], Range[1, 12], {13}}]]

13日は金曜日に当る率が他のどの曜日に当る率よりも高い：

Wolfram Language code: TakeLargestBy[%, Last, 1]
Wolfram Research (2012), DayName, Wolfram言語関数， https://reference.wolfram.com/language/ref/DayName.html （2014年に更新）.

テキスト

Wolfram Research (2012), DayName, Wolfram言語関数， https://reference.wolfram.com/language/ref/DayName.html （2014年に更新）.

CMS

Wolfram Language. 2012. "DayName." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/DayName.html.

APA

Wolfram Language. (2012). DayName. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DayName.html

BibTeX

@misc{reference.wolfram_2026_dayname, author="Wolfram Research", title="{DayName}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/DayName.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dayname, organization={Wolfram Research}, title={DayName}, year={2014}, url={https://reference.wolfram.com/language/ref/DayName.html}, note=[Accessed: 15-September-2026]}