WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Depth[expr]

式 expr の任意の部分を指定するために必要な指標の最大数に1を加算した数を返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一般的な式の深さ  
特別な式の深さ  
オプション  
Heads  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Depth

Depth[expr]

式 expr の任意の部分を指定するために必要な指標の最大数に1を加算した数を返す．

詳細とオプション

  • 未加工のオブジェクトの深さは1とされる．
  • オプション設定をHeads->Trueとすると，Depthは式の頭部と部分を含むようになる．

例題

すべて開く すべて閉じる

例  (3)

シンボルの深さは1である：

Wolfram Language code: Depth[a]

追加的なレベルをネストさせると深さが増す：

Wolfram Language code: Depth[{a}]
Wolfram Language code: Depth[{{a}}]

式の最も深い部分のみが深さに影響する：

Wolfram Language code: Depth[{{{a}}}]
Wolfram Language code: Depth[{{{a}, b}}]

Depthは任意の式に使うことができる：

Wolfram Language code: Depth[1 + x ^ 2]

TreeFormを使って深さを式のレベル数として可視化する：

Wolfram Language code: TreeForm[1 + x ^ 2]

スコープ  (10)

一般的な式の深さ  (5)

Depthはリストだけでなく，どのような式にも使うことができる：

Wolfram Language code: Depth[f[f[f[x]]]]

Depthは頭部を認識しない：

Wolfram Language code: Depth[f[g[h[x]]]]

シンボルと文字列の深さは1である：

Wolfram Language code: Depth[symbol]
Wolfram Language code: Depth["string"]

数の深さはすべて1である：

Wolfram Language code: Depth[12345]
Wolfram Language code: Depth[3 + I]
Wolfram Language code: Depth[(1/2)]

NumberQではない数式はより深い：

Wolfram Language code: Depth[Sqrt[2]]

デフォルトで，Depthは頭部の深さは数えない：

Wolfram Language code: Depth[h[{{{a}}}][x, y]]

オプション設定HeadsTrueを使って頭部も含むようにする：

Wolfram Language code: Depth[h[{{{a}}}][x, y], Heads -> True]

特別な式の深さ  (5)

連想の深さを計算する際にはキーは無視される：

Wolfram Language code: Depth[<|1 -> a|>]
Wolfram Language code: Depth[<|f[g[x]] -> a|>]

以下と比較する：

Wolfram Language code: Depth[{a}]

連想の深さを計算する際は値の深さが考慮される：

Wolfram Language code: Depth[<|1 -> x|>]
Wolfram Language code: Depth[<|1 -> x + y|>]

ネストした連想の深さ：

Wolfram Language code: Depth[<|1 -> <|2 -> 3|>|>]

DepthはSparseArrayオブジェクトおよび構造配列オブジェクトを対応する通常のリストのように扱う：

