WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Failure["tag",assoc]

tag で示されたタイプの失敗を，連想 assoc によって与えられる詳細とともに表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
特性  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

Failure

Failure["tag",assoc]

tag で示されたタイプの失敗を，連想 assoc によって与えられる詳細とともに表す．

詳細

  • Failure[…]["prop"]はFailureオブジェクトから特性を抽出する．Failure[…][{key1,key2,…}]は値のリストを抽出する． »
  • Failure[…]["Properties"]は使用可能な特性のリストを返す． »
  • 連想 assoc は，一般に以下を含む．
  • "MessageTemplate"メッセージについての文字列テンプレート
    "MessageParameters"メッセージテンプレートについて使うパラメータ
  • TemplateApplyを使ってパラメータがメッセージテンプレート有効に挿入される．
  • メッセージ名は，メッセージが生成されたときに使うために，項目"MessageTemplate":>symb::name で保存することができる．
  • FailureはInterpreterおよび関連関数によって生成される．この場合に考えられるタグには，"InterpretationFailure"，"RestrictionFailure"，"ConditionFailure"，"ConnectionFailure"がある．

例題

すべて開く すべて閉じる

例  (2)

Failureが生成される典型的な例：

Wolfram Language code: Interpreter["Integer"]["notnumber"]

もとになっている構造を示す：

Wolfram Language code: InputForm[%]

手動で失敗を起こす：

Wolfram Language code: Failure["InvalidRange", <| "MessageTemplate" -> "Enter a number lower than `Number`", "MessageParameters" -> <|"Number" -> 10|> |>]

スコープ  (10)

基本的な用法  (6)

タグだけを使ってFailureを作成する：

Wolfram Language code: Failure["InvalidInput", <||>]

タグとメッセージを使う：

Wolfram Language code: Failure["InvalidInput", <|"Message" -> "Input must be a string"|>]

位置パラメータがあるテンプレートを使う：

Wolfram Language code: Failure["ExternalOperation", <|"MessageTemplate" -> "External operation `1` failed.", "MessageParameters" -> { "file upload"}|>]

StringTemplateを使って失敗を示す：

Wolfram Language code: Failure["InvalidRange", <| "MessageTemplate" -> StringTemplate["Enter a number lower than `Number`"], "MessageParameters" -> <|"Number" -> 10|>|>]

MessageNameを使って失敗を示す：

Wolfram Language code: MyFunc::nvldrange = "Enter a number greater than `Number`"; Failure["InvalidRange", <|"MessageTemplate" -> MyFunc::nvldrange, "MessageParameters" -> <|"Number" -> 10|>|>]

Failureはメタデータを含むことができる：

Wolfram Language code: Failure["RestrictionFailure", <|"MessageTemplate" :> Interpreter::numberinterval, "MessageParameters" -> <|"Min" -> "1", "Max" -> "10", "Input" -> {"100"}|>, "Interval" -> Interval[{1, 10}], "Input" -> {"100"}, "Type" -> "Number"|> ]

特性  (4)

使用可能な全特性のリストを取得する：

Wolfram Language code: f = Failure["RestrictionFailure", Association["MessageTemplate" :> Interpreter::numberinterval, "MessageParameters" -> Association["Min" -> "1", "Max" -> "10", "Input" -> {"100"}], "Interval" -> Interval[{1, 10}], "Input" -> {"100"}, "Type" -> "Number"]];
Wolfram Language code: f["Properties"]

"Input"特性を抽出する：

Wolfram Language code: f["Input"]

メッセージテンプレート，名前，パラメータを抽出する：

Wolfram Language code: f = Failure["RestrictionFailure", Association["MessageTemplate" :> Interpreter::numberinterval, "MessageParameters" -> Association["Min" -> "1", "Max" -> "10", "Input" -> {"100"}], "Interval" -> Interval[{1, 10}], "Input" -> {"100"}, "Type" -> "Number"]];
Wolfram Language code: f[{"MessageTemplate", "MessageName", "MessageParameters"}]

メッセージテンプレートを評価せずに抽出する：

Wolfram Language code: f = Failure["RestrictionFailure", Association["MessageTemplate" :> Interpreter::numberinterval, "MessageParameters" -> Association["Min" -> "1", "Max" -> "10", "Input" -> {"100"}], "Interval" -> Interval[{1, 10}], "Input" -> {"100"}, "Type" -> "Number"]];
Wolfram Language code: f["HeldMessageTemplate"]

実際のエラーメッセージを抽出する：

Wolfram Language code: f = Failure["RestrictionFailure", Association["MessageTemplate" :> Interpreter::numberinterval, "MessageParameters" -> Association["Min" -> "1", "Max" -> "10", "Input" -> {"100"}], "Interval" -> Interval[{1, 10}], "Input" -> {"100"}, "Type" -> "Number"]];
Wolfram Language code: f["Message"]
Wolfram Language code: f["StyledMessage"]

特性と関係  (4)

ToStringを使ってフォーマットされたメッセージを得る：

Wolfram Language code: f = Interpreter["Number"]["hello"];
Wolfram Language code: f // ToString

これは"Message"特性に等しい：

Wolfram Language code: f["Message"]

Failureは，SendMailやEntityPrefetch等の関数によって返される：

Wolfram Language code: EntityPrefetch["NoSuchEntity"]

これらの関数については，Failureの逆はSuccessである：

Wolfram Language code: EntityPrefetch["Planet"]

Failure式はFailureQである：

Wolfram Language code: FailureQ[Failure["InterpretationFailure", Association["MessageTemplate" :> Interpreter::number, "MessageParameters" -> Association["Input" -> "notnumber"], "Input" -> "notnumber", "Type" -> "Integer"]]]

AssociationをRuleと一緒に使うと，評価された式がFailure式に埋め込まれる：

Wolfram Language code: MyFunc::nvldrange = "Enter a number greater than `Number`";
Wolfram Language code: Failure["InvalidRange", <|"MessageTemplate" -> MyFunc::nvldrange|>]; %["HeldMessageTemplate"]

RuleDelayedを使って評価されないようにする：

Wolfram Language code: Failure["InvalidRange", <|"MessageTemplate" :> MyFunc::nvldrange|>]; %["HeldMessageTemplate"]

おもしろい例題  (1)

Failure式の全特性でデータ集合を生成する：

Wolfram Language code: f = Failure["RestrictionFailure", Association["MessageTemplate" :> Interpreter::numberinterval, "MessageParameters" -> Association["Min" -> "1", "Max" -> "10", "Input" -> {"100"}], "Interval" -> Interval[{1, 10}], "Input" -> {"100"}, "Type" -> "Number"]];
Wolfram Language code: AssociationMap[f, f["Properties"]]//Dataset
Wolfram Research (2014), Failure, Wolfram言語関数， https://reference.wolfram.com/language/ref/Failure.html.

テキスト

Wolfram Research (2014), Failure, Wolfram言語関数， https://reference.wolfram.com/language/ref/Failure.html.

CMS

Wolfram Language. 2014. "Failure." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Failure.html.

APA

Wolfram Language. (2014). Failure. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Failure.html

BibTeX

@misc{reference.wolfram_2026_failure, author="Wolfram Research", title="{Failure}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Failure.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_failure, organization={Wolfram Research}, title={Failure}, year={2014}, url={https://reference.wolfram.com/language/ref/Failure.html}, note=[Accessed: 14-September-2026]}