Wolfram 语言与系统参考资料中心

DivisorSigma

DivisorSigma[k,n]

给出除数函数 .

范例

打开所有单元关闭所有单元

基本范例 (2)

求的因数：

Wolfram Language code: Divisors[20]

除数的和：

Wolfram Language code: DivisorSigma[1, 20]

除数的平方和：

Wolfram Language code: DivisorSigma[2, 20]

用对数值绘制 DivisorSigma：

Wolfram Language code: DiscretePlot[{DivisorSigma[0, n], DivisorSigma[1, n], DivisorSigma[2, n]}, {n, 50}, ...]

范围 (12)

数值运算 (4)

DivisorSigma 适用于整数：

Wolfram Language code: DivisorSigma[2, 6]

负的幂：

Wolfram Language code: DivisorSigma[-2, 10]

有理数幂：

Wolfram Language code: DivisorSigma[1 / 2, 12]

高斯整数：

Wolfram Language code: DivisorSigma[1, 3 + I]

Wolfram Language code: DivisorSigma[2, 6, GaussianIntegers -> True]

对较大的整数进行计算：

Wolfram Language code: DivisorSigma[2, 10 ^ 30]

DivisorSigma 逐项作用于列表的各个元素：

Wolfram Language code: DivisorSigma[2, {1, 2, 3, 4, 5}]

符号运算 (8)

TraditionalForm 格式：

Wolfram Language code: DivisorSigma[k, n]//TraditionalForm

约简表达式：

Wolfram Language code: Reduce[DivisorSigma[1, n] == 3n && 0 < n < 4000, n, Integers]

解方程：

Wolfram Language code: Solve[DivisorSigma[2, n] == n ^ 2 + 1 && 0 < n < 10, n, Integers]

化简表达式：

Wolfram Language code: FullSimplify[DivisorSigma[1, 2 ^ (p - 1)(2 ^ p - 1)], Element[2 ^ p - 1, Primes]]

Wolfram Language code: FullSimplify[DivisorSigma[0, n] < EulerPhi[n], n∈Integers && n > 30]

在和中使用 DivisorSigma：

Wolfram Language code: Sum[DivisorSigma[0, n] / n ^ s, {n, Infinity}]

DirichletTransform：

Wolfram Language code: DirichletTransform[DivisorSigma[k, n], s, n]

对符号参数进行计算：

Wolfram Language code: DivisorSigma[k, 30]

生成函数：

Wolfram Language code: Sum[DivisorSigma[k, n] / n ^ s, {n, Infinity}]

选项 (1)

GaussianIntegers (1)

在整数上求的除数的和：

Wolfram Language code: DivisorSigma[1, 6]

高斯整数：

Wolfram Language code: DivisorSigma[1, 6, GaussianIntegers -> True]

应用 (13)

基本应用 (3)

一般情况下，DivisorSigma[d,n]=∑_k|nk^d：

Wolfram Language code: Table[{DivisorSigma[d, 2 ^ 12 - 1], Sum[k ^ d, {k, Divisors[2 ^ 12 - 1]}]}, {d, 0, 5}]//Grid

高斯因数与整数因数的比：

Wolfram Language code: ListPlot[Table[DivisorSigma[0, n, GaussianIntegers -> True] / DivisorSigma[0, n], {n, 200}], Filling -> Axis]

用对数值绘制 DivisorSigma：

Wolfram Language code: DiscretePlot[{DivisorSigma[0, n], DivisorSigma[1, n], DivisorSigma[2, n]}, {n, 50}, ...]

特殊序列 (4)

识别完美数，即因数的和等于的数字 n：

