WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Divisible[n,m]

n が m で割り切れる場合はTrueを，割り切れない場合はFalseを返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
基本的なアプリケーション  
整数論  
特性と関係  
考えられる問題  
インタラクティブな例題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

Divisible

Divisible[n,m]

n が m で割り切れる場合はTrueを，割り切れない場合はFalseを返す．

詳細

  • Divisibleは，一般に，n が m で割り切れるかどうかを調べる際に使われる．
  • n が m と他の整数の積なら，n は m で割り切れる．
  • Divisible[n,m]は，実質的にMod[n,m]==0と等価である．
  • n が m で明らかに割り切れない限り，Divisible[n, m]はFalseを返す．
  • Divisible[n,m]は として入力できる．
  • は \[Divides]あるいはdividesとして入力できる．

例題

すべて開く すべて閉じる

例  (2)

ある数がで割り切れるかどうか調べる：

Wolfram Language code: Divisible[10, 2]

はでは割り切れない：

Wolfram Language code: Divisible[5, 2]

スコープ  (6)

Divisibleは整数に使うことができる：

Wolfram Language code: Divisible[6, 3]

ガウス整数：

Wolfram Language code: Divisible[3 + I, 1 - I]

有理数：

Wolfram Language code: Divisible[3 / 2, 1 / 2]

数量の記号表記：

Wolfram Language code: Divisible[2Pi, Pi / 2]

数量：

Wolfram Language code: Divisible[Sqrt[6], Sqrt[2]]

大きい整数について調べる：

Wolfram Language code: Divisible[10 ^ 3000 + 1, 16001]

Divisibleは要素単位でリストに縫い込まれる：

Wolfram Language code: Divisible[{1, 2, 3, 4, 5, 6}, 2]

TraditionalFormによる表示：

Wolfram Language code: Divisible[n, m]//TraditionalForm

アプリケーション  (8)

基本的なアプリケーション  (3)

で割り切れる数をハイライトする：

