WOLFRAM

Wolfram 语言与系统参考资料中心

DecisionTreeModel[]

表示一个未经训练的决策树模型.

DecisionTreeModel[hpars]

使用自定义超参数 hpars.

DecisionTreeModel[hpars,vars]

使用提供的变量 vars.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
超参数  
"MaxDepth"  
"MinGain"  
"MinLeafSamples"  
"MinSamples"  
变量  
求值  
信息  
拟合  
应用  
基本用法  
数据建模  
可能存在的问题  
互动范例  
参见
相关指南
历史
按以下格式引用：

DecisionTreeModel

DecisionTreeModel[]

表示一个未经训练的决策树模型.

DecisionTreeModel[hpars]

使用自定义超参数 hpars.

DecisionTreeModel[hpars,vars]

使用提供的变量 vars.

更多信息

  • DecisionTreeModel 将分类或回归任务建模为基于单个输入特征的一系列二元选择.
  • 决策树通常用于处理混合类型数据（分类数据和数值数据），以对非线性关系和多类别问题进行建模.
  • 在决策树中，每个内部节点代表一个测试，每个叶节点代表一个最终值.
  • 决策树的预测结果通常不是连续的.
    • 超参数
  • 可以指定以下超参数来控制决策树：
  • "MaxDepth"10每个分支的最大分裂次数
    "MinGain"0.01保持分裂所需的最小增益
    "MinLeafSamples"1每个叶节点的最小样本数
    "MinSamples"5考虑分裂所需的最小样本数
  • 分裂由模型损失来评估：回归使用均方根误差，分类使用 Gini 指数.
  • 通过调整 "MaxDepth" 参数可以直接控制模型的复杂度. 较大的值会生成更大的决策树，容易导致过拟合；较小的值会生成更小、更快的决策树，但可能导致欠拟合.
  • 只有当分裂将损失减少至少 "MinGain" 时，才会保留该分裂. 当 "MinGain" Scaled[f] 时，阈值是正在被分裂节点损失的 f 倍，而不是一个绝对值.
  • "MinSamples" 是节点被考虑进行分裂所需的最小样本数；"MinLeafSamples" 是分裂被接受时每个生成的子节点必须包含的最小样本数.
    较小的值会产生更精细的分裂，但代价是引入更多噪声.
    • 变量
  • 若未指定，变量将自动使用 x[i] 进行枚举.
  • 有效的变量规范 vars 包括：
  • n变量的数量
    symb单个变量的符号表示
    {symb1,…}符号变量列表
    • 属性
  • 可以使用 Information[PowerModel[…],prop] 提取模型属性.
  • 有效的基本属性包括：
  • "BaseType"模型基本类型
    "Name"模型名称
    "ShortName"用作标签的简短标识符
    "InputType"支持的输入类型
    "OutputType"支持的输出类型
  • 有效的数据相关属性包括：
  • "ColumnNames"输入特征的名称
    "ColumnVariableMap"列名与模型变量之间的映射
    "InputSize"输入的维度
    "OutputSize"输出的维度
    "Trainable"模型是否已完全指定并可训练
    "Trained"模型是否可以进行数值求值
    "VariableColumnMap"模型变量与列名之间的映射
    "Variables"模型变量的名称
  • 最佳模型相关的属性包括：
  • "Expression"模型表达式
    "Function"作为纯函数的模型
    "SymbolicExpression"带符号参数的模型表达式
    "TabularFunction"适用于表格行的纯函数
  • 参数相关的属性包括：
  • "Parameters"参数值（若存在）；否则为参数名称
    "ParameterValues"参数值
  • 超参数相关的属性包括：
  • "HyperparameterDefaultDomain"默认的超参数搜索域
    "HyperparameterDomain"指定的超参数搜索域
    "Hyperparameters"超参数值

范例

打开所有单元 关闭所有单元

基本范例  (3)

创建一个通用决策树模型：

Wolfram Language code: DecisionTreeModel[]

指定多个自定义超参数：

Wolfram Language code: DecisionTreeModel[<|"MaxDepth" -> 20, "MinSamples" -> 7|>]

使用 Fisher Iris 数据集训练一个决策树分类器：

Wolfram Language code: model = ModelFit[ResourceData["Sample Tabular Data: Fisher Iris"] -> "Species", DecisionTreeModel[]]

提取树：

Wolfram Language code: Information[model, "Tree"]

范围  (22)

超参数  (8)

"MaxDepth"  (2)

定义一个具有默认 "MaxDepth" 值的树：

