WOLFRAM

Wolfram 语言与系统参考资料中心

EstimatedPointNormals[{p1,p2,…}]

估计点 p1,p2,… 的法线向量.

EstimatedPointNormals[mreg]

估计网格区域 mreg 顶点的法线向量.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
规范  
选项  
Method  
应用  
基本应用  
点云渲染  
表面重建  
属性和关系  
互动范例  
巧妙范例  
参见
历史
按以下格式引用：

EstimatedPointNormals

EstimatedPointNormals[{p1,p2,…}]

估计点 p1,p2,… 的法线向量.

EstimatedPointNormals[mreg]

估计网格区域 mreg 顶点的法线向量.

更多信息和选项

  • EstimatedPointNormals 通常用于从一组点中找到超曲面方向.
  • EstimatedPointNormals[{p1,p2,…}] 给出一个列表 {n1,n2,…}，其中 ni 是 pi 的单位法向量.
  • EstimatedPointNormals[{p1,p2,…}] 中的 pi 可以是坐标列表或显式 Point 对象.
  • 也可以给出 Method 选项. 可能的 Method 设置包括：
  • "PlaneFitting"使用最近邻进行平面拟合
    "FaceWeighted"面部加权法线

范例

打开所有单元 关闭所有单元

基本范例  (3)

圆点的估计法线：

Wolfram Language code: pts = CirclePoints[20]; EstimatedPointNormals[pts]//Shallow
Wolfram Language code: Graphics[{Point[pts], Arrow /@ Transpose[{pts, pts + %}]}]

球体点的估计法线：

Wolfram Language code: pts = SpherePoints[100]; EstimatedPointNormals[pts]//Shallow
Wolfram Language code: Graphics3D[{Point[pts], Arrow /@ Transpose[{pts, pts + %}]}]

通过对表面随机采样生成点云：

Wolfram Language code: pts = RandomPoint[ResourceData["Stanford Bunny"], 20000]; Graphics3D[{AbsolutePointSize[1], Point[pts]}]

可视化带照明的估计法线：

Wolfram Language code: Graphics3D[{Point[pts, VertexNormals -> EstimatedPointNormals[pts]]}]

范围  (2)

基本用法  (1)

点在一维中的估计法线：

