WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

EllipticThetaPrime[a,u,q]

シータ関数 TemplateBox[{a, u, q}, EllipticTheta] の u による導関数を与える．

EllipticThetaPrime[a,q]

シータ定数 TemplateBox[{a, 0, q}, EllipticThetaPrime]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
関数の特性  
積分  
一般化と拡張  
アプリケーション  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

EllipticThetaPrime

EllipticThetaPrime[a,u,q]

シータ関数 TemplateBox[{a, u, q}, EllipticTheta] の u による導関数を与える．

EllipticThetaPrime[a,q]

シータ定数 TemplateBox[{a, 0, q}, EllipticThetaPrime]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 特別な引数の場合，EllipticThetaPrimeは，自動的に厳密値を計算する．
  • EllipticThetaPrimeは任意の数値精度で評価できる．
  • EllipticThetaPrimeは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

数値的に評価する：

Wolfram Language code: EllipticThetaPrime[2, 2.3, 1 / 3]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[EllipticThetaPrime[2, x, 1 / 3], {x, -6, 6}]

原点における q についての級数展開：

Wolfram Language code: Series[EllipticThetaPrime[1, x, q], {q, 0, 10}]

スコープ  (21)

数値評価  (4)

数値的に評価する：

Wolfram Language code: EllipticThetaPrime[2, 5, .5]
Wolfram Language code: EllipticThetaPrime[1, .4, .5]

高精度で評価する：

Wolfram Language code: N[EllipticThetaPrime[3, 15, 1 / 3], 25]

出力精度は入力精度に従う：

Wolfram Language code: EllipticThetaPrime[3, 8, .600055555555000055005]

複素数入力：

Wolfram Language code: EllipticThetaPrime[2, .4 + I, .5I]

高精度で効率的に評価する：

Wolfram Language code: EllipticThetaPrime[2, 5, .5`100]//Timing
Wolfram Language code: EllipticThetaPrime[2, 5, .5`10000];//Timing

特定の値  (3)

ゼロにおける値：

Wolfram Language code: EllipticThetaPrime[1, 0, 0]

EllipticThetaPrimeは，特定の引数については記号的に評価される：

Wolfram Language code: Table[EllipticThetaPrime[j, z, 0], {j, 4}]

EllipticThetaPrime[3,x,1/2]=2となるような の値を求める：

Wolfram Language code: xval = x /. FindRoot[EllipticThetaPrime[3, x, 1 / 2] == 2, {x, 1}]//Quiet
Wolfram Language code: Plot[EllipticThetaPrime[3, x, 1 / 2], {x, -1, 4}, Epilog -> Style[Point[{xval, EllipticThetaPrime[3, xval, 1 / 2]}], PointSize[Large], Red]]

可視化  (2)

EllipticThetaPrime関数をさまざまなパラメータについてプロットする：

Wolfram Language code: Plot[{EllipticThetaPrime[1, x, 1 / 2], EllipticThetaPrime[2, x, 1 / 2], EllipticThetaPrime[3, x, 1 / 2], EllipticThetaPrime[4, x, 1 / 2]}, {x, -5, 5}]

TemplateBox[{4, z, {1, /, 3}}, EllipticThetaPrime]の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[EllipticThetaPrime[4, z, 1 / 3]], {z, -3 - 3I, 3 + 3 I}, Contours -> 24]

TemplateBox[{4, z, {1, /, 3}}, EllipticThetaPrime]の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[EllipticThetaPrime[4, z, 1 / 3]], {z, -3 - 3I, 3 + 3 I}, Contours -> 24]

関数の特性  (10)

EllipticThetaPrimeの実領域と複素領域：

Wolfram Language code: Table[FunctionDomain[EllipticThetaPrime[a, x, q], {x, q}], {a, 4}]
Wolfram Language code: Table[FunctionDomain[EllipticThetaPrime[a, z, q], {z, q}, Complexes], {a, 4}]

EllipticThetaPrimeは について周期関数である：

Wolfram Language code: Table[FunctionPeriod[EllipticThetaPrime[a, z, q], z], {a, 4}]

