WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DayRange[date1,date2]

date1から date2までの範囲の日付を与える．

DayRange[date1,date2,daytype]

date1から date2までの範囲で指定された daytype の日付を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
CalendarType  
HolidayCalendar  
"IncludeEndPoints"  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

DayRange

DayRange[date1,date2]

date1から date2までの範囲の日付を与える．

DayRange[date1,date2,daytype]

date1から date2までの範囲で指定された daytype の日付を与える．

詳細とオプション

  • DayRangeはDateObject要素のリストを返す．
  • 日付は次の形で指定することができる．
  • DateObject[…]日付オブジェクト
    {y,m,d}年，月，日
    {y,m}指定された月の最初の日
    {y}y 年の最初の月の最初の日
    "string"文字列としての日付 ("Jan. 1, 2000")
    {y,m,d,h,m,s}厳密な時間
    time絶対時間指定
  • 次は，使用可能な日付タイプである．
  • All任意の暦の日付（デフォルト）
    "Weekday"週日とみなされる日付
    "Weekend"週末とみなされる日付
    "Holiday" HolidayCalendarによる祝日
    "NonHoliday"祝日ではない日付
    "BusinessDay"祝日ではない週日
    "NonBusinessDay"祝日または週末
    "WeekdayHoliday"週日の祝日
    "WeekendHoliday"週末の祝日
    "WeekendNonHoliday"祝日ではない週末
    Monday, Tuesday, …週の特定の曜日
    "EndOfMonth"指定された月の最後の日の曜日
    "BeginningOfMonth"指定された月の最初の日の曜日
  • ユダヤ暦の平日はSundayからThursdayまでである．
  • DayRangeは次のオプションを取る．
  • CalendarType"Gregorian"日付が指定された暦
    HolidayCalendar{"UnitedStates","Default"}営業日と祝日の計算に必要な部分指定と祝日の予定
    "IncludeEndPoints"{True,True}date1と date2を範囲に含めるかどうか

例題

すべて開く すべて閉じる

例  (4)

日付範囲のすべての日を出力する：

Wolfram Language code: DayRange[Yesterday, Tomorrow]

指定された曜日に当るすべての日付を出力する：

Wolfram Language code: With[{first = Take[DateList[], 2]}, DayRange[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}], Sunday]]

日付範囲の全営業日を出力する：

Wolfram Language code: DayRange[DateObject[{2022, 1, 1}], DateObject[{2022, 1, 31}], "BusinessDay"]

デフォルトの祝日予定に従って，現行年のすべての祝日を出力する：

Wolfram Language code: With[{firstday = DayRound[CurrentDate["Year"]]}, DayRange[firstday, DatePlus[firstday, {{1, "Year"}, {-1, "Day"}}], "Holiday"]]

スコープ  (1)

月の最後の日を求める：

Wolfram Language code: With[{first = Take[DateList[], 1]}, DayRange[first, DatePlus[first, {{1, "Year"}, {-1, "Day"}}], "EndOfMonth"]]

オプション  (4)

CalendarType  (1)

現行のイスラム暦の年に含まれる合衆国のすべての祝日をリストする：

Wolfram Language code: With[{first = {Nest[First, DateObject[CalendarType -> "Islamic"], 2]}}, DayRange[first, DatePlus[first, {{1, "Year"}, {-1, "Day"}}], "Holiday", CalendarType -> "Islamic"]]

HolidayCalendar  (2)

インドの祝日をリストする：

Wolfram Language code: DayRange[{2012}, {2012, 12, 31}, "Holiday", HolidayCalendar -> "India"]

1つの国の中でも市場によって祝日が異なる場合がある：

Wolfram Language code: CalendarData["UnitedStates"]
Wolfram Language code: With[{first = {2012, 4}}, DayRange[first, DatePlus[first, {{1, "Month"}}], "Holiday", HolidayCalendar -> {"UnitedStates", "NYSE"}]]
Wolfram Language code: With[{first = {2012, 4}}, DayRange[first, DatePlus[first, {{1, "Month"}}], "Holiday"]]

"IncludeEndPoints"  (1)

範囲に始めの日は加えるが最終日は加えない：

Wolfram Language code: With[{first = Take[DateList[], 2]}, DayRange[first, DatePlus[first, {{1, "Week"}}], "IncludeEndPoints" -> {True, False}]]

アプリケーション  (1)

次の合衆国大統領選挙の日（閏年11月の最初の月曜日の次の火曜日）までの日数を計算する：

Wolfram Language code: nextelection[date_] := Module[{year = 4Ceiling[date[[1]] / 4], nearest}, nearest = DatePlus[DayRange[{year, 11, 1}, {year, 11, 30}, Monday][[1]], 1]; If[QuantityMagnitude[DateDifference[date, nearest]] > 0, DayCount[date, nearest], DayCount[date, DatePlus[DayRange[{year + 4, 11, 1}, {year + 4, 11, 30}, Monday][[1]], 1]]]//Floor]; nextelection[DateList[]]

特性と関係  (3)

DayCountは同じ入力に対するDayRangeの出力リストの長さと同じである：

Wolfram Language code: With[{first = Take[DateList[], 2]}, Length[DayRange[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}], "BusinessDay", "IncludeEndPoints" -> {False, True}]] == DayCount[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}], "BusinessDay"]]

DayRangeは，All以外のタイプの日付指定を伴う場合は，Select文に等しい：

Wolfram Language code: DayRange[{2022}, {2023}, "Weekend"] == Select[DayRange[{2022}, {2023}], DayMatchQ[#, "Weekend"]&]

週末，週末ではない祝日，そして営業日が，重なり合わない3つの集合を形成する：

Wolfram Language code: With[{sets = {DayRange[{2022}, {2023}, "Holiday"], DayRange[{2022}, {2023}, "Weekend"], DayRange[{2022}, {2023}, "BusinessDay"]}}, Union@@sets == ((Join@@sets)//Sort)]

考えられる問題  (1)

週末ではない場合に限り祝日になる日もある：

Wolfram Language code: With[{first = {2012, 7}}, DayRange[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}], "Weekend"]]
Wolfram Language code: With[{first = {2012, 7}}, DayRange[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}], "Holiday", HolidayCalendar -> {"Gregorian" -> {{True&, # == 7&, 1 ≤ # ≤ 31&}}}]]
Wolfram Research (2012), DayRange, Wolfram言語関数， https://reference.wolfram.com/language/ref/DayRange.html （2025年に更新）.

テキスト

Wolfram Research (2012), DayRange, Wolfram言語関数， https://reference.wolfram.com/language/ref/DayRange.html （2025年に更新）.

CMS

Wolfram Language. 2012. "DayRange." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/DayRange.html.

APA

Wolfram Language. (2012). DayRange. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DayRange.html

BibTeX

@misc{reference.wolfram_2026_dayrange, author="Wolfram Research", title="{DayRange}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/DayRange.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dayrange, organization={Wolfram Research}, title={DayRange}, year={2025}, url={https://reference.wolfram.com/language/ref/DayRange.html}, note=[Accessed: 12-September-2026]}