WOLFRAM

Wolfram 语言与系统参考资料中心

EllipticThetaPrime[a,u,q]

给出 theta 函数 TemplateBox[{a, u, q}, EllipticTheta] 关于 u 的导数.

EllipticThetaPrime[a,q]

给出 theta 常数 TemplateBox[{a, 0, q}, EllipticThetaPrime].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
函数的属性  
积分  
推广和延伸  
应用  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

EllipticThetaPrime

EllipticThetaPrime[a,u,q]

给出 theta 函数 TemplateBox[{a, u, q}, EllipticTheta] 关于 u 的导数.

EllipticThetaPrime[a,q]

给出 theta 常数 TemplateBox[{a, 0, q}, EllipticThetaPrime].

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

数值计算：

Wolfram Language code: EllipticThetaPrime[2, 2.3, 1 / 3]

在实数的子集上绘图：

Wolfram Language code: Plot[EllipticThetaPrime[2, x, 1 / 3], {x, -6, 6}]

在原点处关于 q 的级数展开式：

Wolfram Language code: Series[EllipticThetaPrime[1, x, q], {q, 0, 10}]

范围  (21)

数值计算  (4)

数值计算：

Wolfram Language code: EllipticThetaPrime[2, 5, .5]
Wolfram Language code: EllipticThetaPrime[1, .4, .5]

高精度计算：

Wolfram Language code: N[EllipticThetaPrime[3, 15, 1 / 3], 25]

输出的精度与输入的精度一致：

Wolfram Language code: EllipticThetaPrime[3, 8, .600055555555000055005]

复数输入：

Wolfram Language code: EllipticThetaPrime[2, .4 + I, .5I]

在高精度条件下进行高效计算：

Wolfram Language code: EllipticThetaPrime[2, 5, .5`100]//Timing
Wolfram Language code: EllipticThetaPrime[2, 5, .5`10000];//Timing

特殊值  (3)

零处的值：

Wolfram Language code: EllipticThetaPrime[1, 0, 0]

EllipticThetaPrime 符号式计算特殊参数：

Wolfram Language code: Table[EllipticThetaPrime[j, z, 0], {j, 4}]

求当 EllipticThetaPrime[3,x,1/2]=2 时 的值：

Wolfram Language code: xval = x /. FindRoot[EllipticThetaPrime[3, x, 1 / 2] == 2, {x, 1}]//Quiet
Wolfram Language code: Plot[EllipticThetaPrime[3, x, 1 / 2], {x, -1, 4}, Epilog -> Style[Point[{xval, EllipticThetaPrime[3, xval, 1 / 2]}], PointSize[Large], Red]]

可视化  (2)

绘制各种参数值的 EllipticThetaPrime 函数：

Wolfram Language code: Plot[{EllipticThetaPrime[1, x, 1 / 2], EllipticThetaPrime[2, x, 1 / 2], EllipticThetaPrime[3, x, 1 / 2], EllipticThetaPrime[4, x, 1 / 2]}, {x, -5, 5}]

绘制 TemplateBox[{4, z, {1, /, 3}}, EllipticThetaPrime] 的实部：

Wolfram Language code: ComplexContourPlot[Re[EllipticThetaPrime[4, z, 1 / 3]], {z, -3 - 3I, 3 + 3 I}, Contours -> 24]

绘制 TemplateBox[{4, z, {1, /, 3}}, EllipticThetaPrime] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[EllipticThetaPrime[4, z, 1 / 3]], {z, -3 - 3I, 3 + 3 I}, Contours -> 24]

函数的属性  (10)

EllipticThetaPrime 的实数和复数定义域：

Wolfram Language code: Table[FunctionDomain[EllipticThetaPrime[a, x, q], {x, q}], {a, 4}]
Wolfram Language code: Table[FunctionDomain[EllipticThetaPrime[a, z, q], {z, q}, Complexes], {a, 4}]

EllipticThetaPrime 是关于 的周期函数：