Wolfram Language code: Select[Range[30], DivisorSigma[1, #] == 2#&]

亏数，即因数的和小于的数字 n：

Wolfram Language code: Select[Range[30], DivisorSigma[1, #] < 2#&]

过剩数，即因数的和大于的数字 n：

Wolfram Language code: Select[Range[30], DivisorSigma[1, #] > 2#&]

识别高合成数： [更多信息]

Wolfram Language code: highlyCompositeQ[n_] := Length[Select[Range[n - 1], DivisorSigma[0, #] ≥ DivisorSigma[0, n]&]] == 0;

Wolfram Language code: Select[Range[20], highlyCompositeQ]

识别亲和数，即两个不同的数，每个数的真除数的和等于另一个数字：

Wolfram Language code: amicablePairQ[n_, m_] := DivisorSigma[1, n] - n == m && DivisorSigma[1, m] - m == n;

Wolfram Language code: amicablePairQ[220, 284]

Wolfram Language code: amicablePairQ[10, 4]

识别 -重完美数，即因数的和等于的数：

Wolfram Language code: kPerfectQ[k_, n_] := DivisorSigma[1, n] == k n;

第一个 -重完美数是 :

Wolfram Language code: kPerfectQ[3, 120]

-重完美数被称为完美数：

Wolfram Language code: kPerfectQ[2, 6]

数论 (6)

如果 n 是的幂，那么 n 的因数的和等于，使得 n 几乎成为完美数：

Wolfram Language code:

n = 2 ^ 10;
{DivisorSigma[1, n], 2 n - 1}

当且仅当一个数是一个完美平方数时，因数的数量是奇数：

Wolfram Language code: DivisorSigma[0, #]&@{2, 3, 5, 6, 7, 8, 10}

Wolfram Language code: DivisorSigma[0, #]&@{1, 4, 9}

将因数的数量与 Euler 总计函数进行比较：

Wolfram Language code: DiscretePlot[{EulerPhi[n], DivisorSigma[0, n]}, {n, 50}, Rule[...]]

绘制因数数量的移动平均值及其渐近值：

Wolfram Language code: Show[ListPlot[Table[Sum[DivisorSigma[0, i], {i, n}] / n, {n, 50}]], Plot[Log[n] + 2EulerGamma - 1, {n, 1, 50}]]

计算迭代的 aliquot sum：

Wolfram Language code: NestList[DivisorSigma[1, #] - #&, 276, 20]

Wolfram Language code: ListLinePlot[Log[10, NestList[DivisorSigma[1, #] - #&, 276, 100]]]

显示极限变化的情况：

Wolfram Language code: ListLinePlot[Table[Table[Log[DivisorSigma[n, n + m] / DivisorSigma[n, n]], {n, 100}], {m, 5}]]

属性和关系 (6)

DivisorSigma 是因数的次幂的和：

Wolfram Language code: Total[Divisors[100] ^ 5]

Wolfram Language code: DivisorSigma[5, 100]

用 DivisorSum 求因数的和：

Wolfram Language code: DivisorSum[100, # ^ 5&]

DivisorSigma 是一个乘法函数：

Wolfram Language code: DivisorSigma[3, 18] DivisorSigma[3, 25] == DivisorSigma[3, 18 25]

完美数 n 的因数的倒数的和必须为：

Wolfram Language code: PerfectNumberQ[28]

Wolfram Language code: DivisorSigma[-1, 28]

素数幂 n 的因数之和小于 2n：

Wolfram Language code: (DivisorSigma[1, #] < 2#) & /@ Select[Range[100], PrimePowerQ]

对于素数 p，因数的数量为：

Wolfram Language code: p = RandomPrime[100];

Wolfram Language code: DivisorSigma[0, p] == 2

因数的和为：

Wolfram Language code: DivisorSigma[1, p] == p + 1

的因数的数量为：

Wolfram Language code:

n = 5;
DivisorSigma[0, p ^ n] == n + 1

用 DivisorSigma 求因数的积：

Wolfram Language code:

a = 24;
Product[d, {d, Divisors[a]}]

Wolfram Language code: a ^ (1 / 2DivisorSigma[0, a])

可能存在的问题 (1)

设置 GaussianIntegers->True，原始定义不会给出正确结果：

Wolfram Language code: DivisorSigma[2, 100, GaussianIntegers -> True]

Wolfram Language code: Total[Divisors[100, GaussianIntegers -> True] ^ 2]

DivisorSigma 成为一个乘法函数，使用包含因子的定义：

Wolfram Language code:

Times@@((#1 ^ ((#2 + 1)2) - 1) / (#1 ^ 2 - 1)&@@@({Select[#1 {1, -1, I, -I}, (Re[#] > 0 && Im[#] > 0)&][[1]], #2}&@@@FactorInteger[100, GaussianIntegers -> True]))

巧妙范例 (4)

绘制 DivisorSigma 的傅立叶变换的参数：

Wolfram Language code: ArrayPlot[Arg[Fourier[Table[DivisorSigma[m, n], {m, 100}, {n, 100}]]], ColorFunction -> Hue]

绘制 DivisorSigma 的傅立叶变换的绝对值：

Wolfram Language code: ArrayPlot[Abs[Fourier[Table[DivisorSigma[m, n], {m, 100}, {n, 100}]]], ColorFunction -> Hue]

绘制 DivisorSigma 的傅立叶变换的参数：

Wolfram Language code:

ArrayPlot[Arg[Fourier[Table[If[x + I y == 0, 0, DivisorSigma[4, x + I y, GaussianIntegers -> True]], {x, 0, 128}, {y, 0, 128}]]], ColorFunction -> "Rainbow"]

绘制因数的均值的 Ulam 螺旋：

Wolfram Language code:

ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table
	[(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n];

Wolfram Language code: ArrayPlot[DivisorSigma[0, ulam[71]], ColorFunction -> "Rainbow"]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

DivisorSigma

更多信息和选项

范例

基本范例 (2)

范围 (12)

数值运算 (4)

符号运算 (8)

选项 (1)

GaussianIntegers (1)

应用 (13)

基本应用 (3)

特殊序列 (4)

数论 (6)

属性和关系 (6)

可能存在的问题 (1)

巧妙范例 (4)

文本

CMS

APA

BibTeX

BibLaTeX

DivisorSigma

更多信息和选项

范例

基本范例 (2)

范围 (12)

数值运算 (4)

符号运算 (8)

选项 (1)

GaussianIntegers (1)

应用 (13)

基本应用 (3)

特殊序列 (4)

数论 (6)

属性和关系 (6)

可能存在的问题 (1)

巧妙范例 (4)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX