WOLFRAM

Wolfram 语言与系统参考资料中心

Divisible[n,m]

如果 n 是能被 m 除尽得出 True，如果不能被除尽则得出 False.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
基本应用  
数论  
属性和关系  
可能存在的问题  
互动范例  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

Divisible

Divisible[n,m]

如果 n 是能被 m 除尽得出 True，如果不能被除尽则得出 False.

更多信息

  • Divisible 通常用于测试 n 是否可被 m 整除.
  • 如果 n 是 m 与整数的乘积，则 n 可被 m 整除.
  • Divisible[n,m] 实际上等价于 Mod[n,m]==0.
  • 除非 n 明显可以被 m 整除，否则 Divisible[n, m] 返回 False.
  • Divisible[n,m] 可输入为 .
  • 可用 \[Divides] 或 divides 输入 .

范例

打开所有单元 关闭所有单元

基本范例  (2)

测试一个数字是否可被 2 整除：

Wolfram Language code: Divisible[10, 2]

不能被 整除：

Wolfram Language code: Divisible[5, 2]

范围  (6)

Divisible 适用于所有整数：

Wolfram Language code: Divisible[6, 3]

高斯整数：

Wolfram Language code: Divisible[3 + I, 1 - I]

有理数：

Wolfram Language code: Divisible[3 / 2, 1 / 2]

数值量的符号形式：

Wolfram Language code: Divisible[2Pi, Pi / 2]

数值量：

Wolfram Language code: Divisible[Sqrt[6], Sqrt[2]]

测试大的整数：

Wolfram Language code: Divisible[10 ^ 3000 + 1, 16001]

Divisible 按元素线性作用于列表：

Wolfram Language code: Divisible[{1, 2, 3, 4, 5, 6}, 2]

TraditionalForm 格式：

Wolfram Language code: Divisible[n, m]//TraditionalForm

应用  (8)

基本应用  (3)

突出显示可被 整除的数：