Wolfram Language code: Depth[SparseArray[Automatic, {1, 1, 1, 1}, 0, {1, {{0, 1}, {{1, 1, 1}}}, {x}}]]
Wolfram Language code: Depth[SymmetrizedArray[StructuredArray`StructuredData[{4, 4}, {{{1, 2} -> a, {2, 3} -> b}, Symmetric[{1, 2}]}]]]

最も生のオブジェクトの深さは1である：

Wolfram Language code: Depth[Graph[{1 -> 2, 3 -> 4}]]
Wolfram Language code: Depth[MeshRegion[{{0}, {1}, {2}, {3}}, {Line[{1, 2}], Line[{3, 4}]}]]

オプション  (1)

Heads  (1)

デフォルトで，頭部の深さは無視される：

Wolfram Language code: Depth[{f[][x], g[y][x], h[g[y]][x]}]

頭部の深さを含める：

Wolfram Language code: Depth[{f[][x], g[y][x], h[g[y]][x]}, Heads -> True]

アプリケーション  (2)

積分の結果がどれほど深くネストしているかを調べる：

Wolfram Language code: Table[Depth[Integrate[1 / (x ^ n - 1), x]], {n, 10}]

組合せの式の深さを求める [詳細]：

Wolfram Language code: combs = NestList[# /. s[x_][y_][z_] -> x[z][y[z]]&, s[s][s][s[s]][s][s], 4]
Wolfram Language code: Depth /@ combs

頭部を考慮すると深さが増す：

Wolfram Language code: Depth[#, Heads -> True]& /@ combs

結合子式のネストレベルを上げる：

Wolfram Language code: moreCombs = NestList[# /. s[x_][y_][z_] -> x[z][y[z]]&, s[s][s][s[s]][s][s], 30];
Wolfram Language code: Depth /@ moreCombs
Wolfram Language code: Depth[#, Heads -> True]& /@ moreCombs

特性と関係  (5)

Depthは，一般に，指数の最大数に1加えた長さを返す：

Wolfram Language code: Position[(1 + x)(2 + y ^ 3), _]
Wolfram Language code: Depth[(1 + x)(2 + y ^ 3)]

等価性を確かめる：

Wolfram Language code: % == Max[Length /@ %%] + 1

Depthは式の最も深い部分を考慮する：

Wolfram Language code: {Depth[{{a}, {b}}], Depth[{{a}, {f[b]}}]}

ArrayDepthは式が完全に矩形となるレベルしか考慮しない：

Wolfram Language code: {ArrayDepth[{{a}, {b}}], ArrayDepth[{{a}, {f[b]}}]}

Depthは，完全に矩形の式についてはArrayDepthより1つ大きい結果を与える：

Wolfram Language code: {Depth[{a, b}], ArrayDepth[{a, b}]}
Wolfram Language code: {Depth[{{a}, {b}}], ArrayDepth[{{a}, {b}}]}

Depth[expr]はLevel[expr,{k}]が空リストを返す最小の正のレベル k である：

Wolfram Language code: expr = a + f[x, y ^ n];
Wolfram Language code: Table[Level[expr, {k}], {k, 0, Depth[expr]}]

長さが0の関数または複合頭部が存在するなら，DepthとLevelの両方にHeadsTrueを使わなければならない：

Wolfram Language code: expr = a + f[];
Wolfram Language code: Table[Level[expr, {k}], {k, 0, Depth[expr]}]
Wolfram Language code: Table[Level[expr, {k}, Heads -> True], {k, 0, Depth[expr, Heads -> True]}]

NestListによる連続した要素はより深い：

Wolfram Language code: NestList[f, x, 5]
Wolfram Language code: Depth /@ %

考えられる問題  (3)

DepthはArrayDepthが返すより1大きい深さを返す：

Wolfram Language code: {Depth[1], ArrayDepth[1]}
Wolfram Language code: {Depth[{1, 2, 3}], ArrayDepth[{1, 2, 3}]}

Depthは連想を単一のレベルとして数える：

Wolfram Language code: Depth[<|a -> x, b -> y|>]

対応する規則のリストは2レベルとして数える：

Wolfram Language code: Depth[{a -> x, b -> y}]

複合頭部が存在する場合はDepthとPositionの関係が壊れる可能性がある：

Wolfram Language code: Depth[f[][]] == 1 + Max[Length /@ Position[f[][], _]]

DepthでHeadsTrueと設定して関係を回復する：

Wolfram Language code: Depth[f[][], Heads -> True] == 1 + Max[Length /@ Position[f[][], _]]
Wolfram Research (1988), Depth, Wolfram言語関数， https://reference.wolfram.com/language/ref/Depth.html （2018年に更新）.

テキスト

Wolfram Research (1988), Depth, Wolfram言語関数， https://reference.wolfram.com/language/ref/Depth.html （2018年に更新）.

CMS

Wolfram Language. 1988. "Depth." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2018. https://reference.wolfram.com/language/ref/Depth.html.

APA

Wolfram Language. (1988). Depth. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Depth.html

BibTeX

@misc{reference.wolfram_2026_depth, author="Wolfram Research", title="{Depth}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/Depth.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_depth, organization={Wolfram Research}, title={Depth}, year={2018}, url={https://reference.wolfram.com/language/ref/Depth.html}, note=[Accessed: 04-September-2026]}