Wolfram Language code: Table[FunctionPeriod[EllipticThetaPrime[a, z, q], z], {a, 4}]

EllipticThetaPrime 逐项作用于列表的各个元素：

Wolfram Language code: EllipticThetaPrime[{1, 2, 3, 4}, z, q]
Wolfram Language code: EllipticThetaPrime[2, {Pi / 2, Pi}, 1 / 2]

TemplateBox[{1, x, q}, EllipticThetaPrime] 是 x 的解析函数：

Wolfram Language code: FunctionAnalytic[EllipticThetaPrime[1, x, q], x, Assumptions -> 0 < q < 1]

例如，TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime] 没有奇点或断点：

Wolfram Language code: FunctionSingularities[EllipticThetaPrime[1, x, 1 / 2], x]//Quiet
Wolfram Language code: FunctionDiscontinuities[EllipticThetaPrime[1, x, 1 / 2], x]//Quiet

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime] 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[EllipticThetaPrime[1, x, 1 / 2], x]

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime] 不是单射函数：

Wolfram Language code: FunctionInjective[EllipticThetaPrime[1, x, 1 / 2], x]
Wolfram Language code: Plot[{EllipticThetaPrime[1, x, 1 / 2], 1}, {x, -6, 6}]

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime] 不是满射函数：

Wolfram Language code: FunctionSurjective[EllipticThetaPrime[1, x, 1 / 2], x]//Quiet
Wolfram Language code: Plot[{EllipticThetaPrime[1, x, 1 / 2], -5}, {x, -6, 6}]

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime] 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[EllipticThetaPrime[1, x, 1 / 2], x]

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime] 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[EllipticThetaPrime[1, x, 1 / 2], x]

TraditionalForm 格式：

Wolfram Language code: EllipticThetaPrime[3, z, q] // TraditionalForm
Wolfram Language code: EllipticThetaPrime[a, q] // TraditionalForm

积分  (2)

用 Integrate 计算不定积分：

Wolfram Language code: Integrate[EllipticThetaPrime[a, u, q], u]

验证反导数：

Wolfram Language code: FullSimplify[D[%, u]]

定积分：

Wolfram Language code: Integrate[EllipticThetaPrime[a, u, q], {u, 0, 5}]

推广和延伸  (1)

EllipticThetaPrime 可用于幂级数：

Wolfram Language code: EllipticThetaPrime[2, z, Log[1 + q] + O[q]^4]

应用  (4)

通过数列展开验证 Jacobi 三重乘积恒等式（ Jacobi's triple product identity）：

Wolfram Language code: Series[EllipticThetaPrime[1, q] - EllipticTheta[2, q]EllipticTheta[3, q]EllipticTheta[4, q], {q, 0, 9}]

具有 Dirichlet 边界条件和初始条件 的一维热方程的格林函数（Green's function）：

Wolfram Language code: T[{x_, t_}, x0_, L_] := (1/2L) (EllipticTheta[3, (π/2L) (x - x0), E^-((π/L))^2t] - EllipticTheta[3, (π/2L)(x + x0), E^-((π/L))^2t])

计算温度梯度：

Wolfram Language code: gradT[{x_, t_}, x0_, L_] = D[T[{x, t}, x0, L], x]

绘制温度梯度：

Wolfram Language code: Plot3D[gradT[{x, t}, 0.6, 1], {x, 0, 1}, {t, 0.01, 0.1}, PlotRange -> All]

氯化钠晶体离子点间的静电力：

Wolfram Language code: fNaCl[{x_, y_, z_}] := (16/π)NIntegrate[{2 π t EllipticTheta[2, 2 π y, E^-t^2] EllipticTheta[2, 2 π z, E^-t^2]EllipticThetaPrime[2, 2 π x, E^-t^2], 2 π t EllipticTheta[2, 2 π x, E^-t^2]EllipticTheta[2, 2 π z, E^-t^2] EllipticThetaPrime[2, 2 π y, E^-t^2], 2 π t EllipticTheta[2, 2 π x, E^-t^2] EllipticTheta[2, 2 π y, E^-t^2]EllipticThetaPrime[2, 2 π z, E^-t^2]}, {t, 0, ∞}, PrecisionGoal -> 5]

绘制穿过晶体平面作用力的大小：

Wolfram Language code: ListPlot3D[Table[Norm[fNaCl[{x, y, 0.3}]], {x, 0, 1, 1 / 10}, {y, 0, 1, 1 / 10}]]//Quiet

线性分子学 的典型旋转分布函数：

Wolfram Language code: Ω[β_] := (1/2) - Subsuperscript[∫, 0, ∞](1/8 Sqrt[π] t^3 / 2)E^-t (-4 t EllipticTheta[3, 0, E^-(β (4 t + β)/4 t)] + β EllipticThetaPrime^(0, 1, 0)[3, 0, E^-(β (4 t + β)/4 t)])ⅆt

绘制配分函数的近似数值：

Wolfram Language code: ListLinePlot[Table[Ω[β] /. Integrate[a_, {t, b_, c_}] :> NIntegrate[a, {t, 10 ^ -3, 10}], {β, 1 / 4, 3, 1 / 4}]]

可能存在的问题  (4)

机器精度输入不足以给出正确答案：

Wolfram Language code: EllipticThetaPrime[1, 10. ^ 30, 1 / Pi]

用任意精度算法获得正确结果：

Wolfram Language code: N[EllipticThetaPrime[1, 10 ^ 30, 1 / Pi], 20]

第一自变量一定是 1 和 4 之间具体的整数：

Wolfram Language code: EllipticThetaPrime[1 + (E + 1) ^ 2 - E ^ 2 - 2E - 1, 3., 1 / 2]
Wolfram Language code: Simplify[%]

EllipticThetaPrime 有属性 NHoldFirst：

Wolfram Language code: Attributes[EllipticThetaPrime]

对于 theta 函数存在不同的参数约定：

Wolfram Language code: {Plot[EllipticThetaPrime[1, z, 1 / 2], {z, 0, 2π}], Plot[EllipticThetaPrime[1, (z/2π), 1 / 2], {z, 0, 2π}]}
Wolfram Language code: {Plot[EllipticThetaPrime[1, 2, q], {q, 0.1, 0.8}], Plot[EllipticThetaPrime[1, 2, Exp[I π (I τ)]], {τ, 0.1, 0.8}]}

巧妙范例  (1)

可视化显示解析的边界函数：

Wolfram Language code: Module[{f, R = 0.99}, f[z_ ? NumberQ] := If[Abs[z] > R, 0, Sin[Arg[EllipticThetaPrime[2, 1, z]] / 2]^2]; DensityPlot[f[qx + I qy], {qx, qy}∈Disk[{0, 0}, R], Frame -> False, PlotPoints -> 90, ColorFunction -> (Hue[2.72 #]&)]]
Wolfram Research (1996)，EllipticThetaPrime，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EllipticThetaPrime.html （更新于 2017 年）.

文本

Wolfram Research (1996)，EllipticThetaPrime，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EllipticThetaPrime.html （更新于 2017 年）.

CMS

Wolfram 语言. 1996. "EllipticThetaPrime." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2017. https://reference.wolfram.com/language/ref/EllipticThetaPrime.html.

APA

Wolfram 语言. (1996). EllipticThetaPrime. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EllipticThetaPrime.html 年

BibTeX

@misc{reference.wolfram_2026_ellipticthetaprime, author="Wolfram Research", title="{EllipticThetaPrime}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/EllipticThetaPrime.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_ellipticthetaprime, organization={Wolfram Research}, title={EllipticThetaPrime}, year={2017}, url={https://reference.wolfram.com/language/ref/EllipticThetaPrime.html}, note=[Accessed: 16-September-2026]}