EllipticThetaPrimeは要素単位でリストに縫い込まれる：

Wolfram Language code: EllipticThetaPrime[{1, 2, 3, 4}, z, q]
Wolfram Language code: EllipticThetaPrime[2, {Pi / 2, Pi}, 1 / 2]

TemplateBox[{1, x, q}, EllipticThetaPrime]は x の解析関数である：

Wolfram Language code: FunctionAnalytic[EllipticThetaPrime[1, x, q], x, Assumptions -> 0 < q < 1]

例えば，TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime]は特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[EllipticThetaPrime[1, x, 1 / 2], x]//Quiet
Wolfram Language code: FunctionDiscontinuities[EllipticThetaPrime[1, x, 1 / 2], x]//Quiet

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime]は非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[EllipticThetaPrime[1, x, 1 / 2], x]

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime]は単射ではない：

Wolfram Language code: FunctionInjective[EllipticThetaPrime[1, x, 1 / 2], x]
Wolfram Language code: Plot[{EllipticThetaPrime[1, x, 1 / 2], 1}, {x, -6, 6}]

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime]は全射ではない：

Wolfram Language code: FunctionSurjective[EllipticThetaPrime[1, x, 1 / 2], x]//Quiet
Wolfram Language code: Plot[{EllipticThetaPrime[1, x, 1 / 2], -5}, {x, -6, 6}]

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime]は非負でも非正でもない：

Wolfram Language code: FunctionSign[EllipticThetaPrime[1, x, 1 / 2], x]

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime]は凸でも凹でもない：

Wolfram Language code: FunctionConvexity[EllipticThetaPrime[1, x, 1 / 2], x]

TraditionalFormによる表示：

Wolfram Language code: EllipticThetaPrime[3, z, q] // TraditionalForm
Wolfram Language code: EllipticThetaPrime[a, q] // TraditionalForm

積分  (2)

Integrateを使って不定積分を計算する：

Wolfram Language code: Integrate[EllipticThetaPrime[a, u, q], u]

不定積分を確かめる：

Wolfram Language code: FullSimplify[D[%, u]]

定積分：

Wolfram Language code: Integrate[EllipticThetaPrime[a, u, q], {u, 0, 5}]

一般化と拡張  (1)

EllipticThetaPrimeはベキ級数に適用することができる：

Wolfram Language code: EllipticThetaPrime[2, z, Log[1 + q] + O[q]^4]

アプリケーション  (4)

ヤコビの三重積恒等式を級数展開を介して検証する：

Wolfram Language code: Series[EllipticThetaPrime[1, q] - EllipticTheta[2, q]EllipticTheta[3, q]EllipticTheta[4, q], {q, 0, 9}]

ディリクレ(Dirichlet)の境界条件を持ち初期条件が である一次元熱伝導方程式についてのグリーン(Green)の関数：

Wolfram Language code: T[{x_, t_}, x0_, L_] := (1/2L) (EllipticTheta[3, (π/2L) (x - x0), E^-((π/L))^2t] - EllipticTheta[3, (π/2L)(x + x0), E^-((π/L))^2t])

温度勾配を計算する：

Wolfram Language code: gradT[{x_, t_}, x0_, L_] = D[T[{x, t}, x0, L], x]

温度勾配をプロットする：

Wolfram Language code: Plot3D[gradT[{x, t}, 0.6, 1], {x, 0, 1}, {t, 0.01, 0.1}, PlotRange -> All]

点状のイオンを持ったNaCl様の結晶内の静電気力：

Wolfram Language code: fNaCl[{x_, y_, z_}] := (16/π)NIntegrate[{2 π t EllipticTheta[2, 2 π y, E^-t^2] EllipticTheta[2, 2 π z, E^-t^2]EllipticThetaPrime[2, 2 π x, E^-t^2], 2 π t EllipticTheta[2, 2 π x, E^-t^2]EllipticTheta[2, 2 π z, E^-t^2] EllipticThetaPrime[2, 2 π y, E^-t^2], 2 π t EllipticTheta[2, 2 π x, E^-t^2] EllipticTheta[2, 2 π y, E^-t^2]EllipticThetaPrime[2, 2 π z, E^-t^2]}, {t, 0, ∞}, PrecisionGoal -> 5]

結晶を通る平面上の力の強さをプロットする：

Wolfram Language code: ListPlot3D[Table[Norm[fNaCl[{x, y, 0.3}]], {x, 0, 1, 1 / 10}, {y, 0, 1, 1 / 10}]]//Quiet

直鎖状分子の標準的な回転分布関数：

Wolfram Language code: Ω[β_] := (1/2) - Subsuperscript[∫, 0, ∞](1/8 Sqrt[π] t^3 / 2)E^-t (-4 t EllipticTheta[3, 0, E^-(β (4 t + β)/4 t)] + β EllipticThetaPrime^(0, 1, 0)[3, 0, E^-(β (4 t + β)/4 t)])ⅆt

分配関数の数値近似をプロットする：

Wolfram Language code: ListLinePlot[Table[Ω[β] /. Integrate[a_, {t, b_, c_}] :> NIntegrate[a, {t, 10 ^ -3, 10}], {β, 1 / 4, 3, 1 / 4}]]

考えられる問題  (4)

機械精度の入力は正しい答を得るのには不十分である：

Wolfram Language code: EllipticThetaPrime[1, 10. ^ 30, 1 / Pi]

任意精度の演算で正しい結果を得る：

Wolfram Language code: N[EllipticThetaPrime[1, 10 ^ 30, 1 / Pi], 20]

第1引数は1から4までの明示的な整数でなければならない：

Wolfram Language code: EllipticThetaPrime[1 + (E + 1) ^ 2 - E ^ 2 - 2E - 1, 3., 1 / 2]
Wolfram Language code: Simplify[%]

EllipticThetaPrimeは，属性NHoldFirstを有する：

Wolfram Language code: Attributes[EllipticThetaPrime]

シータ関数についての異なる引数の慣習もある：

Wolfram Language code: {Plot[EllipticThetaPrime[1, z, 1 / 2], {z, 0, 2π}], Plot[EllipticThetaPrime[1, (z/2π), 1 / 2], {z, 0, 2π}]}
Wolfram Language code: {Plot[EllipticThetaPrime[1, 2, q], {q, 0.1, 0.8}], Plot[EllipticThetaPrime[1, 2, Exp[I π (I τ)]], {τ, 0.1, 0.8}]}

おもしろい例題  (1)

解析性の境界を持つ関数を可視化する：

Wolfram Language code: Module[{f, R = 0.99}, f[z_ ? NumberQ] := If[Abs[z] > R, 0, Sin[Arg[EllipticThetaPrime[2, 1, z]] / 2]^2]; DensityPlot[f[qx + I qy], {qx, qy}∈Disk[{0, 0}, R], Frame -> False, PlotPoints -> 90, ColorFunction -> (Hue[2.72 #]&)]]
Wolfram Research (1996), EllipticThetaPrime, Wolfram言語関数， https://reference.wolfram.com/language/ref/EllipticThetaPrime.html （2017年に更新）.

テキスト

Wolfram Research (1996), EllipticThetaPrime, Wolfram言語関数， https://reference.wolfram.com/language/ref/EllipticThetaPrime.html （2017年に更新）.

CMS

Wolfram Language. 1996. "EllipticThetaPrime." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/EllipticThetaPrime.html.

APA

Wolfram Language. (1996). EllipticThetaPrime. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EllipticThetaPrime.html

BibTeX

@misc{reference.wolfram_2026_ellipticthetaprime, author="Wolfram Research", title="{EllipticThetaPrime}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/EllipticThetaPrime.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_ellipticthetaprime, organization={Wolfram Research}, title={EllipticThetaPrime}, year={2017}, url={https://reference.wolfram.com/language/ref/EllipticThetaPrime.html}, note=[Accessed: 08-September-2026]}