WOLFRAM

Wolfram 语言与系统参考资料中心

Failure["tag",assoc]

表示由 tag 标记的类型的失败，其中的详细信息由关联 assoc 给出.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
属性  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

Failure

Failure["tag",assoc]

表示由 tag 标记的类型的失败，其中的详细信息由关联 assoc 给出.

更多信息

  • Failure[…]["prop"] 从 Failure 对象中提取属性. Failure[…][{key1,key2,…}] 提取一组值. »
  • Failure[…]["Properties"] 返回可用属性列表. »
  • 关联 assoc 通常包括：
  • "MessageTemplate"消息的字符串模板
    "MessageParameters"消息模板使用的参数
  • 用 TemplateApply 将参数插入到消息模板中.
  • 在条目 "MessageTemplate":>symb::name 下，消息名称可以存下来以便在产生消息时使用.
  • Failure 由 Interpreter 和相关函数产生. 这种情况下，可能的标签是 "InterpretationFailure"、"RestrictionFailure"、"ConditionFailure" 和 "ConnectionFailure".

范例

打开所有单元 关闭所有单元

基本范例  (2)

产生 Failure 的常见方式：

Wolfram Language code: Interpreter["Integer"]["notnumber"]

显示底层结构：

Wolfram Language code: InputForm[%]

手动产生一个失败：

Wolfram Language code: Failure["InvalidRange", <| "MessageTemplate" -> "Enter a number lower than `Number`", "MessageParameters" -> <|"Number" -> 10|> |>]

范围  (10)

基本用法  (6)

只用一个标签创建一个 Failure：

Wolfram Language code: Failure["InvalidInput", <||>]

使用标签和消息：

Wolfram Language code: Failure["InvalidInput", <|"Message" -> "Input must be a string"|>]

使用具有位置参数的模板：

Wolfram Language code: Failure["ExternalOperation", <|"MessageTemplate" -> "External operation `1` failed.", "MessageParameters" -> { "file upload"}|>]

使用 StringTemplate 表明失败：

Wolfram Language code: Failure["InvalidRange", <| "MessageTemplate" -> StringTemplate["Enter a number lower than `Number`"], "MessageParameters" -> <|"Number" -> 10|>|>]

用 MessageName 表示一个失败：

Wolfram Language code: MyFunc::nvldrange = "Enter a number greater than `Number`"; Failure["InvalidRange", <|"MessageTemplate" -> MyFunc::nvldrange, "MessageParameters" -> <|"Number" -> 10|>|>]

Failure 可含有元数据：

Wolfram Language code: Failure["RestrictionFailure", <|"MessageTemplate" :> Interpreter::numberinterval, "MessageParameters" -> <|"Min" -> "1", "Max" -> "10", "Input" -> {"100"}|>, "Interval" -> Interval[{1, 10}], "Input" -> {"100"}, "Type" -> "Number"|> ]

属性  (4)

获取所有可用属性：

Wolfram Language code: f = Failure["RestrictionFailure", Association["MessageTemplate" :> Interpreter::numberinterval, "MessageParameters" -> Association["Min" -> "1", "Max" -> "10", "Input" -> {"100"}], "Interval" -> Interval[{1, 10}], "Input" -> {"100"}, "Type" -> "Number"]];
Wolfram Language code: f["Properties"]

提取 "Input" 属性：

Wolfram Language code: f["Input"]

提取消息模板、名称和参数：

Wolfram Language code: f = Failure["RestrictionFailure", Association["MessageTemplate" :> Interpreter::numberinterval, "MessageParameters" -> Association["Min" -> "1", "Max" -> "10", "Input" -> {"100"}], "Interval" -> Interval[{1, 10}], "Input" -> {"100"}, "Type" -> "Number"]];
Wolfram Language code: f[{"MessageTemplate", "MessageName", "MessageParameters"}]

只提取消息模板，不进行计算：

Wolfram Language code: f = Failure["RestrictionFailure", Association["MessageTemplate" :> Interpreter::numberinterval, "MessageParameters" -> Association["Min" -> "1", "Max" -> "10", "Input" -> {"100"}], "Interval" -> Interval[{1, 10}], "Input" -> {"100"}, "Type" -> "Number"]];
Wolfram Language code: f["HeldMessageTemplate"]

提取实际的出错消息：

Wolfram Language code: f = Failure["RestrictionFailure", Association["MessageTemplate" :> Interpreter::numberinterval, "MessageParameters" -> Association["Min" -> "1", "Max" -> "10", "Input" -> {"100"}], "Interval" -> Interval[{1, 10}], "Input" -> {"100"}, "Type" -> "Number"]];
Wolfram Language code: f["Message"]
Wolfram Language code: f["StyledMessage"]

属性和关系  (4)

用 ToString 获取格式化的消息：

Wolfram Language code: f = Interpreter["Number"]["hello"];
Wolfram Language code: f // ToString

这相当于 "Message" 属性：

Wolfram Language code: f["Message"]

由 SendMail 和 EntityPrefetch 这样的函数返回 Failure：

Wolfram Language code: EntityPrefetch["NoSuchEntity"]

对于这些函数，与 Failure 相对的是 Success：

Wolfram Language code: EntityPrefetch["Planet"]

用 FailureQ 测试 Failure 表达式：

Wolfram Language code: FailureQ[Failure["InterpretationFailure", Association["MessageTemplate" :> Interpreter::number, "MessageParameters" -> Association["Input" -> "notnumber"], "Input" -> "notnumber", "Type" -> "Integer"]]]

将 Association 与 Rule 一起使用会把计算的表达式嵌入到 Failure 表达式中：

Wolfram Language code: MyFunc::nvldrange = "Enter a number greater than `Number`";
Wolfram Language code: Failure["InvalidRange", <|"MessageTemplate" -> MyFunc::nvldrange|>]; %["HeldMessageTemplate"]

用 RuleDelayed 阻止计算：

Wolfram Language code: Failure["InvalidRange", <|"MessageTemplate" :> MyFunc::nvldrange|>]; %["HeldMessageTemplate"]

巧妙范例  (1)

用 Failure 表达式的所有属性生成一个数据集：

Wolfram Language code: f = Failure["RestrictionFailure", Association["MessageTemplate" :> Interpreter::numberinterval, "MessageParameters" -> Association["Min" -> "1", "Max" -> "10", "Input" -> {"100"}], "Interval" -> Interval[{1, 10}], "Input" -> {"100"}, "Type" -> "Number"]];
Wolfram Language code: AssociationMap[f, f["Properties"]]//Dataset
Wolfram Research (2014)，Failure，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Failure.html.

文本

Wolfram Research (2014)，Failure，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Failure.html.

CMS

Wolfram 语言. 2014. "Failure." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Failure.html.

APA

Wolfram 语言. (2014). Failure. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Failure.html 年

BibTeX

@misc{reference.wolfram_2026_failure, author="Wolfram Research", title="{Failure}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Failure.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_failure, organization={Wolfram Research}, title={Failure}, year={2014}, url={https://reference.wolfram.com/language/ref/Failure.html}, note=[Accessed: 13-September-2026]}