WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Diagonal[m]

行列 m の主対角上の要素のリストを返す．

Diagonal[m,k]

m の k 次の対角上の要素を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
特殊行列  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

Diagonal

Diagonal[m]

行列 m の主対角上の要素のリストを返す．

Diagonal[m,k]

m の k 次の対角上の要素を返す．

詳細

  • Diagonal[m]は，m が正方行列ではない場合にも使える．
  • k が正の場合，Diagonal[m,k]は主対角の上の対角を返す．Diagonal[m,-k]は下の対角を返す．

例題

すべて開く すべて閉じる

例  (4)

行列の対角要素を返す：

Wolfram Language code: {{a, b, c}, {d, e, f}, {g, h, i}}//MatrixForm
Wolfram Language code: Diagonal[%]

優対角を得る：

Wolfram Language code: Diagonal[{{a, b, c}, {d, e, f}, {g, h, i}}, 1]

劣対角を得る：

Wolfram Language code: Diagonal[{{a, b, c}, {d, e, f}, {g, h, i}}, -1]

非正方行列の対角要素を返す：

Wolfram Language code: {{1, 2, 3, 4}, {5, 6, 7, 8}, {9, 10, 11, 12}}//MatrixForm
Wolfram Language code: Diagonal[%]

スコープ  (12)

基本的な用法  (7)

機械精度の行列の対角を求める：

Wolfram Language code: Diagonal[{{1.1, 12.2, 3.23}, {2.3, 42.2, 35.3}, {1.2, 3.1, 2.3}}]

複素行列の優対角：

Wolfram Language code: Diagonal[{{1. + I, 2, 3 - 2 I}, {0, 4 π, 5I}, {E, 0, 6}}, 1]

厳密行列の対角：

Wolfram Language code: Diagonal[{{2, 3, 1}, {2, 2, 1}, {3, 1, 2}}]

任意精度の行列の対角：

Wolfram Language code: Diagonal[RandomReal[1, {3, 3}, WorkingPrecision -> 20]]

記号行列の主対角の2つ下の対角：

Wolfram Language code: Diagonal[{{a, b, c, d}, {e, f, g, h}, {i, j, k, l}, {m, n, o, p}}, -2]

Diagonalは非正方行列を取る：

Wolfram Language code: {{3, 2, 2}, {2, 3, -2}, {4, 2, 1}, {3, 7, 9}}//MatrixForm
Wolfram Language code: Diagonal[%]

大きい行列の対角の抽出は効率的である：

Wolfram Language code: m = RandomReal[{1, 9}, {50, 100}];
Wolfram Language code: Diagonal[m] //Timing

特殊行列  (5)

疎な行列の対角は疎なリストとして返される：

Wolfram Language code: SparseArray[{{1, 1} -> 12, {3, 2} -> 32, {3, 3} -> 33}, {3, 3}]
Wolfram Language code: Diagonal[%]

結果を通常のリストに変換する：

Wolfram Language code: Normal[%]

疎な配列のすべての対角を得る：

Wolfram Language code: s = SparseArray[{Band[{1, 1}] -> x, Band[{2, 1}] -> y, Band[{1, 2}] -> z}, {3, 3}];
Wolfram Language code: s//MatrixForm
Wolfram Language code: Table[Diagonal[s, k], {k, -2, 2}]

結果を通常のリストに変換する：

Wolfram Language code: Normal[%]

構造化行列の対角：

Wolfram Language code: SymmetrizedArray[{{1, 2} -> 2, {2, 2} -> I, {3, 1} -> 4, {4, 4} -> 2}, {4, 4}, Symmetric[All]]
Wolfram Language code: Diagonal[%]
Wolfram Language code: QuantityArray[{{1, 2}, {3, 4}, {5, 6}}, {"Meters", "Seconds"}]
Wolfram Language code: Diagonal[%]

IdentityMatrixの対角はすべて1である：

Wolfram Language code: Diagonal[IdentityMatrix[15]]

HilbertMatrixの対角：

Wolfram Language code: Diagonal[HilbertMatrix[13]]

アプリケーション  (3)

行列を対角部分と非対角部分の和として表す：