Wolfram Language code: DecisionTreeModel[]

指定自定义值：

Wolfram Language code: DecisionTreeModel["MaxDepth" -> 3]

树的深度控制输入空间被细分的次数：

Wolfram Language code: data = {...};
Wolfram Language code: modelDefault = ModelFit[data, DecisionTreeModel[]]
Wolfram Language code: Information[modelDefault, "Tree"]

降低 "MaxDepth" 值以防止过拟合：

Wolfram Language code: model = ModelFit[data, DecisionTreeModel["MaxDepth" -> 3]]
Wolfram Language code: Information[model, "Tree"]

比较拟合结果：

Wolfram Language code: Plot[{modelDefault[x], model[x]}, {x, 0, 100}, PlotLabels -> {"Default", "MaxDepth" -> 3}, Exclusions -> None, PlotLayout -> "Row", Prolog -> Point[data]]

"MinGain"  (3)

指定分裂的最小增益：

Wolfram Language code: data = Sin[Range[100] / 10.]; model = ModelFit[data, DecisionTreeModel["MinGain" -> .1]]
Wolfram Language code: ListPlot[data, PlotFit -> model]

使用零增益以避免任何正则化：

Wolfram Language code: data = Sin[Range[100] / 10.]; model = ModelFit[data, DecisionTreeModel["MinGain" -> 0]]
Wolfram Language code: ListPlot[data, PlotFit -> model]

通过交叉验证找到 "MinGain" 的最佳值：

Wolfram Language code: model = ModelFit[Sin[Range[100] / 10.], DecisionTreeModel["MinGain" -> 0. | 0.01 | .1 | .5]]
Wolfram Language code: Information[model, "Hyperparameters"]

"MinLeafSamples"  (2)

指定每个树叶节点上的最小样本数：

Wolfram Language code: ModelFit[{...}, DecisionTreeModel["MinLeafSamples" -> 20]]
Wolfram Language code: Information[%, "Tree"]

允许节点包含单个示例：

Wolfram Language code: ModelFit[{...}, DecisionTreeModel["MinLeafSamples" -> 1]]
Wolfram Language code: Information[%, "Tree"]

"MinSamples"  (1)

指定每个树叶节点上的最小样本数：

Wolfram Language code: data = {...};
Wolfram Language code: model10 = ModelFit[data, DecisionTreeModel["MinSamples" -> 10]]
Wolfram Language code: Information[model10, "Tree"]

使用较低的值会导致树更加繁茂，叶节点更多，并有过拟合的风险：

Wolfram Language code: model2 = ModelFit[data, DecisionTreeModel["MinSamples" -> 2]]
Wolfram Language code: Information[model2, "Tree"]

比较拟合结果：

Wolfram Language code: PlotGrid[{{ListPlot[data, PlotFit -> model10], ListPlot[data, PlotFit -> model2]}}]

变量  (3)

定义具有特定变量数的树：

Wolfram Language code: DecisionTreeModel[Automatic, 2]

使用明确的变量名：

Wolfram Language code: DecisionTreeModel[Automatic, {x, y, z}]

ModelFit 将假设变量数比数据点维度少一个：

Wolfram Language code: ModelFit[{{1, 9, 55}, {1, 1, 7}, {1, 4, 25}, {8, 9, 118}, {8, 10, 124}, {8, 5, 94}}, DecisionTreeModel[]]

求值  (4)

对训练好的决策树模型进行数值运算：

Wolfram Language code: ModelFit[{...}, DecisionTreeModel[]][{1, 2}]

对训练好的决策树模型进行符号运算：

Wolfram Language code: ModelFit[{...}, DecisionTreeModel[]][{x, y}]

对决策树模型进行运算，输入为一个列表：

Wolfram Language code: ModelFit[{...}, DecisionTreeModel[]][{{1.17841, 7.0408}, {7.8774, 3.20304}, {5.12858, 7.89375}}]

未经训练的决策树无法进行符号运算：

Wolfram Language code: DecisionTreeModel[2, 1][x]

信息  (5)

查看模型的常规信息：

Wolfram Language code: Information[DecisionTreeModel[]]

有些信息只有在变量或参数完全指定后才能获取：

Wolfram Language code: Information[DecisionTreeModel[Association["Hyperparameters" -> Association["MaxDepth" -> 10, "MinSamples" -> 5, "MinLeafSamples" -> 1, "MinGain" -> 0.01]], Association["ParameterValues" -> Association["Feature" -> 1, "Threshold" -> 4, "Gain" -> 1722.25, "Size" -> 6, "FeatureType" -> "Numerical", "Left" -> Association["Value" -> Around[29., 14.], "Size" -> 3], "Right" -> Association["Value" -> Around[112., 9.16515138991168], "Size" -> 3]]], Association["Variables" -> {x}]]]

