WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DivisorSigma[k,n]

約数関数 を返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
記号演算  
オプション  
GaussianIntegers  
アプリケーション  
基本的なアプリケーション  
特殊数列  
整数論  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

DivisorSigma

DivisorSigma[k,n]

約数関数 を返す．

詳細とオプション

  • DivisorSigmaは，約数関数あるいは約数の和の関数としても知られている．
  • 記号操作・数値操作の両方に適した数学的整数関数である．
  • DivisorSigma[k,n]は n の約数の k 次ベキの和である．
  • 数 （ は単元で は素数）について，DivisorSigma[k,n]はを返す．
  • GaussianIntegers->Trueのとき，DivisorSigmaはガウス整数である約数を含む．
  • DivisorSigma[k,m+In]は自動的にガウス整数上で作用する．

例題

すべて開く すべて閉じる

例  (2)

の約数を求める：

Wolfram Language code: Divisors[20]

約数の和：

Wolfram Language code: DivisorSigma[1, 20]

約数の二乗の和：

Wolfram Language code: DivisorSigma[2, 20]

DivisorSigmaを対数スケールの値でプロットする：

Wolfram Language code: DiscretePlot[{DivisorSigma[0, n], DivisorSigma[1, n], DivisorSigma[2, n]}, {n, 50}, ...]

スコープ  (12)

数値評価  (4)

DivisorSigmaは整数に使うことができる：

Wolfram Language code: DivisorSigma[2, 6]

負のベキ乗：

Wolfram Language code: DivisorSigma[-2, 10]

有理数のベキ乗：

Wolfram Language code: DivisorSigma[1 / 2, 12]

ガウス整数：

Wolfram Language code: DivisorSigma[1, 3 + I]
Wolfram Language code: DivisorSigma[2, 6, GaussianIntegers -> True]

大きい整数について計算する：

Wolfram Language code: DivisorSigma[2, 10 ^ 30]

DivisorSigmaは要素単位でリストに縫い込まれる：

Wolfram Language code: DivisorSigma[2, {1, 2, 3, 4, 5}]

記号演算  (8)

TraditionalFormによる表示：

Wolfram Language code: DivisorSigma[k, n]//TraditionalForm

簡約された式：

Wolfram Language code: Reduce[DivisorSigma[1, n] == 3n && 0 < n < 4000, n, Integers]

方程式を解く：

Wolfram Language code: Solve[DivisorSigma[2, n] == n ^ 2 + 1 && 0 < n < 10, n, Integers]

式を簡約する：

Wolfram Language code: FullSimplify[DivisorSigma[1, 2 ^ (p - 1)(2 ^ p - 1)], Element[2 ^ p - 1, Primes]]
Wolfram Language code: FullSimplify[DivisorSigma[0, n] < EulerPhi[n], n∈Integers && n > 30]

総和の中でDivisorSigmaを使う：

Wolfram Language code: Sum[DivisorSigma[0, n] / n ^ s, {n, Infinity}]

DirichletTransform：

Wolfram Language code: DirichletTransform[DivisorSigma[k, n], s, n]

記号引数について計算する：

Wolfram Language code: DivisorSigma[k, 30]

関数を生成する：

Wolfram Language code: Sum[DivisorSigma[k, n] / n ^ s, {n, Infinity}]

オプション  (1)

GaussianIntegers  (1)

の約数の和を整数上で求める：

Wolfram Language code: DivisorSigma[1, 6]

ガウス整数：

Wolfram Language code: DivisorSigma[1, 6, GaussianIntegers -> True]

アプリケーション  (13)

基本的なアプリケーション  (3)

一般にDivisorSigma[d,n]=∑k|nkdである：

Wolfram Language code: Table[{DivisorSigma[d, 2 ^ 12 - 1], Sum[k ^ d, {k, Divisors[2 ^ 12 - 1]}]}, {d, 0, 5}]//Grid

ガウスの約数と整数の約数の割合：

Wolfram Language code: ListPlot[Table[DivisorSigma[0, n, GaussianIntegers -> True] / DivisorSigma[0, n], {n, 200}], Filling -> Axis]

DivisorSigmaを対数スケールの値でプロットする：

Wolfram Language code: DiscretePlot[{DivisorSigma[0, n], DivisorSigma[1, n], DivisorSigma[2, n]}, {n, 50}, ...]

特殊数列  (4)

完全数（約数の和が になるような数 n）を認識する：

