WOLFRAM

Wolfram 语言与系统参考资料中心

Fold[f,x,list]

给出 FoldList[f,x,list] 的最后元素.

Fold[f,list]

等价于 Fold[f,First[list],Rest[list]].

Fold[f]

表示可应用于表达式的 Fold 的算子形式.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Fold

Fold[f,x,list]

给出 FoldList[f,x,list] 的最后元素.

Fold[f,list]

等价于 Fold[f,First[list],Rest[list]].

Fold[f]

表示可应用于表达式的 Fold 的算子形式.

更多信息

  • 可以使用 Throw 在它被完成前从 Fold 退出.
  • Fold[f][list] 等价于 Fold[f,list].
  • Fold[f][x,list] 等价于 Fold[f,x,list].

范例

打开所有单元 关闭所有单元

基本范例  (4)

连续将函数 f 应用于种子 x 和列表的元素：

Wolfram Language code: Fold[f, x, {a, b, c, d}]

将 Fold 与 List 一起使用，创建嵌套有序数据对：

Wolfram Language code: Fold[List, x, {a, b, c, d}]

一次乘以一个元素：

Wolfram Language code: Fold[Times, 1, {a, b, c, d}]

从列表第一个元素开始：

Wolfram Language code: Fold[f, {a, b, c, d}]

范围  (8)

将纯函数与 Fold 一起使用：

Wolfram Language code: Fold[{2 #1, 3#2}&, x, {a, b, c, d}]

对一个参数使用 Fold 的算子形式：

Wolfram Language code: Fold[f][{a, b, c, d}]

对两个参数使用 Fold 的算子形式：

Wolfram Language code: Fold[f][x, {a, b, c, d}]

用左结合创建嵌套的幂：

Wolfram Language code: Fold[Power, {a, b, c, d}]

用右结合创建嵌套的幂：

Wolfram Language code: Fold[ReverseApplied[Power], Reverse@{a, b, c, d}]

执行接下来的两个置换：

Wolfram Language code: Fold[Permute, {a, b, c, d}, {{1, 4, 3, 2}, {3, 2, 4, 1}}]

执行叉积的链：

Wolfram Language code: Fold[Cross, {{1, -1, 1}, {0, 1, 1}, {1, 1, -1}}]

第三个参数的标头不必是 List：

Wolfram Language code: Fold[f, x, p[a, b, c, d]]

用 Throw 提前退出 Fold：

Wolfram Language code: FoldList[# ^ 2 + #2&, 2, Range[6]]
Wolfram Language code: Catch[Fold[If[# > 10 ^ 6, Throw[#], # ^ 2 + #2]&, 2, Range[6]]]

应用  (9)

创建一个嵌套的多项式 (Horner 形式)：

Wolfram Language code: Fold[x #1 + #2&, 0, {a, b, c, d, e}]

HornerForm 直接产生输出：

Wolfram Language code: HornerForm[Reverse[{a, b, c, d, e}].x ^ Range[0, 4], x]

形成连分式：

Wolfram Language code: Fold[1 / (#2 + #1)&, x, Reverse[{a, b, c, d}]]

形成由数字组成的数：

Wolfram Language code: Fold[10#1 + #2&, 0, {4, 5, 1, 6, 7, 8}]

形成一个交错总和：

Wolfram Language code: Fold[#2 - #1&, 0, Reverse[{a, b, c, d, e}]]

形成一个二元树：

Wolfram Language code: Fold[List, x, {a, b, c, d}]

形成一个左分支二元树：

Wolfram Language code: Fold[{#2, #1}&, x, {a, b, c, d}]

形成一个组合函数：

Wolfram Language code: Fold[#2[#1]&, x, {a, b, c, d}]

应用一个索引的函数序列：

Wolfram Language code: Fold[{f[#, #], g[#]}[[#2]]&, e, {1, 1, 2, 1, 2}]

接连分离列表：

Wolfram Language code: Fold[Partition, Range[30], {2, 4, 3}]
Wolfram Language code: Dimensions[%]

属性和关系  (9)

将空列表折叠，完全不应用函数：

Wolfram Language code: Fold[f, x, {}]

下面的式子同样不应用函数：

Wolfram Language code: Fold[f, {a}]

Fold 返回 FoldList 的最后一个元素：

Wolfram Language code: Fold[f, x, {a, b, c}]
Wolfram Language code: FoldList[f, x, {a, b, c}]
Wolfram Language code: Last[%]

Fold 要求函数 f 在第一个参数中使用种子：

Wolfram Language code: Fold[g, x, {a, b, c, d}]

如果想要在第二个参数中使用种子，可使用 ReverseApplied：

Wolfram Language code: Fold[ReverseApplied[g], x, {a, b, c, d}]

Fold 从左到右获取列表中的元素：

Wolfram Language code: Fold[g, x, {a, b, c, d}]

用 Reverse 从右到左获取元素：

Wolfram Language code: Fold[g, x, Reverse@{a, b, c, d}]

合并使用 Reverse 和 ReverseApplied：

Wolfram Language code: Fold[ReverseApplied[g], x, Reverse@{a, b, c, d}]

折叠一个额外元素相当于将函数应用于额外元素：

Wolfram Language code: Fold[f, x, {a, b, c}]
Wolfram Language code: f[Fold[f, x, {a, b}], c]

Fold[f,x,{a,b,…}] 等价于 Fold[f,f[x,a],{b,…}]：

Wolfram Language code: Fold[f, x, {a, b, c, d}]
Wolfram Language code: Fold[f, f[x, a], {b, c, d}]

忽略第二自变量的函数给出 Nest 中相同的结果：

Wolfram Language code: Fold[f[#1]&, x, Range[5]]
Wolfram Language code: Nest[f[#1]&, x, 5]

可用 NestWhileList 计算 FoldList：

Wolfram Language code: FoldList[f, x, {a, b, c}]
Wolfram Language code: foldStep[f_][{x_, {a_, b___}}] := {f[x, a], {b}} First /@ NestWhileList[foldStep[f], {x, {a, b, c}}, MatchQ[{_, {__}}]]

Fold[Append,{},list] 等价于 list:

Wolfram Language code: Fold[Append, {}, {1, 2, 3, 4, 5}]

可能存在的问题  (1)

没有种子就不能折叠空列表：

Wolfram Language code: Fold[f, {}]

然而，FoldList 的操作是被明确定义的：

Wolfram Language code: FoldList[f, {}]

巧妙范例  (3)

基本递归函数的显示形式 r[z,r[s,r[s,r[s,p[2]]]]] [更多信息]：

Wolfram Language code: Array[Fold[Fold[2 ^ Ceiling[Log[2, Ceiling[(#1 + 2) / (#2 + 2)]]] (#2 + 2) - 2 - #1&, #2, Range[#1]]&, 0, Range[#]]&, 100]

产生一个集合的所有子集：

Wolfram Language code: Fold[Function[{s, e}, Join[s, Append[#, e]& /@ s]], {{}}, {a, b, c}]

求数字列表中任意元素组合的和：

Wolfram Language code: Fold[Union[#1, #1 + #2]&, {0}, {1, 2, 2, 8}]

第四斯维讷通－戴尔（Swinnerton–Dyer）多项式 [更多信息]：

Wolfram Language code: Fold[Expand[(#1 /. x -> x + #2)(#1 /. x -> x - #2)]&, x, Sqrt[Prime[Range[4]]]]
Wolfram Research (1991)，Fold，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Fold.html （更新于 2016 年）.

文本

Wolfram Research (1991)，Fold，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Fold.html （更新于 2016 年）.

CMS

Wolfram 语言. 1991. "Fold." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/Fold.html.

APA

Wolfram 语言. (1991). Fold. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Fold.html 年

BibTeX

@misc{reference.wolfram_2026_fold, author="Wolfram Research", title="{Fold}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/Fold.html}", note=[Accessed: 05-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_fold, organization={Wolfram Research}, title={Fold}, year={2016}, url={https://reference.wolfram.com/language/ref/Fold.html}, note=[Accessed: 05-October-2026]}