WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

EffectiveInterest[r,q]

時間間隔 q で複利計算して，利子指定 r に対応する実行利息率を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

EffectiveInterest

EffectiveInterest[r,q]

時間間隔 q で複利計算して，利子指定 r に対応する実行利息率を与える．

詳細とオプション

  • EffectiveInterestはTimeValueで使用するのに適した式を返す．
  • EffectiveInterestは数値あるいは任意記号の式に使える．
  • EffectiveInterestによって返される記号式は，名目率について解くことができ，期間あるいは時間パラメータを複利計算する．
  • EffectiveInterest[r,q]では，利子 r は以下の形式で指定できる．
  • r名目金利
    {r1,r2,…}単位時間間隔に対して適用される率の一覧表
    {{t1,r1},{t2,r2},…}指定時間で変化する先物相場の一覧表
    {p1->r1,p2->r2,…}金利の時間構造
  • EffectiveInterest[r,q]は，r と同じ形式で式を返す．
  • EffectiveInterest[r,0]は連続複利計算を指定する．
  • EffectiveInterest[{r1,r2,…}]は，利率表{r1,r2,…}に対応する年複利成長率(CAGR)を与える．
  • EffectiveInterest[{p1->r1,p2->r2,…}]は，将来の直物相場の等しい一覧表を与える．

例題

すべて開く すべて閉じる

例  (4)

期間中に4回複利計算される5%の名目金利に対応する実効利率：

Wolfram Language code: EffectiveInterest[.05, 1 / 4]

期間中に12回複利計算される実効利率に対する名目金利の一覧表：

Wolfram Language code: EffectiveInterest[{.05, .065, .07, .085}, 1 / 12]

利率の一覧表に対応する年複利成長率(CAGR)：

Wolfram Language code: EffectiveInterest[{.05, .065, .04, .07, .085}]

名目利率のスケジュールを1期間あたり12回複利の実効利率に変換する：

Wolfram Language code: EffectiveInterest[{{0, .05}, {3, .065}, {5, .07}, {6, .085}}, 1 / 12]

スコープ  (8)

ゼロの利息計算時間は，連続複利計算を指定するのに使える：

Wolfram Language code: EffectiveInterest[.1, 0]

利息を元本に組み入れる積分頻度は，期間に1度より少ない頻度での複利計算を指定するのに使えることがある．予測通り，この場合の実効利率は名目金利よりも小さい：

Wolfram Language code: EffectiveInterest[.06, 3]

単利は，成長期間に等しい積分利息計算時間を使ってシミュレーションを行うことができる：

Wolfram Language code: TimeValue[100, EffectiveInterest[.06, 5], 5]

これは，類似の単利計算に等しい：

Wolfram Language code: 100(1 + .06 * 5)

金利の期間構造（イールドカーブ）を，インプライド・フォワードレートの一覧と，それらが有効である区間に変換する：

Wolfram Language code: EffectiveInterest[{1 / 12 -> .01, 3 / 12 -> .015, 6 / 12 -> .02, 1 -> .025, 2 -> .03, 3 -> .032, 5 -> .035, 7 -> .04, 10 -> .045}]

EffectiveInterestは，記号パラメータに使える：

Wolfram Language code: EffectiveInterest[r, 1 / f]
Wolfram Language code: EffectiveInterest[{r1, r2, r3, r4}]
Wolfram Language code: EffectiveInterest[{1 -> r3, 2 -> r4, 3 -> r5, 5 -> r6, 7 -> r7}]

4半期ごとの複利5%の実効金利に対応する表面金利を求める：

Wolfram Language code: FindRoot[EffectiveInterest[r, 1 / 4] == .05, {r, .05}]

EffectiveInterestを使う方程式の解は，記号パラメータで求めることができる：

Wolfram Language code: Solve[EffectiveInterest[nominalrate, 1 / f] == eff, nominalrate]//Quiet

EffectiveInterestをTimeValueと共に使用する：

Wolfram Language code: TimeValue[100, EffectiveInterest[.06, 1 / 12], 10]

TimeSeriesからのEffectiveInterest：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{0.04, 0.05, 0.06, 0.07, 0.08}}, {{0, 4, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1];
Wolfram Language code: EffectiveInterest[ts, 3]

アプリケーション  (1)

貸手Aは，連続複利計算で年に8%の金利のローンにおける名目金利を見積もる．貸手Bは年に4回複利計算を行う場合の金利を見積もる．貸手Aの金利を年に4回複利計算を行う場合の金利に変換し，2つの金利を比べられるようにする：

Wolfram Language code: Solve[{r > 0, EffectiveInterest[.08, 0] == EffectiveInterest[r, 1 / 4]}, r]

FindRootを代りに使う：

Wolfram Language code: FindRoot[EffectiveInterest[.08, 0] == EffectiveInterest[r, 1 / 4], {r, .08}]

特性と関係  (2)

増える頻度で複利計算を行う名目金利の（連続複利計算への）収束を調べる：

Wolfram Language code: g1 = TimeValue[100, EffectiveInterest[.3, 0], n]
Wolfram Language code: {g2, g3, g4, g5} = Table[TimeValue[100, EffectiveInterest[.3, 1 / i], n], {i, 1, 4}]
Wolfram Language code: Plot[{g1, g2, g3, g4, g5}, {n, 1, 5}, Epilog -> Arrow[{{4.8, 350}, {4.8, 425}}], AxesLabel -> {"time", "future value"}, ImageSize -> 300]

名目金利が複利回数の増加に伴って連続複利へ収束する様子を検討する：

Wolfram Language code: g1 = EffectiveInterest[r, 0]
Wolfram Language code: {g2, g3, g4, g5, g6, g7} = Table[EffectiveInterest[r, 1 / i], {i, 1, 6}]
Wolfram Language code: Plot[{g1, g2, g3, g4, g5, g6, g7}, {r, .05, .7}, Epilog -> Arrow[{{.68, .67}, {.68, .96}}], AxesLabel -> {"nominal rate", "effective rate"}, ImageSize -> 300]
Wolfram Research (2010), EffectiveInterest, Wolfram言語関数， https://reference.wolfram.com/language/ref/EffectiveInterest.html.

テキスト

Wolfram Research (2010), EffectiveInterest, Wolfram言語関数， https://reference.wolfram.com/language/ref/EffectiveInterest.html.

CMS

Wolfram Language. 2010. "EffectiveInterest." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/EffectiveInterest.html.

APA

Wolfram Language. (2010). EffectiveInterest. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EffectiveInterest.html

BibTeX

@misc{reference.wolfram_2026_effectiveinterest, author="Wolfram Research", title="{EffectiveInterest}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/EffectiveInterest.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_effectiveinterest, organization={Wolfram Research}, title={EffectiveInterest}, year={2010}, url={https://reference.wolfram.com/language/ref/EffectiveInterest.html}, note=[Accessed: 04-September-2026]}