Wolfram Language code: Select[Range[30], DivisorSigma[1, #] == 2#&]

不足数（約数の和が よりも小さくなるような数 n）：

Wolfram Language code: Select[Range[30], DivisorSigma[1, #] < 2#&]

過剰数（約数の和が よりも大きくなるような数 n）：

Wolfram Language code: Select[Range[30], DivisorSigma[1, #] > 2#&]

高度に合成された数を認識する [詳細]：

Wolfram Language code: highlyCompositeQ[n_] := Length[Select[Range[n - 1], DivisorSigma[0, #] ≥ DivisorSigma[0, n]&]] == 0;
Wolfram Language code: Select[Range[20], highlyCompositeQ]

友愛数（異なる2つの数．各々の真の約数の和がもう一方の数と等しい）を認識する：

Wolfram Language code: amicablePairQ[n_, m_] := DivisorSigma[1, n] - n == m && DivisorSigma[1, m] - m == n;
Wolfram Language code: amicablePairQ[220, 284]
Wolfram Language code: amicablePairQ[10, 4]

-倍積完全数（約数の和が である数）を認識する：

Wolfram Language code: kPerfectQ[k_, n_] := DivisorSigma[1, n] == k n;

最初の -完全数はである：

Wolfram Language code: kPerfectQ[3, 120]

-完全である数は完全数と呼ばれる：

Wolfram Language code: kPerfectQ[2, 6]

整数論  (6)

n がのベキ乗なら，n の約数の和はになるが，これは n を概完全数にする：

Wolfram Language code: n = 2 ^ 10; {DivisorSigma[1, n], 2 n - 1}

ある数が完全平方のときかつそのときにかぎり，約数の数は奇数である：

Wolfram Language code: DivisorSigma[0, #]&@{2, 3, 5, 6, 7, 8, 10}
Wolfram Language code: DivisorSigma[0, #]&@{1, 4, 9}

オイラー(Euler)のトーシェント関数と約数の数を比較する：

Wolfram Language code: DiscretePlot[{EulerPhi[n], DivisorSigma[0, n]}, {n, 50}, Rule[...]]

約数の数の移動平均をその漸近値とともにプロットする：

Wolfram Language code: Show[ListPlot[Table[Sum[DivisorSigma[0, i], {i, n}] / n, {n, 50}]], Plot[Log[n] + 2EulerGamma - 1, {n, 1, 50}]]

反復するアリコット合計を計算する：

Wolfram Language code: NestList[DivisorSigma[1, #] - #&, 276, 20]
Wolfram Language code: ListLinePlot[Log[10, NestList[DivisorSigma[1, #] - #&, 276, 100]]]

極限の進化を示す：

Wolfram Language code: ListLinePlot[Table[Table[Log[DivisorSigma[n, n + m] / DivisorSigma[n, n]], {n, 100}], {m, 5}]]

特性と関係  (6)

DivisorSigmaは，約数の 次ベキの和である：

Wolfram Language code: Total[Divisors[100] ^ 5]
Wolfram Language code: DivisorSigma[5, 100]

DivisorSumを使って約数の和を求める：

Wolfram Language code: DivisorSum[100, # ^ 5&]

DivisorSigmaは乗法的関数である：

Wolfram Language code: DivisorSigma[3, 18] DivisorSigma[3, 25] == DivisorSigma[3, 18 25]

完全数 n 約数の逆数はまででなければならない：

Wolfram Language code: PerfectNumberQ[28]
Wolfram Language code: DivisorSigma[-1, 28]

素数ベキ n の約数の和は2n 未満である：

Wolfram Language code: (DivisorSigma[1, #] < 2#) & /@ Select[Range[100], PrimePowerQ]

素数 p について，約数の数はである：

Wolfram Language code: p = RandomPrime[100];
Wolfram Language code: DivisorSigma[0, p] == 2

約数の和は である：

Wolfram Language code: DivisorSigma[1, p] == p + 1

の約数の数は である：

Wolfram Language code: n = 5; DivisorSigma[0, p ^ n] == n + 1

DivisorSigmaを使って約数の積を求める：

Wolfram Language code: a = 24; Product[d, {d, Divisors[a]}]
Wolfram Language code: a ^ (1 / 2DivisorSigma[0, a])

考えられる問題  (1)

GaussianIntegers->Trueのとき，ネイティブな定義では正しい結果が出ない：

Wolfram Language code: DivisorSigma[2, 100, GaussianIntegers -> True]
Wolfram Language code: Total[Divisors[100, GaussianIntegers -> True] ^ 2]

DivisorSigmaを倍に増える関数にするために，因数を含む定義が使用されている：

Wolfram Language code: Times@@((#1 ^ ((#2 + 1)2) - 1) / (#1 ^ 2 - 1)&@@@({Select[#1 {1, -1, I, -I}, (Re[#] > 0 && Im[#] > 0)&][[1]], #2}&@@@FactorInteger[100, GaussianIntegers -> True]))

おもしろい例題  (4)

DivisorSigmaのフーリエ変換の引数をプロットする：

Wolfram Language code: ArrayPlot[Arg[Fourier[Table[DivisorSigma[m, n], {m, 100}, {n, 100}]]], ColorFunction -> Hue]

DivisorSigmaのフーリエ変換の絶対値をプロットする：

Wolfram Language code: ArrayPlot[Abs[Fourier[Table[DivisorSigma[m, n], {m, 100}, {n, 100}]]], ColorFunction -> Hue]

DivisorSigmaのフーリエ変換の引数をプロットする：

Wolfram Language code: ArrayPlot[Arg[Fourier[Table[If[x + I y == 0, 0, DivisorSigma[4, x + I y, GaussianIntegers -> True]], {x, 0, 128}, {y, 0, 128}]]], ColorFunction -> "Rainbow"]

約数の平均のウラム(Ulam)螺線をプロットする：

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n];
Wolfram Language code: ArrayPlot[DivisorSigma[0, ulam[71]], ColorFunction -> "Rainbow"]
Wolfram Research (1988), DivisorSigma, Wolfram言語関数， https://reference.wolfram.com/language/ref/DivisorSigma.html.

テキスト

Wolfram Research (1988), DivisorSigma, Wolfram言語関数， https://reference.wolfram.com/language/ref/DivisorSigma.html.

CMS

Wolfram Language. 1988. "DivisorSigma." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DivisorSigma.html.

APA

Wolfram Language. (1988). DivisorSigma. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DivisorSigma.html

BibTeX

@misc{reference.wolfram_2026_divisorsigma, author="Wolfram Research", title="{DivisorSigma}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/DivisorSigma.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_divisorsigma, organization={Wolfram Research}, title={DivisorSigma}, year={1988}, url={https://reference.wolfram.com/language/ref/DivisorSigma.html}, note=[Accessed: 10-September-2026]}