WOLFRAM

Wolfram 语言与系统参考资料中心

Depth[expr]

给出指定 expr 的任意部分所需最大指标，并加 1.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
一般表达式的深度  
特殊表达式的深度  
选项  
Heads  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Depth

Depth[expr]

给出指定 expr 的任意部分所需最大指标，并加 1.

更多信息和选项

  • 原始对象的深度为 1.
  • 如果选项设置为 Heads->True，Depth 包括表达式的标头及其组成部分.

范例

打开所有单元 关闭所有单元

基本范例  (3)

深度为 1 的符号：

Wolfram Language code: Depth[a]

更多嵌套层次会增加深度：

Wolfram Language code: Depth[{a}]
Wolfram Language code: Depth[{{a}}]

只有表达式的最深部分会影响深度：

Wolfram Language code: Depth[{{{a}}}]
Wolfram Language code: Depth[{{{a}, b}}]

Depth 适用于任意表达式：

Wolfram Language code: Depth[1 + x ^ 2]

用e TreeForm 将深度可视化为表达式的层级数：

Wolfram Language code: TreeForm[1 + x ^ 2]

范围  (10)

一般表达式的深度  (5)

Depth 对任意表达式起作用，不仅仅是列表：

Wolfram Language code: Depth[f[f[f[x]]]]

Depth 不区别头部：

Wolfram Language code: Depth[f[g[h[x]]]]

所有数字具有深度 1：

Wolfram Language code: Depth[symbol]
Wolfram Language code: Depth["string"]

所有的数字的深度为 1：

Wolfram Language code: Depth[12345]
Wolfram Language code: Depth[3 + I]
Wolfram Language code: Depth[(1/2)]

NumberQ 结果为假的数值表达式的深度更大：

Wolfram Language code: Depth[Sqrt[2]]

默认情况下，Depth 不计入标头中的深度：

Wolfram Language code: Depth[h[{{{a}}}][x, y]]

用选项设置 HeadsTrue 计入标头中的深度：

Wolfram Language code: Depth[h[{{{a}}}][x, y], Heads -> True]

特殊表达式的深度  (5)

在计算关联的深度时忽略键：

Wolfram Language code: Depth[<|1 -> a|>]
Wolfram Language code: Depth[<|f[g[x]] -> a|>]

与下面的结果比较：

Wolfram Language code: Depth[{a}]

在计算关联的深度时考虑值的深度：

Wolfram Language code: Depth[<|1 -> x|>]
Wolfram Language code: Depth[<|1 -> x + y|>]

嵌套关联的深度：

Wolfram Language code: Depth[<|1 -> <|2 -> 3|>|>]

Depth 将 SparseArray 和结构化数组对象视为一般列表：

