DependentVariables

NDSolveおよびその他の関数のオプションで，与えられた方程式の従属変数と考えられるべきすべてのオブジェクトのリストを指定する．

詳細

DependentVariables->Automaticの場合，従属変数は方程式から決定される．
DependentVariables->{u₁,u₂,…}は，たとえ解が最終的に返されないとしても，解かれるべき関数を表す従属変数 u_i の完全なリストを指定する．
DependentVariables->{uspec₁,uspec₂,…}を使って従属変数の範囲を指定することができる．
uspec_iの可能な形

	u	u の範囲はRealsまたはComplexesである
	Element[u,Reals]	u の範囲はRealsである
	Element[u,Complexes]	u の範囲はComplexesである
	Element[u,{v₁,…}]	u は離散範囲{v₁,…}を持つ
	{u,u_min,u_max}	u の範囲はである
	uspec_iaction_i	uspec_iが満たされなくなった場合に action_iを実行する

例題

すべて開くすべて閉じる

例 (2)

x[t]の解のみを保存する：

Wolfram Language code:

xsol = NDSolve[{x'[t] == y[t], y'[t] == -Sin[x[t]], x[0] == 3.1, y[0] == 0}, x, {t, 0, 20}, DependentVariables -> {x, y}]

解x[t]をtの関数としてプロットする：

Wolfram Language code: Plot[x[t] /. xsol, {t, 0, 20}]

解が指定された範囲外に出たときは積分を中止する：