Wolfram Language code: MatrixForm[m = Array[Subscript[a, ##]&, {4, 4}]]

対角部分：

Wolfram Language code: md = DiagonalMatrix[Diagonal[m]];

もとの行列とその対角部分との差として対角を構築する：

Wolfram Language code: mo = m - md;

2つの行列が希望する特性を有することを確認する：

Wolfram Language code: Map[MatrixForm, {md, mo}]

行列 がそのジョルダン(Jordan)分解を使って非対角化可能かどうかを見る：

Wolfram Language code: m = {{27, 48, 81}, {-6, 0, 0}, {1, 0, 3}};
Wolfram Language code: {s, j} = JordanDecomposition[m]

ジョルダン形 の優対角は0のみからなるわけではないので， は非対角化できない：

Wolfram Language code: Diagonal[j, 1]

DiagonalizableMatrixQを直接呼び出して確かめる：

Wolfram Language code: DiagonalizableMatrixQ[m]

ジョルダン分解を使って行列 の固有値を求める：

Wolfram Language code: m = {{27, 48, 81}, {-6, 0, 0}, {1, 0, 3}};
Wolfram Language code: {s, j} = JordanDecomposition[m]

ジョルダン形 の対角は固有値を与える：

Wolfram Language code: Diagonal[j]

Eigenvaluesを直接呼び出して確認する：

Wolfram Language code: Eigenvalues[m]

特性と関係  (7)

DiagonalMatrixQ[m]がTrueのときかつそのときに限りDiagonalMatrix[Diagonal[m]]==m である：

Wolfram Language code: m = (| | | | - | - | | a | 0 | | 0 | d |);
Wolfram Language code: {DiagonalMatrix[Diagonal[m]] == m, DiagonalMatrixQ[m]}
Wolfram Language code: m = (| | | | - | - | | 1 | 2 | | 3 | 4 |);
Wolfram Language code: {DiagonalMatrix[Diagonal[m]] == m, DiagonalMatrixQ[m]}

行列 m について，Tr[m]はDiagonalとTotalの組合せとして表すことができる：

Wolfram Language code: m = RandomReal[1, {5, 5}];
Wolfram Language code: Tr[m] == Total[Diagonal[m]]

n×n 行列についてのDiagonal[m,k]は，1-n<=k<=n-1のとき非負の結果を与える：

Wolfram Language code: (m = Table[j - i, {i, 4}, {j, 4}])//MatrixForm
Wolfram Language code: Table[Diagonal[m, k], {k, -4, 4}]

Diagonal[m,k]はUpperTriangularize[m,k]の最も低い非零の対角を与える：

Wolfram Language code: m = (⁠| | | | | | - | - | - | - | | 3 | 8 | 7 | 6 | | 8 | 8 | 1 | 3 | | 8 | 6 | 6 | 8 | | 1 | 7 | 3 | 7 |⁠);
Wolfram Language code: {Diagonal[m, 2], UpperTriangularize[m, 2]//MatrixForm}

同様に，Diagonal[m,k]はLowerTriangularize[m,k]の最も高い非零の対角を与える：

Wolfram Language code: {Diagonal[m, 1], LowerTriangularize[m, 1]//MatrixForm}

Bandを使って行列をその対角から再構築することができる：

Wolfram Language code: m = RandomReal[1, {5, 5}];
Wolfram Language code: m == SparseArray[Table[Band[If[k >= 0, {1, 1 + k}, {1 - k, 1}]] -> Diagonal[m, k], {k, -4, 4}]]

行列 m については，Diagonal[m]はTr[m,List]と同じである：

Wolfram Language code: m = (⁠| | | | | - | - | - | | 1 | 2 | 3 | | 4 | 5 | 6 |⁠);
Wolfram Language code: Diagonal[m]
Wolfram Language code: Tr[m, List]

正方行列 m については，Diagonal[m]はTranspose[m,{1,1}]と同じである：

Wolfram Language code: m = (⁠| | | | | - | - | - | | 1 | 2 | 3 | | 4 | 5 | 6 | | 7 | 8 | 9 |⁠);
Wolfram Language code: Diagonal[m]
Wolfram Language code: Transpose[m, {1, 1}]

おもしろい例題  (1)

下対角と上対角：

Wolfram Language code: Grid@Table[Diagonal[Table[x, {10}, {10}], k], {k, -9, 9}]
Wolfram Research (2007), Diagonal, Wolfram言語関数， https://reference.wolfram.com/language/ref/Diagonal.html.

テキスト

Wolfram Research (2007), Diagonal, Wolfram言語関数， https://reference.wolfram.com/language/ref/Diagonal.html.

CMS

Wolfram Language. 2007. "Diagonal." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Diagonal.html.

APA

Wolfram Language. (2007). Diagonal. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Diagonal.html

BibTeX

@misc{reference.wolfram_2026_diagonal, author="Wolfram Research", title="{Diagonal}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Diagonal.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_diagonal, organization={Wolfram Research}, title={Diagonal}, year={2007}, url={https://reference.wolfram.com/language/ref/Diagonal.html}, note=[Accessed: 15-September-2026]}