WOLFRAM

Wolfram 语言与系统参考资料中心

f'

表示一个一元函数 f 的导数.

Derivative[n1,n2,…][f]

是一般形式，表示对 f 的第一个参数微分 n1 次，再对第二参数微分 n2 次，如此依次进行后得到的函数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Derivative

f'

表示一个一元函数 f 的导数.

Derivative[n1,n2,…][f]

是一般形式，表示对 f 的第一个参数微分 n1 次，再对第二参数微分 n2 次，如此依次进行后得到的函数.

更多信息

  • f' 等价于 Derivative[1][f]. »
  • f'' 等价于 Derivative[2][f].
  • 您可以把 Derivative 当作一个函数算子，它作用于函数得到导函数.
  • Derivative 在对 Wolfram 语言中导数未知的函数应用 D 时生成.
  • Wolfram 语言总尝试把 Derivative[n][f] 等转化为纯函数. 一旦生成 Derivative[n][f]，Wolfram 语言把它重写成 D[f[#]&,{#,n}]. 如果 Wolfram 语言找到该导数的明确值，它就返回这个值. 否则，它返回原有的Derivative 形式.
  • Derivative[-n][f] 表示 f 的 n 重不定积分.
  • Derivative[{n1,n2,…}][f] 表示 f[{x1,x2,…}] 对 xi 微分 ni 次的导数. 一般来说, f 中以列表给出的参数可以通过使用 Derivative 中相应的列表结构来处理.
  • N[f'[x]] 将给出导数的近似数值.

范例

打开所有单元 关闭所有单元

基本范例  (4)

内置函数的导数：

Wolfram Language code: {Exp'[x], Cos'[x]}

在特定点求值导数：

Wolfram Language code: {Exp'[1.5], Cos'[1.5]}

用户自定义函数的导数：

Wolfram Language code: f[x_] := Sin[x] + x ^ 2 f'[x]

这等价于 ：

Wolfram Language code: D[f[x], x]

在特定值处的导数：

Wolfram Language code: f'[0.5]

这等价于 ：

Wolfram Language code: D[f[x], x] /. x -> 0.5

二阶导数：

Wolfram Language code: Cos''[x]

三阶导数：

Wolfram Language code: Cos'''[x]

用户自定义函数的高阶导数：

Wolfram Language code: f[x_] := Sin[x] + x ^ 2 {f''[x], f'''[x]}

f' 是 Derivative[1][f] 的简写：

Wolfram Language code: Hold[f'] === Hold[Derivative[1][f]]

类似地，f'' 是 Derivative[2][f] 的简写：

Wolfram Language code: Hold[f''] === Hold[Derivative[2][f]]

范围  (7)

Derivative[k] 作用于一个函数后返回一个函数：

Wolfram Language code: Tan'
Wolfram Language code: Tan''

这也适用于用户自定义函数：

Wolfram Language code: f[x_] := x Cos[x];
Wolfram Language code: f'
Wolfram Language code: f''

例外情况是，如果导数无法计算，则原样返回输入：

Wolfram Language code: g'

在输入中，可以使用任意多个撇号：

Wolfram Language code: {Sin'[x], Sin''[x], Sin'''[x], Sin''''[x]}

在输出中，三阶及以上的符号导数不使用撇号：

Wolfram Language code: {f'[x], f''[x], f'''[x], f''''[x]}

关于不同自变量的偏导数：

Wolfram Language code: f[x_, y_] := Cos[x] Sin[y]

关于第一个自变量的偏导数：

Wolfram Language code: Derivative[1, 0][f][x, y]

在特定点求值的混合偏导数：

Wolfram Language code: Derivative[1, 2][f][3, 4]

具有列表参数的函数的偏导数：

Wolfram Language code: f[{x_, y_}] := Cos[x] Sin[y]

关于第一元素的偏导数：

Wolfram Language code: Derivative[{1, 0}][f][{x, y}]

在特定值的混合偏导：

Wolfram Language code: Derivative[{1, 2}][f][{3, 4}]

为函数定义一个导数：

Wolfram Language code: f'[x_] := If[PossibleZeroQ[x], N[0, Precision[x]], (x Cos[x] - Sin[x]) / x ^ 2];
Wolfram Language code: f'[0.]
Wolfram Language code: Plot[f'[x], {x, -10, 10}]

为函数定义偏导数：

Wolfram Language code: Derivative[1, 0][f][x_, y_] := y; Derivative[0, 1][f][x_, y_] := x;

这个实际上定义梯度：

Wolfram Language code: D[f[x, y], {{x, y}}]

显示矢量场：

Wolfram Language code: VectorPlot[%, {x, -2, 2}, {y, -2, 2}]

有负整数次的Derivative 可以积分：

Wolfram Language code: Derivative[-2][Function[x, x ^ n]]
Wolfram Language code: Integrate[x ^ n, x, x]

属性和关系  (4)

Derivative 计算关于输入参数的导数，而不是关于任何特定变量的导数：

Wolfram Language code: Sinh'

任何求值点只是代入所得导数函数中：

Wolfram Language code: {Sinh'[1], Sinh'[x], Sinh'[a x]}

这与 D 不同，后者计算表达式中关于特定变量的偏导数：

Wolfram Language code: {D[Sinh[1], x], D[Sinh[x], x], D[Sinh[a x], x]}

未知函数的偏导数用 Derivative 表示：

Wolfram Language code: D[f[x], x]
Wolfram Language code: %//FullForm

这也扩展到多元函数：

Wolfram Language code: D[g[x, y], y]
Wolfram Language code: %//FullForm

多元函数的偏导数用一个带有整数序列的 Derivative 表达式表示：

Wolfram Language code: D[f[x, y], {x, 2}, y]
Wolfram Language code: %//InputForm

关于列表的单变量函数的偏导数用一个带有整数列表的 Derivative 表达式表示：

Wolfram Language code: D[g[{x, y}], {x, 2}, y]
Wolfram Language code: %//InputForm

使用 N 求导数的数值近似：

Wolfram Language code: Zeta'[3]
Wolfram Language code: N[Zeta'[3]]
Wolfram Research (1988)，Derivative，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Derivative.html （更新于 2002 年）.

文本

Wolfram Research (1988)，Derivative，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Derivative.html （更新于 2002 年）.

CMS

Wolfram 语言. 1988. "Derivative." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2002. https://reference.wolfram.com/language/ref/Derivative.html.

APA

Wolfram 语言. (1988). Derivative. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Derivative.html 年

BibTeX

@misc{reference.wolfram_2026_derivative, author="Wolfram Research", title="{Derivative}", year="2002", howpublished="\url{https://reference.wolfram.com/language/ref/Derivative.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_derivative, organization={Wolfram Research}, title={Derivative}, year={2002}, url={https://reference.wolfram.com/language/ref/Derivative.html}, note=[Accessed: 10-September-2026]}