WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Fold[f,x,list]

FoldList[f,x,list]の最後の要素を返す．

Fold[f,list]

Fold[f,First[list],Rest[list]]に等しい．

Fold[f]

式に適用可能なFoldの演算子形を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Fold

Fold[f,x,list]

FoldList[f,x,list]の最後の要素を返す．

Fold[f,list]

Fold[f,First[list],Rest[list]]に等しい．

Fold[f]

式に適用可能なFoldの演算子形を表す．

詳細

  • Foldが終了する前にThrowを使って中断することができる．
  • Fold[f][list]はFold[f,list]に等しい．
  • Fold[f][x,list]はFold[f,x,list]に等しい．

例題

すべて開く すべて閉じる

例  (4)

関数 f を連続的に適用して x およびリスト要素をシードする：

Wolfram Language code: Fold[f, x, {a, b, c, d}]

FoldをListと一緒に使ってネストした順序対を作る：

Wolfram Language code: Fold[List, x, {a, b, c, d}]

一度に1要素ずつ要素を乗算する：

Wolfram Language code: Fold[Times, 1, {a, b, c, d}]

リストの最初の要素から始める：

Wolfram Language code: Fold[f, {a, b, c, d}]

スコープ  (8)

Foldと一緒に純関数を使う：

Wolfram Language code: Fold[{2 #1, 3#2}&, x, {a, b, c, d}]

1つの引数にFoldの演算子形を使う：

Wolfram Language code: Fold[f][{a, b, c, d}]

2つの引数のFoldの演算子形を使う：

Wolfram Language code: Fold[f][x, {a, b, c, d}]

左結合性でベキをネストさせる：

Wolfram Language code: Fold[Power, {a, b, c, d}]

右結合性でベキをネストさせる：

Wolfram Language code: Fold[ReverseApplied[Power], Reverse@{a, b, c, d}]

続く2つの置換を行う：

Wolfram Language code: Fold[Permute, {a, b, c, d}, {{1, 4, 3, 2}, {3, 2, 4, 1}}]

一連の外積を行う：

Wolfram Language code: Fold[Cross, {{1, -1, 1}, {0, 1, 1}, {1, 1, -1}}]

頭部はListでなくともよい：

Wolfram Language code: Fold[f, x, p[a, b, c, d]]

Throwを使って早めにFoldから出る：

Wolfram Language code: FoldList[# ^ 2 + #2&, 2, Range[6]]
Wolfram Language code: Catch[Fold[If[# > 10 ^ 6, Throw[#], # ^ 2 + #2]&, 2, Range[6]]]

アプリケーション  (9)

ネストした多項式（Horner形式）を作る：

Wolfram Language code: Fold[x #1 + #2&, 0, {a, b, c, d, e}]

HornerFormは直接次の出力を生成する：

Wolfram Language code: HornerForm[Reverse[{a, b, c, d, e}].x ^ Range[0, 4], x]

連分数を作る：

Wolfram Language code: Fold[1 / (#2 + #1)&, x, Reverse[{a, b, c, d}]]

各桁の数字から数字を作る：

Wolfram Language code: Fold[10#1 + #2&, 0, {4, 5, 1, 6, 7, 8}]

交代和を作る：

Wolfram Language code: Fold[#2 - #1&, 0, Reverse[{a, b, c, d, e}]]

二分木を作る：

Wolfram Language code: Fold[List, x, {a, b, c, d}]

左に枝分かれする二分木を作る：

Wolfram Language code: Fold[{#2, #1}&, x, {a, b, c, d}]

関数合成を行う：

Wolfram Language code: Fold[#2[#1]&, x, {a, b, c, d}]

指標順になった関数を適用する：

Wolfram Language code: Fold[{f[#, #], g[#]}[[#2]]&, e, {1, 1, 2, 1, 2}]

リストを連続的に分割する：

Wolfram Language code: Fold[Partition, Range[30], {2, 4, 3}]
Wolfram Language code: Dimensions[%]

特性と関係  (9)

空のリストでたたんでも関数は適用されない：

Wolfram Language code: Fold[f, x, {}]

同様に，以下は関数を全く適用しない：

Wolfram Language code: Fold[f, {a}]

FoldはFoldListの最終要素を返す：

Wolfram Language code: Fold[f, x, {a, b, c}]
Wolfram Language code: FoldList[f, x, {a, b, c}]
Wolfram Language code: Last[%]

Foldは第1引数としてシードを取る関数 f を必要とする：

Wolfram Language code: Fold[g, x, {a, b, c, d}]

第2引数のシードが使いたければ，ReverseAppliedを使うとよい：

Wolfram Language code: Fold[ReverseApplied[g], x, {a, b, c, d}]

Foldはリスト要素を左から右に取る：

Wolfram Language code: Fold[g, x, {a, b, c, d}]

Reverseを使って右から左に要素を取る：

Wolfram Language code: Fold[g, x, Reverse@{a, b, c, d}]

ReverseとReverseAppliedを組み合せる：

Wolfram Language code: Fold[ReverseApplied[g], x, Reverse@{a, b, c, d}]

追加要素をたたむことは追加要素に関数を適用することに等しい：

Wolfram Language code: Fold[f, x, {a, b, c}]
Wolfram Language code: f[Fold[f, x, {a, b}], c]

Fold[f,x,{a,b,…}]はFold[f,f[x,a],{b,…}]に等しい：

Wolfram Language code: Fold[f, x, {a, b, c, d}]
Wolfram Language code: Fold[f, f[x, a], {b, c, d}]

第2引数を無視する関数はNestにおけるのと同じ結果を与える：

Wolfram Language code: Fold[f[#1]&, x, Range[5]]
Wolfram Language code: Nest[f[#1]&, x, 5]

FoldListはNestWhileListで計算できる：

Wolfram Language code: FoldList[f, x, {a, b, c}]
Wolfram Language code: foldStep[f_][{x_, {a_, b___}}] := {f[x, a], {b}} First /@ NestWhileList[foldStep[f], {x, {a, b, c}}, MatchQ[{_, {__}}]]

Fold[Append,{},list]は list に等しい：

Wolfram Language code: Fold[Append, {}, {1, 2, 3, 4, 5}]

考えられる問題  (1)

空リストはシードなしでたたむことはできない：

Wolfram Language code: Fold[f, {}]

しかし，FoldListの動作はよく定義されている：

Wolfram Language code: FoldList[f, {}]

おもしろい例題  (3)

原始再帰関数 r[z,r[s,r[s,r[s,p[2]]]]]の明示的な形 [詳細]：

Wolfram Language code: Array[Fold[Fold[2 ^ Ceiling[Log[2, Ceiling[(#1 + 2) / (#2 + 2)]]] (#2 + 2) - 2 - #1&, #2, Range[#1]]&, 0, Range[#]]&, 100]

集合の部分集合をすべて生成する：

Wolfram Language code: Fold[Function[{s, e}, Join[s, Append[#, e]& /@ s]], {{}}, {a, b, c}]

数のリスト中の任意の要素のすべての可能な和を求める：

Wolfram Language code: Fold[Union[#1, #1 + #2]&, {0}, {1, 2, 2, 8}]

四次のSwinnerton–Dyer多項式 [詳細]：

Wolfram Language code: Fold[Expand[(#1 /. x -> x + #2)(#1 /. x -> x - #2)]&, x, Sqrt[Prime[Range[4]]]]
Wolfram Research (1991), Fold, Wolfram言語関数， https://reference.wolfram.com/language/ref/Fold.html （2016年に更新）.

テキスト

Wolfram Research (1991), Fold, Wolfram言語関数， https://reference.wolfram.com/language/ref/Fold.html （2016年に更新）.

CMS

Wolfram Language. 1991. "Fold." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/Fold.html.

APA

Wolfram Language. (1991). Fold. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Fold.html

BibTeX

@misc{reference.wolfram_2026_fold, author="Wolfram Research", title="{Fold}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/Fold.html}", note=[Accessed: 03-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_fold, organization={Wolfram Research}, title={Fold}, year={2016}, url={https://reference.wolfram.com/language/ref/Fold.html}, note=[Accessed: 03-July-2026]}