WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DirichletWindow[x]

x のディリクレ(Dirichlet)窓関数を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

DirichletWindow

DirichletWindow[x]

x のディリクレ(Dirichlet)窓関数を表す．

詳細

  • DirichletWindowは，矩形窓あるいはボックスカー窓としても知られるもので，データを短いセグメントで処理する必要がある信号処理アプリケーションで使われる窓関数である．
  • DirichletWindow[x]は 1 -1/2<=x<=1/2; 0 TemplateBox[{x}, Abs]>1/2; に等しい．
  • DirichletWindowは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

1Dディリクレ窓の形：

Wolfram Language code: Plot[DirichletWindow[x], {x, -1, 1}, Exclusions -> None]

2Dディリクレ窓の形：

Wolfram Language code: Plot3D[DirichletWindow[x]DirichletWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All, Exclusions -> None]

ディリクレ窓を表す連続関数を抽出する：

Wolfram Language code: FunctionExpand[DirichletWindow[x]]

スコープ  (4)

数値的に評価する：

Wolfram Language code: DirichletWindow[0.1]

平行移動され広げられたディリクレ窓：

Wolfram Language code: Plot[DirichletWindow[(x - 1) / 2], {x, -1, 3}, Exclusions -> None]

円形の台を持つ2Dディリクレ窓：

Wolfram Language code: Plot3D[DirichletWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All, Exclusions -> None]

長さ15の離散ディリクレ窓：

Wolfram Language code: ListPlot[Array[DirichletWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

15×10の2Dの離散ディリクレ窓：

Wolfram Language code: ListPointPlot3D[Array[DirichletWindow[#1] DirichletWindow[#2]&, {15, 10}, {{-1, 1}}], Filling -> Axis]

アプリケーション  (2)

窓指定を使ってサンプルPowerSpectralDensityを計算する：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

スペクトルを計算する：

Wolfram Language code: spec = PowerSpectralDensity[data, w, DirichletWindow];

窓関数を使わずに計算されたスペクトル密度と比較する：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

ディリクレ窓はスペクトル密度を変化させない：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotLegends -> {"no window", "with window"}]

この過程の理論的なスペクトル密度と比較する：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

時系列推定に窓指定を使う：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

スペクトル推定器に窓を指定する：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> DirichletWindow}]

特性と関係  (3)

DirichletWindowはUnitBoxと等価である：

Wolfram Language code: PiecewiseExpand[DirichletWindow[x]] === PiecewiseExpand[UnitBox[x]]

ディリクレ窓のフーリエ変換：

Wolfram Language code: f = FourierTransform[DirichletWindow[x], x, w]

ディリクレ窓のパワースペクトル：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 80}]

長さ11の離散ディリクレ窓の離散時間フーリエ変換：

Wolfram Language code: f = ListFourierSequenceTransform[Array[DirichletWindow, 11, {-1 / 2, 1 / 2}], ω, -5]//FullSimplify

ω=0における振幅：

Wolfram Language code: f0 = N[f /. ω -> 0]

パワースペクトル：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f] / f0], {ω, .1, π}, GridLines -> Automatic]
Wolfram Research (2012), DirichletWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/DirichletWindow.html.

テキスト

Wolfram Research (2012), DirichletWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/DirichletWindow.html.

CMS

Wolfram Language. 2012. "DirichletWindow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DirichletWindow.html.

APA

Wolfram Language. (2012). DirichletWindow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DirichletWindow.html

BibTeX

@misc{reference.wolfram_2026_dirichletwindow, author="Wolfram Research", title="{DirichletWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/DirichletWindow.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dirichletwindow, organization={Wolfram Research}, title={DirichletWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/DirichletWindow.html}, note=[Accessed: 11-September-2026]}