Wolfram Language code: Depth[SparseArray[Automatic, {1, 1, 1, 1}, 0, {1, {{0, 1}, {{1, 1, 1}}}, {x}}]]
Wolfram Language code: Depth[SymmetrizedArray[StructuredArray`StructuredData[{4, 4}, {{{1, 2} -> a, {2, 3} -> b}, Symmetric[{1, 2}]}]]]

大多数原始对象的深度为 1：

Wolfram Language code: Depth[Graph[{1 -> 2, 3 -> 4}]]
Wolfram Language code: Depth[MeshRegion[{{0}, {1}, {2}, {3}}, {Line[{1, 2}], Line[{3, 4}]}]]

选项  (1)

Heads  (1)

默认情况下，忽略标头的深度：

Wolfram Language code: Depth[{f[][x], g[y][x], h[g[y]][x]}]

考虑标头的深度：

Wolfram Language code: Depth[{f[][x], g[y][x], h[g[y]][x]}, Heads -> True]

应用  (2)

在积分结果的嵌套深度：

Wolfram Language code: Table[Depth[Integrate[1 / (x ^ n - 1), x]], {n, 10}]

求出组合表达式的深度 [更多信息]:

Wolfram Language code: combs = NestList[# /. s[x_][y_][z_] -> x[z][y[z]]&, s[s][s][s[s]][s][s], 4]
Wolfram Language code: Depth /@ combs

考虑标头的深度，深度增加：

Wolfram Language code: Depth[#, Heads -> True]& /@ combs

增大组合器表达式的嵌套层数：

Wolfram Language code: moreCombs = NestList[# /. s[x_][y_][z_] -> x[z][y[z]]&, s[s][s][s[s]][s][s], 30];
Wolfram Language code: Depth /@ moreCombs
Wolfram Language code: Depth[#, Heads -> True]& /@ moreCombs

属性和关系  (5)

Depth 一般给出最大指标的长度，并加1：

Wolfram Language code: Position[(1 + x)(2 + y ^ 3), _]
Wolfram Language code: Depth[(1 + x)(2 + y ^ 3)]

验证相等性：

Wolfram Language code: % == Max[Length /@ %%] + 1

Depth 考虑表达式的最深的部分：

Wolfram Language code: {Depth[{{a}, {b}}], Depth[{{a}, {f[b]}}]}

ArrayDepth 只考虑表达式完全为矩形的层级：

Wolfram Language code: {ArrayDepth[{{a}, {b}}], ArrayDepth[{{a}, {f[b]}}]}

对于完全为矩形的表达式，Depth 给出的结果比 ArrayDepth 的结果大 1：

Wolfram Language code: {Depth[{a, b}], ArrayDepth[{a, b}]}
Wolfram Language code: {Depth[{{a}, {b}}], ArrayDepth[{{a}, {b}}]}

Depth[expr] 是可能的最小的正的层级 k，Level[expr,{k}] 返回空列表：

Wolfram Language code: expr = a + f[x, y ^ n];
Wolfram Language code: Table[Level[expr, {k}], {k, 0, Depth[expr]}]

如果存在长度为 0 的函数或复合头部，则 Depth 和 Level 都必须使用 HeadsTrue：

Wolfram Language code: expr = a + f[];
Wolfram Language code: Table[Level[expr, {k}], {k, 0, Depth[expr]}]
Wolfram Language code: Table[Level[expr, {k}, Heads -> True], {k, 0, Depth[expr, Heads -> True]}]

NestList 中的连续元素有更大的深度：

Wolfram Language code: NestList[f, x, 5]
Wolfram Language code: Depth /@ %

可能存在的问题  (3)

Depth 返回的深度比 ArrayDepth 返回的深度大 1：

Wolfram Language code: {Depth[1], ArrayDepth[1]}
Wolfram Language code: {Depth[{1, 2, 3}], ArrayDepth[{1, 2, 3}]}

Depth 将关联视为一个层级：

Wolfram Language code: Depth[<|a -> x, b -> y|>]

将相应的规则列表视为两个层级：

Wolfram Language code: Depth[{a -> x, b -> y}]

当存在复合头部时，Depth 和 Position 之间的关系可能会崩溃：

Wolfram Language code: Depth[f[][]] == 1 + Max[Length /@ Position[f[][], _]]

在 Depth 中设置 HeadsTrue 以恢复其关系：

Wolfram Language code: Depth[f[][], Heads -> True] == 1 + Max[Length /@ Position[f[][], _]]
Wolfram Research (1988)，Depth，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Depth.html （更新于 2018 年）.

文本

Wolfram Research (1988)，Depth，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Depth.html （更新于 2018 年）.

CMS

Wolfram 语言. 1988. "Depth." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2018. https://reference.wolfram.com/language/ref/Depth.html.

APA

Wolfram 语言. (1988). Depth. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Depth.html 年

BibTeX

@misc{reference.wolfram_2026_depth, author="Wolfram Research", title="{Depth}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/Depth.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_depth, organization={Wolfram Research}, title={Depth}, year={2018}, url={https://reference.wolfram.com/language/ref/Depth.html}, note=[Accessed: 10-September-2026]}