Wolfram Language code: pts = {{-0.9}, {-1.0}, {-1.1}, {0.9}, {1.0}, {1.1}}; EstimatedPointNormals[pts]
Wolfram Language code: Graphics[{Point[Append[#, 0]& /@ pts], Arrow /@ Transpose[{Append[#, 0]& /@ pts, Append[#, 0]& /@ (pts + %)}]}]

二维：

Wolfram Language code: pts = RandomPoint[Circle[], 50]; EstimatedPointNormals[pts]//Shallow
Wolfram Language code: Graphics[{Point[pts], Arrow /@ Transpose[{pts, pts + %}]}]

三维：

Wolfram Language code: pts = RandomPoint[Sphere[], 100]; EstimatedPointNormals[pts]//Shallow
Wolfram Language code: Graphics3D[{Point[pts], Arrow /@ Transpose[{pts, pts + %}]}]

维：

Wolfram Language code: pts = RandomPoint[Sphere[{0, 0, 0, 0, 0}], 120]; EstimatedPointNormals[pts]//Shallow

规范  (1)

EstimatedPointNormals 接受一组点：

Wolfram Language code: pts = {{-5, 0}, {-3, 0}, {-1, 0}, {1, 0}, {3, 0}, {5, 0}};
Wolfram Language code: EstimatedPointNormals[pts]

使用 Point 列表：

Wolfram Language code: EstimatedPointNormals[Point[pts]]

选项  (2)

Method  (2)

通过将每个点的局部邻域拟合到一个平面来估计点集的法线：

Wolfram Language code: EstimatedPointNormals[CirclePoints[8], Method -> "PlaneFitting"]

默认情况下，通过相邻面的法线的加权平均值估算网格顶点的法线：

Wolfram Language code: mesh = [image];
Wolfram Language code: coords = MeshCoordinates[mesh]; normals = EstimatedPointNormals[mesh];
Wolfram Language code: Show[mesh, Graphics3D[{Arrow[Transpose[{coords, coords + normals}]]}]]

改用平面拟合：

Wolfram Language code: pnormals = EstimatedPointNormals[mesh, Method -> "PlaneFitting"];
Wolfram Language code: Show[mesh, Graphics3D[{Arrow[Transpose[{coords, coords + pnormals}]]}]]

这相当于直接估计网格坐标的法线：

Wolfram Language code: EstimatedPointNormals[mesh, Method -> "PlaneFitting"] === EstimatedPointNormals[MeshCoordinates[mesh]]

应用  (3)

基本应用  (1)

给定光滑表面的充足密集采样，可以假设空间中彼此靠近的样本在平面上也彼此靠近：

Wolfram Language code: pts = Table[(2 + 2 / 3.5Sin[5 t]) * {Cos[t], Sin[t]}, {t, 0, 2 Pi, Pi / 40}]; nng = NearestNeighborGraph[pts, 4]

因此，每个点周围的局部表面由该点的最近邻域采样：

Wolfram Language code: ngs = NeighborhoodGraph[nng, pts[[#]]]& /@ {1, 10, 65}

该局部表面可以通过一个拟合到它的样本点的平面来近似：

Wolfram Language code: fitPlane[p_] := Hyperplane[Eigensystem[Covariance[p]][[2, 2]], Mean[p]] Show[#, Graphics[{Red, fitPlane[VertexList[#]]}]]& /@ ngs

这些拟合平面的法线可以用作它们对应点的法线的估计：

Wolfram Language code: nls = Table[n = Eigensystem[Covariance[AdjacencyList[nng, pts[[pi]]]]][[2, 2]]; n * Sign[Dot[n, pts[[pi]]]], {pi, Length[pts]}];
Wolfram Language code: Graphics[Table[Arrow[{pts[[pi]], pts[[pi]] + nls[[pi]]}], {pi, Length[pts]}]]

点云渲染  (1)

使用估计的法线渲染点云以进行照明计算：

Wolfram Language code: pts = RandomPoint[ResourceData["Cow"], 6000]; Graphics3D[{AbsolutePointSize[1], Point[pts]}]
Wolfram Language code: Graphics3D[{Point[pts, VertexNormals -> EstimatedPointNormals[pts]]}]

将渲染点云与地面实况模型进行比较：

Wolfram Language code: Graphics3D[{EdgeForm[], ResourceData["Cow"]}]

表面重建  (1)

估计在曲面重建期间要使用的法线：

Wolfram Language code: pts = MeshCoordinates[ResourceData["Stanford Bunny"]]; GradientFittedMesh[Point[pts, VertexNormals -> EstimatedPointNormals[pts]]]

属性和关系  (2)

EstimatedPointNormals 可以生成用于表面重建的法线：

Wolfram Language code: pts = MeshCoordinates[ResourceData["Horse"]]; Graphics3D[{AbsolutePointSize[1], Point[pts]}]
Wolfram Language code: GradientFittedMesh[Point[pts, VertexNormals -> EstimatedPointNormals[pts]]]

如果基础函数已知，则可以直接使用偏导数计算法向量：

Wolfram Language code: f[x_, y_] := Sin[x + Cos[y]] fx = Subscript[∂, x]f[x, y]; fy = Subscript[∂, y]f[x, y]; fnormal[a_, b_] := {-fx, -fy, 1} /. {x -> a, y -> b}; farrow[x_, y_] := Arrow[{{x, y, f[x, y]}, {x, y, f[x, y]} + fnormal[x, y]}] arrows = Table[farrow[x, y], {x, -Pi, Pi, Pi / 6}, {y, -Pi, Pi, Pi / 6}]; Show[Plot3D[f[x, y], {x, -Pi, Pi}, {y, -Pi, Pi}], Graphics3D[{Arrowheads[Small], arrows}], PlotRange -> All]

互动范例  (1)

创建一个带有可拖动点的交互式示例以实时查看法线更新：

Wolfram Language code: DynamicModule[{p = Table[(2 + 2 / 3.5 Sin[3 t]) * {Cos[t], Sin[t]}, {t, 0, 2 Pi, 0.15}]}, LocatorPane[Dynamic[p], Graphics[{Dynamic[Arrow /@ Transpose[{p, p + EstimatedPointNormals[p]}]]}, PlotRange -> 4], Appearance -> "∘"]]

巧妙范例  (1)

根据估计的法线方向为点云分配颜色：

Wolfram Language code: pts = RandomPoint[ResourceData["Utah Teapot"], 10000]; nls = EstimatedPointNormals[pts]; Graphics3D[{Point[pts, VertexColors -> RGBColor /@ Abs[nls]]}]
Wolfram Research (2022)，EstimatedPointNormals，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EstimatedPointNormals.html.

文本

Wolfram Research (2022)，EstimatedPointNormals，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EstimatedPointNormals.html.

CMS

Wolfram 语言. 2022. "EstimatedPointNormals." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/EstimatedPointNormals.html.

APA

Wolfram 语言. (2022). EstimatedPointNormals. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EstimatedPointNormals.html 年

BibTeX

@misc{reference.wolfram_2026_estimatedpointnormals, author="Wolfram Research", title="{EstimatedPointNormals}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/EstimatedPointNormals.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_estimatedpointnormals, organization={Wolfram Research}, title={EstimatedPointNormals}, year={2022}, url={https://reference.wolfram.com/language/ref/EstimatedPointNormals.html}, note=[Accessed: 08-September-2026]}