提取单个属性：

Wolfram Language code: Information[DecisionTreeModel[Association["Hyperparameters" -> Association["MaxDepth" -> 10, "MinSamples" -> 5, "MinLeafSamples" -> 1, "MinGain" -> 0.01]], Association["ParameterValues" -> Association["Feature" -> 1, "Threshold" -> 4, "Gain" -> 1722.25, "Size" -> 6, "FeatureType" -> "Numerical", "Left" -> Association["Value" -> Around[29., 14.], "Size" -> 3], "Right" -> Association["Value" -> Around[112., 9.16515138991168], "Size" -> 3]]], Association["Variables" -> {x}]], "Variables"]

检索多个属性：

Wolfram Language code: Information[DecisionTreeModel[Association["Hyperparameters" -> Association["MaxDepth" -> 10, "MinSamples" -> 5, "MinLeafSamples" -> 1, "MinGain" -> 0.01]], Association["ParameterValues" -> Association["Feature" -> 1, "Threshold" -> 4, "Gain" -> 1722.25, "Size" -> 6, "FeatureType" -> "Numerical", "Left" -> Association["Value" -> Around[29., 14.], "Size" -> 3], "Right" -> Association["Value" -> Around[112., 9.16515138991168], "Size" -> 3]]], Association["Variables" -> {x}]], {"Variables", "Hyperparameters"}]

获取有关默认模型值的信息：

Wolfram Language code: Information[DecisionTreeModel[Automatic, 2], {"Variables", "Hyperparameters"}]

拟合  (2)

使用默认超参数拟合决策树模型：

Wolfram Language code: ModelFit[{...}, DecisionTreeModel[]]

同时拟合多个模型：

Wolfram Language code: report = ModelFit[{...}, DecisionTreeModel["MaxDepth" -> 0 ;; 5], "Report"]

通过交叉验证比较不同超参数值的选择：

Wolfram Language code: report["CrossValidationChart"]

应用  (4)

基本用法  (1)

根据体温和时间预测海狸是否处于清醒状态：

Wolfram Language code: ModelFit[ResourceData["Sample Data: Beaver Body Temperatures", "Dataset"] -> {"Temperature", "Active"}, DecisionTreeModel[Automatic, bodyTemperature], "Tree"]

数据建模  (3)

获取泰坦尼克号乘客生还的数据：

Wolfram Language code: titanicData = ResourceData["Sample Tabular Data: Titanic"]

使用决策树模型来了解影响生存率的最佳预测因素：

Wolfram Language code: model = ModelFit[titanicData, DecisionTreeModel[<|"MinGain" -> .1|>]]

查看决策树：

Wolfram Language code: Information[model, "Tree"]

提取属于多种不同分布的数据：

Wolfram Language code: data = ResourceData["Sample Data: Old Faithful Eruptions"];
Wolfram Language code: ListPlot[data]

使用决策树模型，根据等待时间预测最可能的持续时间：

Wolfram Language code: model = ModelFit[data -> "WaitingTime", DecisionTreeModel[]]
Wolfram Language code: Show[ ListPlot[data], Plot[model[x], {x, Quantity[1, "Minutes"], Quantity[5, "Minutes"]}] ]

增加 "MinLeafSamples" 的值，以避免对每个分区内噪声的过度拟合：

Wolfram Language code: modelRegularized = ModelFit[data -> "WaitingTime", DecisionTreeModel[<|"MinLeafSamples" -> 30|>]]
Wolfram Language code: Show[ ListPlot[data], Plot[modelRegularized[x], {x, Quantity[1, "Minutes"], Quantity[5, "Minutes"]}] ]

从 Fisher Iris 数据集中获取数据：

Wolfram Language code: data = ResourceData["Sample Tabular Data: Fisher Iris"]

用决策树根据萼片和花瓣尺寸对品种进行分类：

Wolfram Language code: model = ModelFit[data -> "Species", DecisionTreeModel[]]

获取使用的特征：

Wolfram Language code: Union@Cases[Information[model, "TabularFunction"], Slot[name_] :> name, All]

只使用 "PetalLength" 和 "PetalWidth" 作为预测变量. 在该空间中绘制数据：

