WOLFRAM

Wolfram 语言与系统参考资料中心

Direction

是 Limit 和相关函数的一个选项，指定极限的方向.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
参见
历史
按以下格式引用：

Direction

Direction

是 Limit 和相关函数的一个选项，指定极限的方向.

更多信息

  • Direction 的可能设置包括：
  • Reals 或 "TwoSided"来自两边实方向
    "FromAbove" 或 -1来自上面或更大的值
    "FromBelow" 或 +1来自下面或更小的值
    Complexes来自所有复方向
    Exp[ θ]在方向
    {dir1,…,dirn}为变量 xi 分别使用方向 diri
  • 在 x* 的 DirectionExp[ θ] 表明逼近极限点 x* 的曲线的方向正切.

范例

打开所有单元 关闭所有单元

基本范例  (1)

下限的极限：

Wolfram Language code: Limit[1 / x, x -> 0, Direction -> "FromBelow"]

上限的极限：

Wolfram Language code: Limit[1 / x, x -> 0, Direction -> "FromAbove"]

不存在双边极限：

Wolfram Language code: Limit[1 / x, x -> 0, Direction -> "TwoSided"]
Wolfram Language code: Plot[1 / x, {x, -1, 1}]

范围  (5)

分段不连续的单边极限：

Wolfram Language code: Limit[RealAbs[x] / x, x -> 0, Direction -> "FromAbove"]
Wolfram Language code: Limit[RealAbs[x] / x, x -> 0, Direction -> "FromBelow"]

默认方向是双边的：

Wolfram Language code: Limit[RealAbs[x] / x, x -> 0]
Wolfram Language code: Plot[RealAbs[x] / x, {x, -1, 1}]

单边最大极限：

Wolfram Language code: MaxLimit[UnitStep[x]Sin[(1/x)] + (1/2), x -> 0, Direction -> "FromAbove"]
Wolfram Language code: MaxLimit[UnitStep[x]Sin[(1/x)] + (1/2), x -> 0, Direction -> "FromBelow"]

默认方向 Reals 给出两个单边最大极限的较大的哪一个：

Wolfram Language code: MaxLimit[UnitStep[x]Sin[(1/x)] + (1/2), x -> 0]
Wolfram Language code: MaxLimit[UnitStep[x]Sin[(1/x)] + (1/2), x -> 0, Direction -> Reals]

可视化函数：

Wolfram Language code: Plot[UnitStep[x]Sin[(1/x)] + (1/2), {x, -.1, .1}]

简单极点处的极限：

Wolfram Language code: Limit[Tan[x], x -> π / 2, Direction -> "FromBelow"]
Wolfram Language code: Limit[Tan[x], x -> π / 2, Direction -> "FromAbove"]
Wolfram Language code: Limit[Tan[x], x -> π / 2, Direction -> ℝ]
Wolfram Language code: Limit[Tan[x], x -> π / 2, Direction -> ℂ]

分支分割处的极限：

Wolfram Language code: Limit[Sqrt[x], x -> -1, Direction -> Reals]
Wolfram Language code: Limit[Sqrt[x], x -> -1, Direction -> -I]
Wolfram Language code: Limit[Sqrt[x], x -> -1, Direction -> +I]
Wolfram Language code: Limit[Sqrt[x], x -> -1, Direction -> Complexes]

计算从不同象限逼近的双边极限：

Wolfram Language code: f[x_, y_] := (x y/x + y)(2 + RealSign[ x y] + RealSign[y])

从第一象限逼近原点：

Wolfram Language code: Limit[f[x, y], {x, y} -> {0, 0}, Direction -> "FromAbove"]

等同于：

Wolfram Language code: Limit[f[x, y], {x, y} -> {0, 0}, Direction -> {"FromAbove", "FromAbove"}]

从第二象限逼近原点：

Wolfram Language code: Limit[f[x, y], {x, y} -> {0, 0}, Direction -> {"FromBelow", "FromAbove"}]

从左半平面逼近原点：

Wolfram Language code: Limit[f[x, y], {x, y} -> {0, 0}, Direction -> {"FromBelow", Reals}]

从下半平面逼近原点：

Wolfram Language code: Limit[f[x, y], {x, y} -> {0, 0}, Direction -> {Reals, "FromBelow"}]

可视化函数：

Wolfram Language code: Row@{Plot3D[f[x, y], {x, y}∈Disk[], Exclusions -> {{x == -y , x <= 0}}, ClippingStyle -> None, ImageSize -> 200], DensityPlot[f[x, y], {x, -1, 1}, {y, -1, 1}, Exclusions -> {{x == -y , x <= 0}}, ClippingStyle -> Automatic, ImageSize -> Small]}

属性和关系  (4)

设置 "FromBelow" 和 1 是等价的：

Wolfram Language code: MinLimit[Cos[x] / x, x -> 0, Direction -> "FromBelow"]
Wolfram Language code: MinLimit[Cos[x] / x, x -> 0, Direction -> 1]

设置 "FromAbove" 和 -1 是等价的：

Wolfram Language code: MinLimit[Cos[x] / x, x -> 0, Direction -> "FromAbove"]
Wolfram Language code: MinLimit[Cos[x] / x, x -> 0, Direction -> -1]

设置 "TwoSided" 和 Reals 是等价的：

Wolfram Language code: MinLimit[Cos[x] / x, x -> 0, Direction -> "TwoSided"]
Wolfram Language code: MinLimit[Cos[x] / x, x -> 0, Direction -> ℝ]

Direction 在极限变量上放置条件：

Wolfram Language code: Limit[Tan[x], x -> π / 2 + n π, Direction -> 1, Assumptions -> n∈Integers]

Assumptions 在极限表达式上应用参数：

Wolfram Language code: Limit[Tan[x], x -> π / 2 + n π, Direction -> -1, Assumptions -> n∈Integers]
Wolfram Language code: Plot[Tan[x], {x, -2π, 2π}, ExclusionsStyle -> {{Dashed, Red}}]
Wolfram Research (1991)，Direction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Direction.html （更新于 2017 年）.

文本

Wolfram Research (1991)，Direction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Direction.html （更新于 2017 年）.

CMS

Wolfram 语言. 1991. "Direction." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2017. https://reference.wolfram.com/language/ref/Direction.html.

APA

Wolfram 语言. (1991). Direction. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Direction.html 年

BibTeX

@misc{reference.wolfram_2026_direction, author="Wolfram Research", title="{Direction}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/Direction.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_direction, organization={Wolfram Research}, title={Direction}, year={2017}, url={https://reference.wolfram.com/language/ref/Direction.html}, note=[Accessed: 11-September-2026]}