Wolfram Language code: Multicolumn[If[Divisible[#, 3], Style[#, Red, Bold], #]& /@ Range[100], 10, ...]

生成可被给定数字整除的随机数：

Wolfram Language code: randomDivisible[n_, m_ : 1] := RandomChoice[Select[Range[1000], Divisible[#, n]&], m];
Wolfram Language code: randomDivisible[5, 10]
Wolfram Language code: AllTrue[%, Divisible[#, 5]&]

可视化可被另一个数字整除的数字：

Wolfram Language code: ArrayPlot[Table[Boole[Divisible[i, j]], {i, 100}, {j, 100}]]

数论  (5)

识别 Wieferich 素数，即满足 整除 的素数 p：

Wolfram Language code: wprimeQ[n_] := PrimeQ[n] && (Mod[2 ^ (n - 1) - 1, n ^ 2] == 0);
Wolfram Language code: wprimeQ[1093]

只有两个已知的 Wieferich 素数：

Wolfram Language code: Select[Range[10 ^ 4], wprimeQ]

设 是形为 的所有数字：

Wolfram Language code: hilbertQ[n_] := Divisible[n - 1, 4]; h = Select[Range[1000], hilbertQ];

查看这样的两个数字的乘积是否依然为 ：

Wolfram Language code: {a, b} = RandomChoice[h, 2]; hilbertQ[a b]

识别 Hilbert 素数，即在 中除了 和自身外没有其他因数的素数：

Wolfram Language code: hprimeQ[n_] := If[Length[Select[h, Divisible[n, #] && hilbertQ[n] && hilbertQ[#]&]] == 2, True, False];

求前 个 Hilbert 素数：

Wolfram Language code: Select[h, hprimeQ, 10]

求两种用两个数字的平方的和表示一个数字的方式：

Wolfram Language code: {{a, b}, {c, d}} = PowersRepresentations[377, 2, 2]

通过计算 和一个数字的 GCD 求该数的因数：

Wolfram Language code: GCD[377, a d + b c ]
Wolfram Language code: Divisible[377, %]

通过计算 和该数的 GCD 求另一个因数：

Wolfram Language code: GCD[377, a d - b c ]
Wolfram Language code: Divisible[377, %]

如果整数的各个数字的和可被 整除，则该整数可被 整除：

Wolfram Language code: Total[IntegerDigits[2895]]
Wolfram Language code: Divisible[2895, 3]

如果整数的各个数字的交错和可被 整除，则该整数可被 整除：

Wolfram Language code: Divisible[918082, 11]
Wolfram Language code: 9 - 1 + 8 - 0 + 8 - 2

可被 整除，其中 n 为奇数：

Wolfram Language code: AllTrue[Table[4 ^ n + 5 ^ n + 6 ^ n, {n, 1, 100, 2}], Divisible[#, 15]&]

属性和关系  (7)

如果 为整数，则 可被 整除：

Wolfram Language code: {IntegerQ[10 / 2], Divisible[10, 2]}

如果 可被 整除，则它们的最大公约数 GCD 为 ：

Wolfram Language code: Divisible[48, 8]
Wolfram Language code: GCD[48, 8]

如果 和 互质，则 不可被 整除：

Wolfram Language code: CoprimeQ[25, 12]
Wolfram Language code: Divisible[25, 12]

如果整数的质因数分解的形式为 ，则因数的数量为 ：

Wolfram Language code: Part[FactorInteger[24], All, 2] + 1
Wolfram Language code: Times@@%
Wolfram Language code: Length[Divisors[24]]

用 Divisors 求整数的所有因数：

Wolfram Language code: Divisors[12]
Wolfram Language code: Divisible[12, %]

PrimeNu 给出相异质因数的数量：

Wolfram Language code: PrimeNu[12]
Wolfram Language code: Divisible[12, {2, 3}]

化简表达式：

Wolfram Language code: Simplify[Divisible[b a, a], {a, b}∈Integers]

可能存在的问题  (2)

如果输入为符号，Divisible 不进行计算：

Wolfram Language code: Divisible[x, y]

Divisible 不自动对值进行求解：

Wolfram Language code: Divisible[6(E + 1) ^ 2, 6 (1 + 2 E + E ^ 2)]
Wolfram Language code: Simplify[%]

互动范例  (1)

可视化可被给定数字整除的两个质数之和：

Wolfram Language code: Manipulate[ArrayPlot[Boole /@ Table[Divisible[Prime[m] + Prime[n], a], {m, 1, 100}, {n, 1, 100}]], {a, 3, 50, 1}]

巧妙范例  (3)

可视化可被素数整除的 . 每一行点对应于 的因数，在水平轴上标出：

Wolfram Language code: NumberLinePlot[Table[Select[Range[Prime[n]], (Divisible[Prime[n] - 1, #] && # > 1 && PrimeQ[#])&], {n, 1, 40}], PlotRange -> All]

绘制可被 整除的三个数的平方的和：

Wolfram Language code: ArrayMesh[Boole[Table[Divisible[a ^ 2 + b ^ 2 + c ^ 2, 5], {a, 10}, {b, 10}, {c, 10}]]]

绘制可被 整除的数字的 Ulam 螺旋：

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n];
Wolfram Language code: ArrayPlot[ulam[101]Boole[Divisible[ulam[101], 9]], ColorFunction -> "Rainbow", ColorRules -> {0 -> White}]
Wolfram Research (2007)，Divisible，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Divisible.html.

文本

Wolfram Research (2007)，Divisible，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Divisible.html.

CMS

Wolfram 语言. 2007. "Divisible." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Divisible.html.

APA

Wolfram 语言. (2007). Divisible. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Divisible.html 年

BibTeX

@misc{reference.wolfram_2026_divisible, author="Wolfram Research", title="{Divisible}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Divisible.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_divisible, organization={Wolfram Research}, title={Divisible}, year={2007}, url={https://reference.wolfram.com/language/ref/Divisible.html}, note=[Accessed: 15-September-2026]}