Wolfram Language code: petalData = GroupBy[data, #"Species"&, KeyTake[{"PetalWidth", "PetalLength"}]];
Wolfram Language code: ListPlot[Normal /@ petalData, AxesLabel -> {"Width", "Length"}]

在花瓣空间中的网格上计算模型预测：

Wolfram Language code: predictions = Table[model[<|"PetalWidth" -> Quantity[w, "Centimeters"], "PetalLength" -> Quantity[l, "Centimeters"], "SepalWidth" -> Quantity[1, "Centimeters"], "SepalLength" -> Quantity[1, "Centimeters"]|>], {w, 0, 2.5, .1}, {l, 0, 7, .2}];

为类别选择配色方案：

Wolfram Language code: colors = {"setosa" -> Opacity[0.2, RGBColor[0.4, 0.6, 1]], "versicolor" -> Opacity[0.2, RGBColor[0.98, 0.56, 0.17]], "virginica" -> Opacity[0.2, RGBColor[0.14, 0.8, 0.14]]};

可视化模型如何按品种划分空间：

Wolfram Language code: regions = ArrayPlot[Replace[predictions, colors, {2}], ...]

将数据与 DecisionTreeModel 映射出的域进行比较：

Wolfram Language code: Show[ListPlot[Normal /@ petalData], regions, {...}]

可能存在的问题  (2)

指定默认模型：

Wolfram Language code: DecisionTreeModel[]

若不进行拟合，DecisionTreeModel 无法求值：

Wolfram Language code: DecisionTreeModel[][{Quantity[3, "Minutes"]}]

拟合模型，以进行正常求值：

Wolfram Language code: model = ModelFit[ResourceData["Sample Data: Old Faithful Eruptions"], DecisionTreeModel[]]; model[{Quantity[3, "Minutes"]}]

DecisionTreeModel 在包含噪声的数据集上容易出现过拟合：

Wolfram Language code: data = ResourceData["Sample Data: Old Faithful Eruptions"]; model = ModelFit[data, DecisionTreeModel[]] Show[ ListPlot[data, PlotStyle -> StandardGray], Plot[model[x], {x, Quantity[1, "Minutes"], Quantity[6, "Minutes"]}] ]

超参数提供了多种方法来控制树如何分割数据并减少过拟合：

Wolfram Language code: spec = {"MaxDepth" -> 2, "MinGain" -> 2, "MinSamples" -> 100, "MinLeafSamples" -> 20};

针对每个规范拟合模型：

Wolfram Language code: models = ModelFit[ data, DecisionTreeModel[#]]& /@ spec;

将拟合结果与原始数据一起可视化：

Wolfram Language code: PlotGrid[Partition[MapThread[Show[ ListPlot[data, PlotStyle -> { StandardGray, Opacity[0.5]}], Plot[#[x], {x, Quantity[1, "Minutes"], Quantity[6, "Minutes"]}], PlotLabel -> #2 ]&, {models, spec}], 2], ImageSize -> Medium]

互动范例  (1)

比较决策树超参数的影响：

Wolfram Language code: Manipulate[Module[{model, data}, data = BlockRandom[Sin[Range[1000] / 100.] + RandomReal[{-.1, .1}, 1000]];model = N@ModelFit[data, DecisionTreeModel[<|"MaxDepth" -> depth, "MinSamples" -> samples, "MinGain" -> gain, "MinLeafSamples" -> leafsamples|>], "Function"]; ListPlot[{data, model /@ Range[1000.]}, Joined -> {False, True}, InterpolationOrder -> 0, PlotStyle -> {Opacity[.5], Thickness[0.01]}, ImageSize -> Medium] ], {{depth, 3}, 0, 10, 1}, {{samples, 10}, 1, 20, 1}, {{leafsamples, 5}, 1, 20, 1}, {gain, 0, .15}]
Wolfram Research (2026)，DecisionTreeModel，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DecisionTreeModel.html.

文本

Wolfram Research (2026)，DecisionTreeModel，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DecisionTreeModel.html.

CMS

Wolfram 语言. 2026. "DecisionTreeModel." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DecisionTreeModel.html.

APA

Wolfram 语言. (2026). DecisionTreeModel. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DecisionTreeModel.html 年

BibTeX

@misc{reference.wolfram_2026_decisiontreemodel, author="Wolfram Research", title="{DecisionTreeModel}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/DecisionTreeModel.html}", note=[Accessed: 22-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_decisiontreemodel, organization={Wolfram Research}, title={DecisionTreeModel}, year={2026}, url={https://reference.wolfram.com/language/ref/DecisionTreeModel.html}, note=[Accessed: 22-September-2026]}