WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DimensionalCombinations[{pq1,pq2,…}]

無次元である物理量 pqiのリストの可能な組合せを返す．

DimensionalCombinations[{pq1,pq2,…},dim]

物理量 dim の次元にマッチする物理量 pqiのリストの可能な組合せを返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
GeneratedParameters  
IncludeQuantities  
アプリケーション  
特性と関係  
考えられる問題  
インタラクティブな例題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

DimensionalCombinations

DimensionalCombinations[{pq1,pq2,…}]

無次元である物理量 pqiのリストの可能な組合せを返す．

DimensionalCombinations[{pq1,pq2,…},dim]

物理量 dim の次元にマッチする物理量 pqiのリストの可能な組合せを返す．

詳細とオプション

  • 物理量は，有効なQuantityVariableオブジェクト，"PhysicalQuantity"実体，あるいは物理量の文字列でよい．
  • dim はQuantityVariableオブジェクトでよい．また，QuantityVariableオブジェクトあるいはその導関数の組合せでもよい．
  • 解は，純粋に数学的に，単位次元での物理量成分によって決定され，物理的な有意性を保証しない．
  • 物理次元には，"AmountUnit"，"AngleUnit"，"ElectricCurrentUnit"，"InformationUnit"，"LengthUnit"，"LuminousIntensityUnit"，"MassUnit"，"MoneyUnit"，"SolidAngleUnit"，"TemperatureDifferenceUnit"，"TemperatureUnit"，"TimeUnit"が含まれる．
  • 無次元の物理量は解に使用されない．
  • 与えられるオプション
  • GeneratedParameters C生成されたパラメータにどのように名前を付けるか
    IncludeQuantities {}追加で含む数量
  • GeneratedParametersは，パラメータのない解のリストを返すオプションNoneを取る．
  • IncludeQuantitiesには，組合せに含む数量値と定数が使える．
  • IncludeQuantitiesの設定"PhysicalConstants"には，数量Quantity["BoltzmannConstant"]，Quantity["ElectricConstant"]，Quantity["GravitationalConstant"]，Quantity["MagneticConstant"]，Quantity["PlanckConstant"]，Quantity["SpeedOfLight"]が含まれる．

例題

すべて開く すべて閉じる

例  (1)

エネルギーと等しい次元の物理量の組合せを見極める：

Wolfram Language code: DimensionalCombinations[{"MassDensity", "Radius", "Time"}, "Energy"]

結果として無次元の式に結なる物理量の組合せすべてを求める：

Wolfram Language code: DimensionalCombinations[{QuantityVariable["V", "ElectricPotential"], QuantityVariable["I", "ElectricCurrent"], QuantityVariable["R", "ElectricResistance"]}]

物理量の集合で，無次元の式が可能であるかどうかを調べる：

Wolfram Language code: DimensionalCombinations[{QuantityVariable["Force"], QuantityVariable["Distance"], QuantityVariable["ElectricCharge"]}]

スコープ  (3)

QuantityVariableオブジェクトあるいは物理量の文字列の任意の組合せを使う：

Wolfram Language code: pqs = {QuantityVariable["E", "Energy"], QuantityVariable["MassDensity"], "Radius", QuantityVariable["Time"]}; DimensionalCombinations[pqs]

ターゲットの物理次元は，物理量の組合せとして指定することができる：

Wolfram Language code: DimensionalCombinations[{QuantityVariable["m", "Mass"], QuantityVariable["l", "Length"], QuantityVariable["t", "Time"], QuantityVariable["e", "ElectricCharge"]}, QuantityVariable["V", "ElectricPotential"] * QuantityVariable["K", "Energy"] ^ 2 / QuantityVariable["m", "Mass"]]

Derivativeオブジェクトを式に含むこともできる：

Wolfram Language code: DimensionalCombinations[{QuantityVariable["m", "Mass"], QuantityVariable["l", "Length"], QuantityVariable["t", "Time"], QuantityVariable["e", "ElectricCharge"]}, QuantityVariable["RadiantFluxDensity"]''[QuantityVariable["Time"]] / QuantityVariable["Speed"]]

QuantityVariable式に含まれる"PhysicalQuantity"実体も使うことができる：

Wolfram Language code: DimensionalCombinations[{QuantityVariable[Entity["PhysicalQuantity", "ElectricPotential"]], QuantityVariable["I", Entity["PhysicalQuantity", "ElectricCurrent"]], Entity["PhysicalQuantity", "ElectricResistance"]}]

オプション  (5)

GeneratedParameters  (3)

パラメータに別の記号を使う：

Wolfram Language code: DimensionalCombinations[{"Force", "Distance", "ElectricCharge", "ElectricCharge"}, IncludeQuantities -> {"ElectricConstant"}, GeneratedParameters -> K]

デフォルトで，一般的な解が返される：

Wolfram Language code: DimensionalCombinations[ {QuantityVariable["t", "Time"], QuantityVariable["a", "Acceleration"], QuantityVariable["F", "Force"], QuantityVariable["P", "Momentum"], QuantityVariable["E", "Energy"]}, QuantityVariable["x", "Length"]]

GeneratedParameters->Noneを使って特定の解を得る：

Wolfram Language code: DimensionalCombinations[ {QuantityVariable["t", "Time"], QuantityVariable["a", "Acceleration"], QuantityVariable["F", "Force"], QuantityVariable["P", "Momentum"], QuantityVariable["E", "Energy"]}, QuantityVariable["x", "Length"], GeneratedParameters -> None]

GeneratedParameters->NoneをIncludeQuantitiesと使うと，QuantityVariableとQuantityのオブジェクトを組み合せることができる：

Wolfram Language code: DimensionalCombinations[ {QuantityVariable["a", "Acceleration"], QuantityVariable["F", "Force"], QuantityVariable["P", "Momentum"]}, GeneratedParameters -> None, IncludeQuantities -> {Quantity["Meters"], Quantity["Seconds"]}]

IncludeQuantities  (2)

結果に追加的な定数とQuantityオブジェクトを含む：

Wolfram Language code: DimensionalCombinations[{"Force", "Distance", "ElectricCharge"}, IncludeQuantities -> {"ElectricConstant"}]
Wolfram Language code: DimensionalCombinations[{"Force"}, IncludeQuantities -> {Quantity["ElectricConstant"], Quantity[1, "Meters"], "ElementaryCharge"}]

設定"PhysicalConstants"を使って，物理定数の標準的な集合を含む：

Wolfram Language code: DimensionalCombinations[{"Force", "Distance", "ElectricCharge"}, IncludeQuantities -> "PhysicalConstants"]

アプリケーション  (4)

公式E^2 - p^2 == m^2に欠落している物理定数を求める：

Wolfram Language code: sol1 = DimensionalCombinations[{"Mass", "Energy"}, IncludeQuantities -> "PhysicalConstants"]
Wolfram Language code: sol2 = DimensionalCombinations[{"Momentum", "Energy"}, IncludeQuantities -> "PhysicalConstants"]

定数の値について解く：

Wolfram Language code: Reduce[{C[1] == -1, -C[1] - 2C[2] == 1}, {C[1], C[2]}]
Wolfram Language code: Reduce[{2C[1] == -1, -2C[1] - 4C[2] == 1}, {C[1], C[2]}]

正しい指数を挿入する：

Wolfram Language code: sol1 = sol1 /. {C[1] -> -1, C[2] -> 0}
Wolfram Language code: sol2 = sol2 /. {C[1] -> -1 / 2, C[2] -> 0}

不要な定数を取り除く：

Wolfram Language code: sol1 /. C[3] -> 4 /. Quantity[1, "ElectricConstant"^2*"MagneticConstant"^2*"SpeedOfLight"^8] -> Quantity[1, "SpeedOfLight"^2]
Wolfram Language code: sol2 /. C[3] -> 1 /. Quantity[1, Sqrt["ElectricConstant"]*Sqrt["MagneticConstant"]*"SpeedOfLight"^2] -> Quantity[1, "SpeedOfLight"]

クライバー(Kleiber)の法則 を平衡にするのに必要な定数の次元を求める：

Wolfram Language code: sol = DimensionalCombinations[{"MetabolicRate", "Mass"}, IncludeQuantities -> {Quantity["Kilograms"], Quantity["Days"]}]

質量指数の値について解く：

Wolfram Language code: Reduce[-3 C[1] + 1 == 3 / 4, C[1]]
Wolfram Language code: sol /. {C[2] -> -1, C[1] -> 1 / 12}

以下の物理量のみを使って，爆風の力を推定する：

Wolfram Language code: pqs = {QuantityVariable["Energy"], QuantityVariable["MassDensity"], QuantityVariable["Radius"], QuantityVariable["Time"]};

無次元の組合せを構築する：

Wolfram Language code: DimensionalCombinations[pqs]

与えられた時間におけるパラメータの値から，爆発のエネルギーを推定する：

Wolfram Language code: massdensity = Quantity[1.2, "Kilograms" / "Meters" ^ 3]; radius = Quantity[80, "Meters"]; time = Quantity[0.006, "Seconds"];
Wolfram Language code: energy = (massdensity radius^5/time^2)
Wolfram Language code: UnitConvert[energy, "KilotonsOfTNT"]

株式の価格，サイズ，ベットの費用，取引量，株式の変動性に依存する，考えられる無次元の価格影響関数を定義する：

Wolfram Language code: stockprice = QuantityVariable["P", "Money" / IndependentPhysicalQuantity["shares"]]; betsize = QuantityVariable["Q", IndependentPhysicalQuantity["shares"]]; tradingvolume = QuantityVariable["V", IndependentPhysicalQuantity["shares"] / "Time"]; stockvolatility = QuantityVariable[Superscript["σ", "2"], 1 / Sqrt["Time"]]; betcost = QuantityVariable["C", "Money"];

一般的な無次元の組合せを求める：

Wolfram Language code: DimensionalCombinations[{stockprice, betsize, tradingvolume, stockvolatility, betcost}]

特定の例に決定する：

Wolfram Language code: DimensionalCombinations[{stockprice, betsize, tradingvolume, stockvolatility, betcost}, GeneratedParameters -> None]

特性と関係  (1)

無次元定数についての公式は，物理量から構築できる：

Wolfram Language code: FormulaLookup[All, 10, RequiredPhysicalQuantities -> {"Length", "Speed", "DynamicViscosity", "MassDensity"}]
Wolfram Language code: FormulaData[{"ReynoldsNumber", "DynamicViscosity"}]
Wolfram Language code: DimensionalCombinations[{QuantityVariable["l", "Length"], QuantityVariable["v", "Speed"], QuantityVariable["η", "DynamicViscosity"], QuantityVariable["ρ", "MassDensity"]}, GeneratedParameters -> None]

考えられる問題  (5)

有効な物理量のみが使える：

Wolfram Language code: DimensionalCombinations[{QuantityVariable["ElectricPotential"], QuantityVariable["ElectricCurrent"], QuantityVariable["Ohms"]}]

無次元の数量は結果から削除される：

Wolfram Language code: DimensionalCombinations[{QuantityVariable["Φ", "RadiantFluxDensity"], QuantityVariable["T", "Temperature"], QuantityVariable["ϵ", "Emissivity"]}, IncludeQuantities -> {Quantity["StefanBoltzmannConstant"]}]

有効な定数のみが使われる：

Wolfram Language code: DimensionalCombinations[{"Force", "Distance", "ElectricCharge"}, IncludeQuantities -> {"ElectricConstant", "Foo"}]

角度単位と物理量は，無次元として取り扱われない：

Wolfram Language code: DimensionalCombinations[{"Area", "Angle", "Radius"}]
Wolfram Language code: DimensionalCombinations[{"Area", "Angle", "Radius"}, IncludeQuantities -> {Quantity["AngularDegrees"]}]

返された組合せが無次元であっても，その大きさが1であるとは限らない：

Wolfram Language code: DimensionalCombinations[{QuantityVariable["E", "Energy"], QuantityVariable["λ", "Wavelength"]}, IncludeQuantities -> {Quantity["PlankConstant"], Quantity["SpeedOfLight"]}]
Wolfram Language code: DimensionalCombinations[{QuantityVariable["E", "Energy"], QuantityVariable["λ", "Wavelength"]}, IncludeQuantities -> {Quantity["ReducedPlankConstant"], Quantity["SpeedOfLight"]}]

インタラクティブな例題  (1)

物理量と物理定数の集合について，可能な無次元の組合せをすべて調べる：

Wolfram Language code: solutions = DimensionalCombinations[{ QuantityVariable["E", "Energy"], QuantityVariable["f", "Frequency"], QuantityVariable["m", "Mass"], QuantityVariable["T", "Temperature"] }, IncludeQuantities -> "PhysicalConstants", GeneratedParameters -> None]; Manipulate[solutions[[i]], {{i, 1, "Solution"}, 1, Length[solutions], 1}, SaveDefinitions -> True]

おもしろい例題  (2)

電磁物理量の可能な無次元の組合せを調べる：

Wolfram Language code: DimensionalCombinations[{ QuantityVariable["Q", "ElectricCharge"], QuantityVariable["V", "ElectricPotential"], QuantityVariable["I", "ElectricCurrent"], QuantityVariable["R", "ElectricResistance"], QuantityVariable["C", "ElectricCapacitance"], QuantityVariable["L", "MagneticInductance"], QuantityVariable["M", "MagneticMemristance"], QuantityVariable["Φ", "MagneticFlux"]}, GeneratedParameters -> None]

物理量から微細構造定数の因数を導き出す：

Wolfram Language code: sol = DimensionalCombinations[{}, IncludeQuantities -> { Quantity["SpeedOfLight"], Quantity["PlanckConstant"], Quantity["ElectricConstant"], Quantity["ElementaryCharge"] }, GeneratedParameters -> None]
Wolfram Language code: UnitConvert[sol[[1]], "SIBase"] ^ 2 / Quantity["FineStructureConstant"]
Wolfram Research (2014), DimensionalCombinations, Wolfram言語関数， https://reference.wolfram.com/language/ref/DimensionalCombinations.html （2018年に更新）.

テキスト

Wolfram Research (2014), DimensionalCombinations, Wolfram言語関数， https://reference.wolfram.com/language/ref/DimensionalCombinations.html （2018年に更新）.

CMS

Wolfram Language. 2014. "DimensionalCombinations." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2018. https://reference.wolfram.com/language/ref/DimensionalCombinations.html.

APA

Wolfram Language. (2014). DimensionalCombinations. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DimensionalCombinations.html

BibTeX

@misc{reference.wolfram_2026_dimensionalcombinations, author="Wolfram Research", title="{DimensionalCombinations}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/DimensionalCombinations.html}", note=[Accessed: 07-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_dimensionalcombinations, organization={Wolfram Research}, title={DimensionalCombinations}, year={2018}, url={https://reference.wolfram.com/language/ref/DimensionalCombinations.html}, note=[Accessed: 07-October-2026]}