DeleteColumns
DeleteColumns[tab, cspec]
cspec で指定される列を表形式データ tab から削除する．
DeleteColumns[cspec]
表形式データに適用可能なDeleteColumnsの演算子形を表す．
詳細
- DeleteColumnsは列の削除としても知られている．
- DeleteColumnsは，一般に，表形式データから列を削除することで続く処理を効率化するために使われる．
- 次は，表形式データ tab の可能な形である．
-
Tabular[…] 表形式オブジェクト Dataset[…] データ集合オブジェクト {assoc1,assoc2,…} 共通キーの連想のリスト matrix 行列 TimeSeries[…] 複数の成分を持つ時系列 EventSeries[…] 複数の成分を持つ事象系列 - 以下は，可能な列指定 cspec である．
-
name または Key[name] または ExtendedKey[…] 名前付きの列 ind 整数の番号が付いた列 {col1,…} 複数の列 cmin;;cmax;;step 列のSpan
例題
すべて開く すべて閉じる例 (1)
Tabularオブジェクトから単一の列を削除する：
tab = Tabular[{{1, 2, 3}, {4, 5, 6}}, {"a", "b", "c"}]DeleteColumns[tab, "a"]DeleteColumns[tab, {"a", "c"}]スコープ (10)
Tabularオブジェクトから1列削除する：
tab = Tabular[{{"a", "A", "α"}, {"b", "B", "β"}}, {"lower", "upper", "greek"}]DeleteColumns[tab, "upper"]DeleteColumns[tab, {"upper", "lower"}]DeleteColumns[tab, {1, 2}]Span指定も使える：
DeleteColumns[tab, 1 ;; 2]Tabularオブジェクトからすべての列を削除することもできる：
Tabular[{{1, 2}, {3, 4}, {5, 6}}]DeleteColumns[%, {1, 2}]Dimensions[%]Datasetオブジェクトから1列削除する：
ds = Dataset[{<|"c1" -> 1, "c2" -> 7.3, "c3" -> True|>, <|"c1" -> 5, "c2" -> 2.8, "c3" -> False|>}]DeleteColumns[ds, "c2"]DeleteColumns[ds, {"c2", "c1"}]data = {<|"a" -> 1, "b" -> 2, "c" -> 3|>, <|"a" -> 4, "b" -> 5, "c" -> 6|>};DeleteColumns[data, "a"]DeleteColumns[data, {"a", "c"}]mat = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}};DeleteColumns[mat, {2}]DeleteColumns[mat, {1, -1}]DeleteColumns[mat, 2 ;; 3]TimeSeriesオブジェクトの成分の一つを削除する：
ts = TimeSeries[{{1, "dog"}, {2, "cat"}, {3, "fox"}}, {Today}, ComponentKeys -> {"number", "animal"}]Tabular[ts]DeleteColumns[ts, "number"]Tabular[%]DeleteColumns[ts, {"number", "animal"}]Tabular[%]名前付きの成分があるEventSeriesオブジェクトを取る：
es = EventSeries[{"foo", "bar", "baz"}, {{.2, .6, 1.7}}, {"a"}]Tabular[es]時系列あるいは事象系列の"Timestamp"成分を削除すると，自動タイムスタンプが加えられる：
DeleteColumns[es, "Timestamp"]Tabular[%]DeleteColumnsの演算子形を使う：
ToTabular[{{1, 2}, {3, 4}, {5, 6}}, "Columns", <|"ColumnKeys" -> {"a", "b", "c"}|>]%//DeleteColumns["b"]Tabularオブジェクトを取る：
tab = Tabular[{{"a", "A", "α"}, {"b", "B", "β"}}, {"lower", "upper", "greek"}]DeleteColumns[tab, "greek"]列のキーはKeyまたはExtendedKeyで包み込むこともできる：
DeleteColumns[tab, {Key["lower"], ExtendedKey["upper"]}]拡張列キーを含むTabularオブジェクトを取得する：
tab = Tabular[{{"a", "A", "α"}, {"b", "B", "β"}}, {ExtendedKey["latin", "lower"], ExtendedKey["latin", "upper"], ExtendedKey["greek", "lower"]}]DeleteColumns[tab, ExtendedKey["latin", "upper"]]拡張キーの最後の部分キーは，それが一意的に列を特定する場合は，指定することができる：
DeleteColumns[tab, "upper"]アプリケーション (1)
パーマーペンギンについての情報を持つTabularオブジェクトを取得する：
data = ResourceData["Sample Tabular Data: Palmer Penguins"]インデックス列は余分で削除できる．削除するとデータが小さくなる：
DeleteColumns[data, "index"]特性と関係 (5)
DeleteColumnsの挙動は，残りの列からPartを使って抽出することに等しい：
tab = Tabular[RandomReal[10, {3, 5}]]DeleteColumns[tab, {1, 3, 4}]% === Part[tab, All, {2, 5}]列の任意の空リストを削除するともとのオブジェクトが返される：
mat = RandomColor[RGBColor[_, _, _], {3, 4}]DeleteColumns[mat, {}] === matDeleteColumnsはTransformColumnsの特殊バージョンである：
tab = Tabular[{{1, 2, 3}, {3, 4, 7}}, {"a", "b", "c"}]DeleteColumnsを使って選択した列を削除する：
DeleteColumns[tab, "b"]TransformColumnsを使って選択した列をNothingに設定する：
TransformColumns[tab, "b" -> Nothing]DeleteColumnsはConstructColumnsの補完操作である：
tab = Tabular[{{1, 2, 3}, {3, 4, 7}, {5, 6, 11}}, {"a", "b", "c"}]DeleteColumns[tab, {"a", "c"}]ConstructColumns[tab, {"b"}]Tabularオブジェクトを取って1列抽出する：
tab = Tabular[{{1, 2, 5}, {3, 4, 7}}, {"a", "b", "c"}]colb = tab[[All, "b"]]Tabularオブジェクトから同じ列を削除する：
DeleteColumns[tab, "b"]InsertColumnsを使って列"a"の後ろにキー"B"を使って列を挿入する：
InsertColumns[%, {"a", "B" -> colb}]テキスト
Wolfram Research (2025), DeleteColumns, Wolfram言語関数， https://reference.wolfram.com/language/ref/DeleteColumns.html （2026年に更新）.
CMS
Wolfram Language. 2025. "DeleteColumns." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/DeleteColumns.html.
APA
Wolfram Language. (2025). DeleteColumns. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DeleteColumns.html