Wolfram Language code: sol = NDSolve[{y'[t] == y[t], y[0] == 1}, y, {t, 0, 10}, DependentVariables -> {{y[t], 0, 3}}]

Wolfram Language code: Plot[y[t] /. sol, {t, 0, 1.1}]

スコープ (4)

従属変数が1つの場合は複数の範囲を指定することができる：

Wolfram Language code: a = 1;

Wolfram Language code: NDSolve[{y'[t] == a y[t], y[0] == 2}, y, {t, 0, 1}, DependentVariables -> {{y, 0, 3}, {y, 1, 4}}]

Wolfram Language code: a = -1;

Wolfram Language code: NDSolve[{y'[t] == a y[t], y[0] == 2}, y, {t, 0, 1}, DependentVariables -> {{y, 0, 3}, {y, 1, 4}}]

従属変数が範囲外に出る場合にカスタムアクションを行う：

Wolfram Language code:

{sol, {point}} = NDSolve[{y'[t] == y[t], y[0] == 1}, y, {t, 0, 2}, DependentVariables -> {{y[t], 0, 5} :> {Print[{t, y[t]}], Sow[{t, y[t]}]}}]//Reap;

Wolfram Language code: Plot[y[t] /. sol, {t, 0, 2}, Epilog -> {PointSize[Medium], Point[point]}]

変数が指定された範囲の外に出るたびに事象アクションを実行する：

Wolfram Language code:

{sol, {points}} = NDSolve[{y''[t] == -y[t], y[0] == 0, y'[0] == 1}, y, {t, 0, 20}, DependentVariables -> {{y[t], -.5, .5} :> Sow[{t, y[t]}]}]//Reap;

Wolfram Language code: Plot[y[t] /. sol, {t, 0, 20}, Epilog -> {PointSize[Medium], Point[points]}]

変数が最初に範囲外に出た段階でメッセージを出力し積分を中止する：

Wolfram Language code:

NDSolve[{y''[t] == -y[t], y[0] == 0, y'[0] == 1}, y, {t, 0, 20}, DependentVariables -> {{y[t], -.5, .5} :> {Print[{ t, y[t]}], "StopIntegration"}}]

アプリケーション (2)

非常に大きい方程式系を設定する：

Wolfram Language code:

n = 1000;
vars = Table[Subscript[x, i][t], {i, n}];
eqns = Table[j = Mod[i, n] + 1;{Subscript[x, i]'[t] == 1 / (Subscript[x, i][t] + Subscript[x, j][t])^2, Subscript[x, i][0] == 1 / i}, {i, n}];

Wolfram Language code: Short[eqns, 3]

すべての従属変数について解くが，x₁についての解のみを保存する：

Wolfram Language code: sol = NDSolve[eqns, Subscript[x, 1], {t, 0, 100}, DependentVariables -> vars]

Wolfram Language code: Plot[Subscript[x, 1][t] /. sol, {t, 0, 100}, PlotRange -> All]

こうすると，すべての解を保存するのに比べ，メモリ消費が大幅に抑えられる：

Wolfram Language code: allsol = NDSolve[eqns, vars, {t, 0, 100}];

Wolfram Language code: {ByteCount[sol], ByteCount[allsol]}

振動する台座上の不安定な倒立振子のモデルを作る：

Wolfram Language code:

de[a_] := With[{ω = 50}, θ''[t] - (-9.8 / 10)Sin[θ[t]] == -(a / 10)ω ^ 2 Sin[ω t]Sin[θ[t]]];
ic = {θ[0] == π, θ'[0] == 0.01};

θ[t]が範囲の外に出た場合はシミュレーションを中止する：

Wolfram Language code: sol = NDSolve[{de[5], ic}, θ, {t, 0, 2}, DependentVariables -> {{θ[t], 2, 4}}]

Wolfram Language code: Plot[θ[t] /. sol, {t, 0, 1.0732}, PlotRange -> {2, 4}]

振幅が安定している場合，振動する台座上倒立振子は範囲の外には出ない：

Wolfram Language code: sol = NDSolve[{de[2], ic}, θ, {t, 0, 2}, DependentVariables -> {{θ[t], 2, 4}}];

Wolfram Language code: Plot[θ[t] /. sol, {t, 0, 2}, PlotRange -> {3.139, 3.145}]

特性と関係 (1)

変数範囲のチェックはWhenEventで行うこともできる：

Wolfram Language code: NDSolve[{y'[t] == y[t], y[0] == 1, WhenEvent[(y[t] + 10)(y[t] - 10), "StopIntegration"]}, y, {t, 0, 10}]

DependentVariablesを使った同様の範囲チェックは，これより直接的で分かりやすい：

Wolfram Language code: NDSolve[{y'[t] == y[t], y[0] == 1}, y, {t, 0, 10}, DependentVariables -> {{y[t], -10, 10}}]

WhenEventはより複雑な範囲チェックに役に立つ：

Wolfram Language code: NDSolve[{y'[t] == y[t], y[0] == 1, WhenEvent[y[t] ^ 8 - y[t] - 2, "StopIntegration"]}, y, {t, 0, 10}]

考えられる問題 (3)

従属的かつ離散的な変数は指定できない：

Wolfram Language code: NDSolve[{y'[t] == a[t]y[t], y[0] == 1, a[0] == 1}, y, {t, 0, 1}, DiscreteVariables -> {a}, DependentVariables -> {a, y}]

従属変数の範囲は離散的であってはならない：

Wolfram Language code: NDSolve[{y'[t] == y[t], y[0] == 1}, y, {t, 0, 1}, DependentVariables -> {Element[y[t], {0, 1, 2, 3}]}]

範囲指定中の変数は有効な従属変数でなければならない：

Wolfram Language code: NDSolve[{y'[t] == y[t], y[0] == 0.5}, y[t], {t, 0, 1}, DependentVariables -> {{y[t] ^ 2, 0, 1}}]

従属変数には条件を直接使う：

Wolfram Language code: NDSolve[{y'[t] == y[t], y[0] == 0.5}, y[t], {t, 0, 1}, DependentVariables -> {{y[t], -1, 1}}]

方程式中でWhenEvent式を使ってもよい：

Wolfram Language code: NDSolve[{y'[t] == y[t], WhenEvent[y[t]^2 == 1, "StopIntegration"], y[0] == 0.5}, y[t], {t, 0, 1}]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

DependentVariables

詳細

例題

例 (2)

スコープ (4)

アプリケーション (2)

特性と関係 (1)

考えられる問題 (3)

テキスト

CMS

APA

BibTeX

BibLaTeX

DependentVariables

詳細

例題

例 (2)

スコープ (4)

アプリケーション (2)

特性と関係 (1)

考えられる問題 (3)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX