WOLFRAM

Wolfram 语言与系统参考资料中心

DimensionalCombinations[{pq1,pq2,…}]

返回无量纲物理量 pqi 的列表的可能组合.

DimensionalCombinations[{pq1,pq2,…},dim]

返回匹配物理量维度 dim 的物理量 pqi 的列表的可能组合.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
GeneratedParameters  
IncludeQuantities  
应用  
属性和关系  
可能存在的问题  
互动范例  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

DimensionalCombinations

DimensionalCombinations[{pq1,pq2,…}]

返回无量纲物理量 pqi 的列表的可能组合.

DimensionalCombinations[{pq1,pq2,…},dim]

返回匹配物理量维度 dim 的物理量 pqi 的列表的可能组合.

更多信息和选项

  • 物理量可以是有效的 QuantityVariable 对象、"PhysicalQuantity" 实体或物理量字符串.
  • dim 可以是 QuantityVariable 对象，也可以是 QuantityVariable 对象或其导数的组合.
  • 解由物理量分量确定，其单位维度是纯数学意义的，并不能保证有物理意义.
  • 物理维度包括："AmountUnit"、"AngleUnit"、"ElectricCurrentUnit"、"InformationUnit"、"LengthUnit"、"LuminousIntensityUnit"、"MassUnit"、"MoneyUnit"、"SolidAngleUnit"、"TemperatureDifferenceUnit"、"TemperatureUnit" 和 "TimeUnit".
  • 无量纲物理量不用于解.
  • 可以给出以下选项：
  • GeneratedParameters C如何命名生成的参数
    IncludeQuantities {}要包括的额外数量
  • GeneratedParameters 取选项 None，这将返回无参数解的列表.
  • IncludeQuantities 允许量值和常数包括在组合中.
  • IncludeQuantities 的设置 "PhysicalConstants" 包括量 Quantity["BoltzmannConstant"]、Quantity["ElectricConstant"]、Quantity["GravitationalConstant"]、Quantity["MagneticConstant"]、Quantity["PlanckConstant"] 和Quantity["SpeedOfLight"].

范例

打开所有单元 关闭所有单元

基本范例  (1)

确定量纲相当于能量的物理量组合：

Wolfram Language code: DimensionalCombinations[{"MassDensity", "Radius", "Time"}, "Energy"]

求生成无量纲表达式的物理量的所有组合：

Wolfram Language code: DimensionalCombinations[{QuantityVariable["V", "ElectricPotential"], QuantityVariable["I", "ElectricCurrent"], QuantityVariable["R", "ElectricResistance"]}]

求无量纲表达式是否可能带有一组物理量时：

Wolfram Language code: DimensionalCombinations[{QuantityVariable["Force"], QuantityVariable["Distance"], QuantityVariable["ElectricCharge"]}]

范围  (3)

使用 QuantityVariable 对象或物理量字符串的任意组合：

Wolfram Language code: pqs = {QuantityVariable["E", "Energy"], QuantityVariable["MassDensity"], "Radius", QuantityVariable["Time"]}; DimensionalCombinations[pqs]

目标物理量纲可以用物理量的组合指定：

Wolfram Language code: DimensionalCombinations[{QuantityVariable["m", "Mass"], QuantityVariable["l", "Length"], QuantityVariable["t", "Time"], QuantityVariable["e", "ElectricCharge"]}, QuantityVariable["V", "ElectricPotential"] * QuantityVariable["K", "Energy"] ^ 2 / QuantityVariable["m", "Mass"]]

Derivative 对象也可以包括在表达式中：

Wolfram Language code: DimensionalCombinations[{QuantityVariable["m", "Mass"], QuantityVariable["l", "Length"], QuantityVariable["t", "Time"], QuantityVariable["e", "ElectricCharge"]}, QuantityVariable["RadiantFluxDensity"]''[QuantityVariable["Time"]] / QuantityVariable["Speed"]]

也可以使用包括在 QuantityVariable 表达式中的 "PhysicalQuantity" 实体：

Wolfram Language code: DimensionalCombinations[{QuantityVariable[Entity["PhysicalQuantity", "ElectricPotential"]], QuantityVariable["I", Entity["PhysicalQuantity", "ElectricCurrent"]], Entity["PhysicalQuantity", "ElectricResistance"]}]

选项  (5)

GeneratedParameters  (3)

使用不同符号作为参数：

Wolfram Language code: DimensionalCombinations[{"Force", "Distance", "ElectricCharge", "ElectricCharge"}, IncludeQuantities -> {"ElectricConstant"}, GeneratedParameters -> K]

默认情况下，返回通解：

Wolfram Language code: DimensionalCombinations[ {QuantityVariable["t", "Time"], QuantityVariable["a", "Acceleration"], QuantityVariable["F", "Force"], QuantityVariable["P", "Momentum"], QuantityVariable["E", "Energy"]}, QuantityVariable["x", "Length"]]

使用 GeneratedParameters->None 得到特解：

Wolfram Language code: DimensionalCombinations[ {QuantityVariable["t", "Time"], QuantityVariable["a", "Acceleration"], QuantityVariable["F", "Force"], QuantityVariable["P", "Momentum"], QuantityVariable["E", "Energy"]}, QuantityVariable["x", "Length"], GeneratedParameters -> None]

GeneratedParameters->None 适用于 IncludeQuantities 以允许 QuantityVariable 和 Quantity 对象的混合：

Wolfram Language code: DimensionalCombinations[ {QuantityVariable["a", "Acceleration"], QuantityVariable["F", "Force"], QuantityVariable["P", "Momentum"]}, GeneratedParameters -> None, IncludeQuantities -> {Quantity["Meters"], Quantity["Seconds"]}]

IncludeQuantities  (2)

在结果中包括额外常数和 Quantity 对象：

Wolfram Language code: DimensionalCombinations[{"Force", "Distance", "ElectricCharge"}, IncludeQuantities -> {"ElectricConstant"}]
Wolfram Language code: DimensionalCombinations[{"Force"}, IncludeQuantities -> {Quantity["ElectricConstant"], Quantity[1, "Meters"], "ElementaryCharge"}]

使用设置 "PhysicalConstants" 包括一组标准的物理常数：

Wolfram Language code: DimensionalCombinations[{"Force", "Distance", "ElectricCharge"}, IncludeQuantities -> "PhysicalConstants"]

应用  (4)

找到公式 E^2 - p^2 == m^2 中缺失的物理常数：

Wolfram Language code: sol1 = DimensionalCombinations[{"Mass", "Energy"}, IncludeQuantities -> "PhysicalConstants"]
Wolfram Language code: sol2 = DimensionalCombinations[{"Momentum", "Energy"}, IncludeQuantities -> "PhysicalConstants"]

求解常数值：

Wolfram Language code: Reduce[{C[1] == -1, -C[1] - 2C[2] == 1}, {C[1], C[2]}]
Wolfram Language code: Reduce[{2C[1] == -1, -2C[1] - 4C[2] == 1}, {C[1], C[2]}]

插入正确的指数：

Wolfram Language code: sol1 = sol1 /. {C[1] -> -1, C[2] -> 0}
Wolfram Language code: sol2 = sol2 /. {C[1] -> -1 / 2, C[2] -> 0}

去除不必要的常数：

Wolfram Language code: sol1 /. C[3] -> 4 /. Quantity[1, "ElectricConstant"^2*"MagneticConstant"^2*"SpeedOfLight"^8] -> Quantity[1, "SpeedOfLight"^2]
Wolfram Language code: sol2 /. C[3] -> 1 /. Quantity[1, Sqrt["ElectricConstant"]*Sqrt["MagneticConstant"]*"SpeedOfLight"^2] -> Quantity[1, "SpeedOfLight"]

求平衡克莱伯定律 所需常数的量纲：

Wolfram Language code: sol = DimensionalCombinations[{"MetabolicRate", "Mass"}, IncludeQuantities -> {Quantity["Kilograms"], Quantity["Days"]}]

求解质量指数的值：

Wolfram Language code: Reduce[-3 C[1] + 1 == 3 / 4, C[1]]
Wolfram Language code: sol /. {C[2] -> -1, C[1] -> 1 / 12}

仅用这些物理量估计炸弹爆炸的威力：

Wolfram Language code: pqs = {QuantityVariable["Energy"], QuantityVariable["MassDensity"], QuantityVariable["Radius"], QuantityVariable["Time"]};

构建一个无量纲的组合：

Wolfram Language code: DimensionalCombinations[pqs]

已知给定时刻的参数值，估计爆炸的能量：

Wolfram Language code: massdensity = Quantity[1.2, "Kilograms" / "Meters" ^ 3]; radius = Quantity[80, "Meters"]; time = Quantity[0.006, "Seconds"];
Wolfram Language code: energy = (massdensity radius^5/time^2)
Wolfram Language code: UnitConvert[energy, "KilotonsOfTNT"]

根据股票价格、投注规模和成本、交易量和股票的波动性确定可能的无量纲价格影响函数：

Wolfram Language code: stockprice = QuantityVariable["P", "Money" / IndependentPhysicalQuantity["shares"]]; betsize = QuantityVariable["Q", IndependentPhysicalQuantity["shares"]]; tradingvolume = QuantityVariable["V", IndependentPhysicalQuantity["shares"] / "Time"]; stockvolatility = QuantityVariable[Superscript["σ", "2"], 1 / Sqrt["Time"]]; betcost = QuantityVariable["C", "Money"];

求总的无量纲组合式：

Wolfram Language code: DimensionalCombinations[{stockprice, betsize, tradingvolume, stockvolatility, betcost}]

给出特殊情况下的式子：

Wolfram Language code: DimensionalCombinations[{stockprice, betsize, tradingvolume, stockvolatility, betcost}, GeneratedParameters -> None]

属性和关系  (1)

无量纲常数的公式可以从物理量来构造：

Wolfram Language code: FormulaLookup[All, 10, RequiredPhysicalQuantities -> {"Length", "Speed", "DynamicViscosity", "MassDensity"}]
Wolfram Language code: FormulaData[{"ReynoldsNumber", "DynamicViscosity"}]
Wolfram Language code: DimensionalCombinations[{QuantityVariable["l", "Length"], QuantityVariable["v", "Speed"], QuantityVariable["η", "DynamicViscosity"], QuantityVariable["ρ", "MassDensity"]}, GeneratedParameters -> None]

可能存在的问题  (5)

仅使用有效的物理量：

Wolfram Language code: DimensionalCombinations[{QuantityVariable["ElectricPotential"], QuantityVariable["ElectricCurrent"], QuantityVariable["Ohms"]}]

无量纲量会从结果中忽略：

Wolfram Language code: DimensionalCombinations[{QuantityVariable["Φ", "RadiantFluxDensity"], QuantityVariable["T", "Temperature"], QuantityVariable["ϵ", "Emissivity"]}, IncludeQuantities -> {Quantity["StefanBoltzmannConstant"]}]

仅使用有效常数：

Wolfram Language code: DimensionalCombinations[{"Force", "Distance", "ElectricCharge"}, IncludeQuantities -> {"ElectricConstant", "Foo"}]

角单位和物理量不被视为无量纲的：

Wolfram Language code: DimensionalCombinations[{"Area", "Angle", "Radius"}]
Wolfram Language code: DimensionalCombinations[{"Area", "Angle", "Radius"}, IncludeQuantities -> {Quantity["AngularDegrees"]}]

尽管返回的组合是无量纲的，它们不必具有一的幅值：

Wolfram Language code: DimensionalCombinations[{QuantityVariable["E", "Energy"], QuantityVariable["λ", "Wavelength"]}, IncludeQuantities -> {Quantity["PlankConstant"], Quantity["SpeedOfLight"]}]
Wolfram Language code: DimensionalCombinations[{QuantityVariable["E", "Energy"], QuantityVariable["λ", "Wavelength"]}, IncludeQuantities -> {Quantity["ReducedPlankConstant"], Quantity["SpeedOfLight"]}]

互动范例  (1)

检查一组物理量和常数的所有可能的无量纲组合：

Wolfram Language code: solutions = DimensionalCombinations[{ QuantityVariable["E", "Energy"], QuantityVariable["f", "Frequency"], QuantityVariable["m", "Mass"], QuantityVariable["T", "Temperature"] }, IncludeQuantities -> "PhysicalConstants", GeneratedParameters -> None]; Manipulate[solutions[[i]], {{i, 1, "Solution"}, 1, Length[solutions], 1}, SaveDefinitions -> True]

巧妙范例  (2)

探索电磁物理量的可能量纲组合：

Wolfram Language code: DimensionalCombinations[{ QuantityVariable["Q", "ElectricCharge"], QuantityVariable["V", "ElectricPotential"], QuantityVariable["I", "ElectricCurrent"], QuantityVariable["R", "ElectricResistance"], QuantityVariable["C", "ElectricCapacitance"], QuantityVariable["L", "MagneticInductance"], QuantityVariable["M", "MagneticMemristance"], QuantityVariable["Φ", "MagneticFlux"]}, GeneratedParameters -> None]

从物理量推导用于精细结构常数的因数：

Wolfram Language code: sol = DimensionalCombinations[{}, IncludeQuantities -> { Quantity["SpeedOfLight"], Quantity["PlanckConstant"], Quantity["ElectricConstant"], Quantity["ElementaryCharge"] }, GeneratedParameters -> None]
Wolfram Language code: UnitConvert[sol[[1]], "SIBase"] ^ 2 / Quantity["FineStructureConstant"]
Wolfram Research (2014)，DimensionalCombinations，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DimensionalCombinations.html （更新于 2018 年）.

文本

Wolfram Research (2014)，DimensionalCombinations，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DimensionalCombinations.html （更新于 2018 年）.

CMS

Wolfram 语言. 2014. "DimensionalCombinations." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2018. https://reference.wolfram.com/language/ref/DimensionalCombinations.html.

APA

Wolfram 语言. (2014). DimensionalCombinations. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DimensionalCombinations.html 年

BibTeX

@misc{reference.wolfram_2026_dimensionalcombinations, author="Wolfram Research", title="{DimensionalCombinations}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/DimensionalCombinations.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dimensionalcombinations, organization={Wolfram Research}, title={DimensionalCombinations}, year={2018}, url={https://reference.wolfram.com/language/ref/DimensionalCombinations.html}, note=[Accessed: 08-September-2026]}