Wolfram Language code: Multicolumn[If[Divisible[#, 3], Style[#, Red, Bold], #]& /@ Range[100], 10, ...]

指定された数で割り切れる数をランダムに生成する：

Wolfram Language code: randomDivisible[n_, m_ : 1] := RandomChoice[Select[Range[1000], Divisible[#, n]&], m];
Wolfram Language code: randomDivisible[5, 10]
Wolfram Language code: AllTrue[%, Divisible[#, 5]&]

ある数が他の数を割り切れるときを可視化する：

Wolfram Language code: ArrayPlot[Table[Boole[Divisible[i, j]], {i, 100}, {j, 100}]]

整数論  (5)

Wieferich素数（が で割り切れるような素数 p）を認識する：

Wolfram Language code: wprimeQ[n_] := PrimeQ[n] && (Mod[2 ^ (n - 1) - 1, n ^ 2] == 0);
Wolfram Language code: wprimeQ[1093]

既知のWieferich素数は2つだけである：

Wolfram Language code: Select[Range[10 ^ 4], wprimeQ]

がの形のすべての数であるとする：

Wolfram Language code: hilbertQ[n_] := Divisible[n - 1, 4]; h = Select[Range[1000], hilbertQ];

このような数2つの積も に含まれることを確かめる：

Wolfram Language code: {a, b} = RandomChoice[h, 2]; hilbertQ[a b]

ヒルベルト(Hilbert)素数（ の中にとそれ自身以外に約数を持たない素数）を認識する：

Wolfram Language code: hprimeQ[n_] := If[Length[Select[h, Divisible[n, #] && hilbertQ[n] && hilbertQ[#]&]] == 2, True, False];

最初の個のヒルベルト素数を求める：

Wolfram Language code: Select[h, hprimeQ, 10]

ある数を2つの平方の和として表現する方法を2つ求める：

Wolfram Language code: {{a, b}, {c, d}} = PowersRepresentations[377, 2, 2]

とその数の最大公約数を求めることで，その数の約数を求める：

Wolfram Language code: GCD[377, a d + b c ]
Wolfram Language code: Divisible[377, %]

とその数の最大公約数を計算することで別の約数を求める：

Wolfram Language code: GCD[377, a d - b c ]
Wolfram Language code: Divisible[377, %]

整数の各桁の合計がで割り切れるとき，その整数はで割り切れる：

Wolfram Language code: Total[IntegerDigits[2895]]
Wolfram Language code: Divisible[2895, 3]

整数の各桁の交代和がで割り切れる時，その整数はで割り切れる：

Wolfram Language code: Divisible[918082, 11]
Wolfram Language code: 9 - 1 + 8 - 0 + 8 - 2

はで割り切れる．ただし，n は奇整数である：

Wolfram Language code: AllTrue[Table[4 ^ n + 5 ^ n + 6 ^ n, {n, 1, 100, 2}], Divisible[#, 15]&]

特性と関係  (7)

が整数なら， は で割り切れる：

Wolfram Language code: {IntegerQ[10 / 2], Divisible[10, 2]}

が で割り切れるなら，両者の最大公約数GCDは である：

Wolfram Language code: Divisible[48, 8]
Wolfram Language code: GCD[48, 8]

と が互いに素なら， は では割り切れない：

Wolfram Language code: CoprimeQ[25, 12]
Wolfram Language code: Divisible[25, 12]

整数の素因数分解が の形なら，約数の数はである：

Wolfram Language code: Part[FactorInteger[24], All, 2] + 1
Wolfram Language code: Times@@%
Wolfram Language code: Length[Divisors[24]]

Divisorsを使ってある整数の約数をすべて求める：

Wolfram Language code: Divisors[12]
Wolfram Language code: Divisible[12, %]

PrimeNuは異なる素因数の数を与える：

Wolfram Language code: PrimeNu[12]
Wolfram Language code: Divisible[12, {2, 3}]

式を簡約する：

Wolfram Language code: Simplify[Divisible[b a, a], {a, b}∈Integers]

考えられる問題  (2)

Divisibleは記号入力に対しては評価されない：

Wolfram Language code: Divisible[x, y]

Divisibleは自動的には値を簡約しない：

Wolfram Language code: Divisible[6(E + 1) ^ 2, 6 (1 + 2 E + E ^ 2)]
Wolfram Language code: Simplify[%]

インタラクティブな例題  (1)

2つの素数の和が指定された数で割り切れるときを可視化する：

Wolfram Language code: Manipulate[ArrayPlot[Boole /@ Table[Divisible[Prime[m] + Prime[n], a], {m, 1, 100}, {n, 1, 100}]], {a, 3, 50, 1}]

おもしろい例題  (3)

が素数で割り切れるときを可視化する．点の各行は水平軸に沿ってラベルが付けられた の約数を表す：

Wolfram Language code: NumberLinePlot[Table[Select[Range[Prime[n]], (Divisible[Prime[n] - 1, #] && # > 1 && PrimeQ[#])&], {n, 1, 40}], PlotRange -> All]

が3つの平方の和で割り切れるときをプロットする：

Wolfram Language code: ArrayMesh[Boole[Table[Divisible[a ^ 2 + b ^ 2 + c ^ 2, 5], {a, 10}, {b, 10}, {c, 10}]]]

で割り切れる数のウルム(Ulam)螺線をプロットする：

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n];
Wolfram Language code: ArrayPlot[ulam[101]Boole[Divisible[ulam[101], 9]], ColorFunction -> "Rainbow", ColorRules -> {0 -> White}]
Wolfram Research (2007), Divisible, Wolfram言語関数， https://reference.wolfram.com/language/ref/Divisible.html.

テキスト

Wolfram Research (2007), Divisible, Wolfram言語関数， https://reference.wolfram.com/language/ref/Divisible.html.

CMS

Wolfram Language. 2007. "Divisible." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Divisible.html.

APA

Wolfram Language. (2007). Divisible. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Divisible.html

BibTeX

@misc{reference.wolfram_2026_divisible, author="Wolfram Research", title="{Divisible}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Divisible.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_divisible, organization={Wolfram Research}, title={Divisible}, year={2007}, url={https://reference.wolfram.com/language/ref/Divisible.html}, note=[Accessed: 07-September-2026]}