WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ExponentialMovingAverage[list,α]

平滑化定数が α の list の指数移動平均を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

ExponentialMovingAverage

ExponentialMovingAverage[list,α]

平滑化定数が α の list の指数移動平均を返す．

詳細

例題

すべて開く すべて閉じる

例  (2)

記号形式の指数移動平均：

Wolfram Language code: ExponentialMovingAverage[{a, b, c}, x]

数値の指数移動平均：

Wolfram Language code: ExponentialMovingAverage[Range[10], 1 / 3]

スコープ  (4)

指数移動平均を機械精度で計算する：

Wolfram Language code: ExponentialMovingAverage[N[{1, 5, 7, 3, 6, 2}], 1 / 2]

行列の指数移動平均は行列である：

Wolfram Language code: data = RandomReal[5, {10, 2}]
Wolfram Language code: ExponentialMovingAverage[data, 1 / 4]

任意精度のリストの結果を求める：

Wolfram Language code: ExponentialMovingAverage[N[{1, 5, 7, 3, 6, 2}, 25], 1 / 2]

任意精度で平滑係数の結果を求める：

Wolfram Language code: ExponentialMovingAverage[{1, 5, 7, 3, 6, 2}, N[1 / 2, 30]]

一般化と拡張  (2)

SparseArrayについての結果を計算する：

Wolfram Language code: sp = SparseArray[{{i_, i_} :> i, {i_, j_} /; j == i + 1 :> i - 1}, {100, 10}]
Wolfram Language code: ExponentialMovingAverage[sp, 1 / 10]

TemporalDataオブジェクトについての結果を計算する：

Wolfram Language code: td = TemporalData[{1, 2, 3}, {0}]
Wolfram Language code: ExponentialMovingAverage[td, 1 / 2]
Wolfram Language code: Normal[%]

アプリケーション  (3)

ノイズのあるデータの平滑化：

Wolfram Language code: data = Range[20] + RandomReal[{-2, 2}, 20]
Wolfram Language code: smoothed = ExponentialMovingAverage[data, 1 / 4]
Wolfram Language code: ListPlot[{data, smoothed}, PlotLegends -> {"data", "smoothed"}]

初期値を使って指数移動平均を計算する：

Wolfram Language code: data = Range[20] + RandomReal[{-2, 2}, 20]
Wolfram Language code: start = 4.5;
Wolfram Language code: smoothed = Rest[ExponentialMovingAverage[Join[{start}, data], 1 / 5]]
Wolfram Language code: ListPlot[{data, smoothed}, PlotLegends -> {"data", "smoothed"}]

金融時系列の指数移動平均を計算する：

Wolfram Language code: ListLinePlot[ExponentialMovingAverage[FinancialData["GE", "Jan. 1, 2000", "Value"], 0.1]]

特性と関係  (3)

指数移動平均の項は循環関係を満足する：

Wolfram Language code: data = RandomReal[10, 100];
Wolfram Language code: alpha = 3 / 4;
Wolfram Language code: ema = ExponentialMovingAverage[data, alpha];
Wolfram Language code: Rest[ema] == Most[ema] + alpha(Rest[data] - Most[ema])

0の平滑化係数の指数移動平均は定数である：

Wolfram Language code: ExponentialMovingAverage[{a, b, c, d}, 0]

1の平滑化係数の指数移動平均はもとのリストである：

Wolfram Language code: ExponentialMovingAverage[{a, b, c, d}, 1]
Wolfram Research (2007), ExponentialMovingAverage, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExponentialMovingAverage.html.

テキスト

Wolfram Research (2007), ExponentialMovingAverage, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExponentialMovingAverage.html.

CMS

Wolfram Language. 2007. "ExponentialMovingAverage." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ExponentialMovingAverage.html.

APA

Wolfram Language. (2007). ExponentialMovingAverage. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ExponentialMovingAverage.html

BibTeX

@misc{reference.wolfram_2026_exponentialmovingaverage, author="Wolfram Research", title="{ExponentialMovingAverage}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/ExponentialMovingAverage.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_exponentialmovingaverage, organization={Wolfram Research}, title={ExponentialMovingAverage}, year={2007}, url={https://reference.wolfram.com/language/ref/ExponentialMovingAverage.html}, note=[Accessed: 15-September-2026]}